Adds helpers for dealing with Maybe values in Order.Extra

src/Order/Extra.elm

@@ -2,6 +2,7 @@ module Order.Extra exposing
     ( explicit, byField, byFieldWith, byRank, ifStillTiedThen
     , breakTies, breakTiesWith, reverse
     , natural
+    , nothingLast, nothingFirst
     , isOrdered, greaterThanBy, lessThanBy
     )
 
@@ -90,6 +91,11 @@ to sort a deck of cards you can use `cardOrdering` directly:
 @docs natural
 
 
+# Maybes
+
+@docs nothingLast, nothingFirst
+
+
 # Utility
 
 @docs isOrdered, greaterThanBy, lessThanBy
@@ -462,6 +468,56 @@ greaterThanBy ordering x y =
 
 
 
+--- Maybe
+
+
+{-| Returns an ordering that treats `Nothing` as greater than `Just a`.
+
+    [ Just 1, Nothing, Just 2 ]
+        |> List.sortWith (Order.Extra.nothingLast compare)
+        --> [ Just 1, Just 2, Nothing ]
+
+-}
+nothingLast : (a -> a -> Order) -> Maybe a -> Maybe a -> Order
+nothingLast ordering x y =
+    case ( x, y ) of
+        ( Nothing, Nothing ) ->
+            EQ
+
+        ( Nothing, Just _ ) ->
+            GT
+
+        ( Just _, Nothing ) ->
+            LT
+
+        ( Just a, Just b ) ->
+            ordering a b
+
+
+{-| Returns an ordering that treats `Nothing` as less than `Just a`.
+
+    [ Just 1, Nothing, Just 2 ]
+        |> List.sortWith (Order.Extra.nothingFirst compare)
+        --> [ Nothing, Just 1, Just 2 ]
+
+-}
+nothingFirst : (a -> a -> Order) -> Maybe a -> Maybe a -> Order
+nothingFirst ordering x y =
+    case ( x, y ) of
+        ( Nothing, Nothing ) ->
+            EQ
+
+        ( Nothing, Just _ ) ->
+            LT
+
+        ( Just _, Nothing ) ->
+            GT
+
+        ( Just a, Just b ) ->
+            ordering a b
+
+
+
 --- String