fix: impl. export logic for <PythonWheel /> resource

src/cls/IPM/ResourceProcessor/PythonWheel.cls

@@ -5,9 +5,9 @@ Parameter ATTRIBUTES As STRING = "Name,Directory,ExtraPipFlags";
 
 Parameter DESCRIPTION As STRING = "Installs a Python wheel package.";
 
-Property Name As %IPM.DataType.PythonWheelName;
+Property Name As %IPM.DataType.PythonWheelName [ Required ];
 
-Property Directory As %IPM.DataType.ResourceDirectory;
+Property Directory As %IPM.DataType.ResourceDirectory [ InitialExpression = "wheels" ];
 
 Property ExtraPipFlags As %IPM.DataType.CommandLineArgs;
 
@@ -51,4 +51,42 @@ Method OnPhase(pPhase As %String, ByRef pParams, Output pResourceHandled As %Boo
     Return $$$OK
 }
 
+Method OnExportItem(pFullExportPath As %String, pItemName As %String, ByRef pItemParams, ByRef pParams, Output pItemHandled As %Boolean = 0) As %Status
+{
+    Set pItemHandled = 0
+    Set verbose = $Get(pParams("Verbose"))
+
+    Set source = ##class(%File).NormalizeDirectory(..Directory, ..ResourceReference.Module.Root)
+    Set source = ##class(%File).NormalizeFilename(..Name, source)
+    Set source = ##class(%File).NormalizeFilenameWithSpaces(source)
+
+    Set dir = ##class(%File).GetDirectory(pFullExportPath)
+    If (##class(%File).Exists(dir)) && ('##class(%File).DirectoryExists(dir)) {
+        Return $$$ERROR($$$GeneralError, "File """_dir_""" exists and is not a directory. Failed to export item: "_..Name)
+    }
+    If '##class(%File).DirectoryExists(dir) {
+        If '##class(%File).CreateDirectoryChain(dir, .return) {
+            Return $$$ERROR($$$GeneralError, "Failed to create directory "_dir_", OS returned code: "_-return)
+        }
+    }
+    If verbose {
+        Write !,"Copying wheel item '"_source_"' to '"_pFullExportPath_"'"
+    }
+    Set pItemHandled = ##class(%File).CopyFile(source, pFullExportPath, 1, .return)
+    If 'pItemHandled {
+        Return $$$ERROR($$$GeneralError, "Failed to copy "_source_" to "_pFullExportPath_", OS returned code: "_-return)
+    }
+    Quit $$$OK
+}
+
+Method OnResolveChildren(ByRef pResourceArray, pCheckModuleOwnership As %Boolean) As %Status
+{
+    Set key = $Order(pResourceArray(""))
+    If key = "" {
+        $$$ThrowStatus($$$ERROR($$$GeneralError, "Empty resource array for PythonWheel resource processor: "_..Name))
+    }
+    Set pResourceArray(key, "RelativePath") = ..Directory _"/"_..Name
+    Quit $$$OK
+}
+
 }