feat: Add Nix flake for reproducible builds

.gitignore

@@ -37,6 +37,8 @@ pnpm-debug.log*
 .pnpm-debug.log*
 
 # Common build outputs
+result
+result-*
 dist/
 **/dist/
 build/

README.md

@@ -41,6 +41,12 @@ curl -fsSL --proto '=https' --tlsv1.2 https://install.codanna.sh | sh
 brew install codanna
 ```
 
+### Or via Nix
+
+```bash
+nix run github:bartolli/codanna
+```
+
 ### Windows (PowerShell)
 ```powershell
 irm https://raw.githubusercontent.com/bartolli/codanna/main/scripts/install.ps1 | iex

flake.nix

@@ -0,0 +1,69 @@
+{
+  description = "Code Intelligence for Large Language Models";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    rust-overlay = {
+      url = "github:oxalica/rust-overlay";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+    naersk = {
+      url = "github:nix-community/naersk";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs =
+    {
+      self,
+      nixpkgs,
+      rust-overlay,
+      naersk,
+      flake-utils,
+      ...
+    }:
+    flake-utils.lib.eachDefaultSystem (
+      system:
+      let
+        pkgs = import nixpkgs {
+          inherit system;
+          overlays = [ rust-overlay.overlays.default ];
+        };
+        rust = pkgs.rust-bin.stable.latest.default;
+        naersk' = pkgs.callPackage naersk {
+          cargo = rust;
+          rustc = rust;
+        };
+      in
+      {
+        devShells.default = pkgs.mkShell {
+          buildInputs = with pkgs; [
+            rust
+            rust-analyzer
+            openssl
+            onnxruntime
+            pkg-config
+          ];
+          ORT_SKIP_DOWNLOAD = "1";
+        };
+        packages.default = naersk'.buildPackage {
+          pname = "codanna";
+          src = ./.;
+          buildInputs = [
+            pkgs.openssl
+            pkgs.onnxruntime
+          ];
+          nativeBuildInputs = [ pkgs.pkg-config ];
+          cargoBuildOptions =
+            x:
+            x
+            ++ [
+              "-p"
+              "codanna"
+            ];
+          ORT_SKIP_DOWNLOAD = "1";
+        };
+      }
+    );
+}