feat: deploy Rollup contracts

.gitmodules

@@ -7,3 +7,12 @@
 [submodule "lib/permit2"]
 	path = lib/permit2
 	url = https://github.com/Uniswap/permit2
+[submodule "lib/simple-erc20"]
+	path = lib/simple-erc20
+	url = https://github.com/init4tech/simple-erc20
+[submodule "lib/safe-smart-account"]
+	path = lib/safe-smart-account
+	url = https://github.com/safe-global/safe-smart-account
+[submodule "lib/stablecoin-evm"]
+	path = lib/stablecoin-evm
+	url = https://github.com/circlefin/stablecoin-evm

script/DeployGnosisSafe.s.sol

@@ -0,0 +1,99 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity 0.8.26;
+
+// deps
+import {SafeL2} from "safe-smart-account/contracts/SafeL2.sol";
+import {SafeProxyFactory} from "safe-smart-account/contracts/proxies/SafeProxyFactory.sol";
+import {CompatibilityFallbackHandler} from "safe-smart-account/contracts/handler/CompatibilityFallbackHandler.sol";
+// script deps
+import {Script, console2} from "forge-std/Script.sol";
+
+struct SafeSetup {
+    address[] owners;
+    uint256 threshold;
+    address to;
+    bytes data;
+    address fallbackHandler;
+    address paymentToken;
+    uint256 payment;
+    address payable paymentReceiver;
+    uint256 saltNonce;
+}
+
+address constant OWNER_ONE = 0x1111111111111111111111111111111111111111;
+address constant OWNER_TWO = 0x2222222222222222222222222222222222222222;
+bytes32 constant SENTINEL_VALUE = 0x0000000000000000000000000000000000000000000000000000000000000001;
+
+contract GnosisScript is Script {
+    // deploy:
+    // forge script GnosisScript --sig "deployGnosis()" --rpc-url $RPC_URL --broadcast [signing args]
+    function deployGnosis()
+        public
+        returns (address gnosisFactory, address gnosisSingleton, address gnosisFallbackHandler, address usdcAdmin)
+    {
+        vm.startBroadcast();
+
+        // deploy gnosis safe singleton & proxy factory
+        (gnosisFactory, gnosisSingleton, gnosisFallbackHandler) = deployGnosisCore();
+
+        // deploy a gnosis safe proxy as the USDC admin
+        usdcAdmin = deploySafeInstance(gnosisFactory, gnosisSingleton, getUsdcAdminSetup(gnosisFallbackHandler));
+    }
+
+    function deployGnosisCore() public returns (address factory, address singleton, address fallbackHandler) {
+        factory = address(new SafeProxyFactory{salt: "zenith.gnosisFactory"}());
+        singleton = address(new SafeL2{salt: "zenith.gnosisSingleton"}());
+        fallbackHandler = address(new CompatibilityFallbackHandler{salt: "zenith.gnosisFallbackHandlder"}());
+    }
+
+    function deploySafeInstance(address factory, address singleton, SafeSetup memory setup)
+        public
+        returns (address safe)
+    {
+        bytes memory init = abi.encodeWithSignature(
+            "setup(address[],uint256,address,bytes,address,address,uint256,address)",
+            setup.owners,
+            setup.threshold,
+            setup.to,
+            setup.data,
+            setup.fallbackHandler,
+            setup.paymentToken,
+            setup.payment,
+            setup.paymentReceiver
+        );
+        safe = address(SafeProxyFactory(factory).createProxyWithNonce(singleton, init, setup.saltNonce));
+    }
+
+    // setup the gnosis safe with 2 owners, threshold of 1.
+    // make the owners recognizable addrs to aid in inspecting storage layout
+    function getUsdcAdminSetup(address fallbackHandler) public pure returns (SafeSetup memory usdcAdminSetup) {
+        address[] memory owners = new address[](2);
+        owners[0] = OWNER_ONE;
+        owners[1] = OWNER_TWO;
+        usdcAdminSetup = SafeSetup({
+            owners: owners,
+            threshold: 1,
+            to: address(0),
+            data: "",
+            fallbackHandler: fallbackHandler,
+            paymentToken: address(0),
+            payment: 0,
+            paymentReceiver: payable(address(0)),
+            saltNonce: 17001
+        });
+    }
+
+    // example run:
+    // forge script GnosisScript --sig "printOwnerSlots" "[0x1111111111111111111111111111111111111111, 0x2222222222222222222222222222222222222222]"
+    function printOwnerSlots(address[] memory owners) public pure {
+        for (uint256 i = 0; i <= owners.length; i++) {
+            bytes32 value = (i == 0) ? SENTINEL_VALUE : addressToBytes32(owners[i - 1]);
+            bytes32 slot = keccak256(abi.encodePacked(value, uint256(2)));
+            console2.logBytes32(slot);
+        }
+    }
+
+    function addressToBytes32(address addr) internal pure returns (bytes32) {
+        return bytes32(uint256(uint160(addr)));
+    }
+}

script/Zenith.s.sol

@@ -5,9 +5,7 @@ pragma solidity 0.8.26;
 import {Zenith} from "../src/Zenith.sol";
 import {Transactor} from "../src/Transactor.sol";
 import {HostOrders} from "../src/orders/HostOrders.sol";
-import {RollupOrders} from "../src/orders/RollupOrders.sol";
 import {Passage} from "../src/passage/Passage.sol";
-import {RollupPassage} from "../src/passage/RollupPassage.sol";
 // utils
 import {Script} from "forge-std/Script.sol";
 
@@ -28,14 +26,6 @@ contract ZenithScript is Script {
         m = new HostOrders(permit2);
     }
 
-    // deploy:
-    // forge script ZenithScript --sig "deployL2(address)" --rpc-url $L2_RPC_URL --private-key $PRIVATE_KEY --broadcast $PERMIT_2
-    function deployL2(address permit2) public returns (RollupPassage p, RollupOrders m) {
-        vm.startBroadcast();
-        p = new RollupPassage(permit2);
-        m = new RollupOrders(permit2);
-    }
-
     // NOTE: script must be run using SequencerAdmin key
     // set sequencer:
     // forge script ZenithScript --sig "setSequencerRole(address,address)" --rpc-url $RPC_URL --private-key $PRIVATE_KEY --broadcast $ZENITH_ADDRESS $SEQUENCER_ADDRESS

script/ZenithL2.s.sol

@@ -0,0 +1,36 @@
+// SPDX-License-Identifier: MIT OR Apache-2.0
+pragma solidity 0.8.26;
+
+// system contracts
+import {RollupOrders} from "../src/orders/RollupOrders.sol";
+import {RollupPassage} from "../src/passage/RollupPassage.sol";
+// simple erc20
+import {SimpleERC20} from "simple-erc20/SimpleERC20.sol";
+// utils
+import {Script, console2} from "forge-std/Script.sol";
+
+// create2 address for Permit2
+address constant PERMIT2 = 0x000000000022D473030F116dDEE9F6B43aC78BA3;
+// address of Minter with permission to mint ERC20 tokens
+address constant MINTER = 0x9999999999999999999999999999999999999999;
+
+contract L2Script is Script {
+    // deploy:
+    // forge script L2Script --sig "deploySystem()" --rpc-url $RPC_URL --broadcast [signing args]
+    function deploySystem() public returns (address rollupPassage, address rollupOrders, address wbtc, address usdt) {
+        vm.startBroadcast();
+
+        // deploy system contracts
+        rollupPassage = address(new RollupPassage{salt: "zenith.rollupPassage"}(PERMIT2));
+        rollupOrders = address(new RollupOrders{salt: "zenith.rollupOrders"}(PERMIT2));
+
+        // deploy simple erc20 tokens
+        wbtc = address(new SimpleERC20{salt: "zenith.wbtc"}(MINTER, "Wrapped BTC", "WBTC"));
+        usdt = address(new SimpleERC20{salt: "zenith.usdt"}(MINTER, "Tether USD", "USDT"));
+    }
+}
+
+// NOTE: must deploy Permit2 via https://github.com/Uniswap/permit2/blob/main/script/DeployPermit2.s.sol
+// in order to properly setup _CACHED_CHAIN_ID and _CACHED_DOMAIN_SEPARATOR
+
+// NOTE: must deploy USDC via https://github.com/circlefin/stablecoin-evm/blob/master/scripts/deploy/deploy-fiat-token.s.sol