fix accuracy of logit

src/basicfuns.jl

@@ -120,7 +120,13 @@ for ``0 < x < 1``.
 
 Its inverse is the [`logistic`](@ref) function.
 """
-logit(x::Real) = log(x / (one(x) - x))
+function logit(x::Real)
+    if 4 * x < 1
+        -log(inv(x) - 1)
+    else
+        2 * atanh(2*x - 1)
+    end
+end
 
 """
 $(SIGNATURES)

test/basicfuns.jl

@@ -86,6 +86,13 @@ end
     @test logistic(+750.0) === 1.0
     @test iszero(logit(0.5))
     @test logit(logistic(2)) ≈ 2.0
+    @testset "accuracy of `logit`" begin
+        for t in (Float16, Float32, Float64)
+            for x in range(start = t(0), stop = t(1), length = 500)
+                @test 2 * ulp_error(logit, x) < 3
+            end
+        end
+    end
 end
 
 @testset "logcosh and logabssinh" begin

test/common/ULPError.jl

@@ -0,0 +1,48 @@
+module ULPError
+    export ulp_error, ulp_error_maximum
+    function ulp_error(accurate::AbstractFloat, approximate::AbstractFloat)
+        # the ULP error is usually not required to great accuracy, so `Float32` should be precise enough
+        zero_return = 0f0
+        inf_return = Inf32
+        # handle floating-point edge cases
+        if !(isfinite(accurate) && isfinite(approximate))
+            accur_is_nan = isnan(accurate)
+            approx_is_nan = isnan(approximate)
+            if accur_is_nan || approx_is_nan
+                return if accur_is_nan === approx_is_nan
+                    zero_return
+                else
+                    inf_return
+                end
+            end
+            if isinf(approximate)
+                return if isinf(accurate) && (signbit(accurate) == signbit(approximate))
+                    zero_return
+                else
+                    inf_return
+                end
+            end
+        end
+        acc = if accurate isa Union{Float16, Float32}
+            # widen for better accuracy when doing so does not impact performance too much
+            widen(accurate)
+        else
+            accurate
+        end
+        abs(Float32((approximate - acc) / eps(approximate))::Float32)
+    end
+    function ulp_error(accurate::Acc, approximate::App, x::AbstractFloat) where {Acc, App}
+        acc = accurate(x)
+        app = approximate(x)
+        ulp_error(acc, app)
+    end
+    function ulp_error(func::Func, x::AbstractFloat) where {Func}
+        ulp_error(func ∘ BigFloat, func, x)
+    end
+    function ulp_error_maximum(func::Func, iterator) where {Func}
+        function f(x::AbstractFloat)
+            ulp_error(func, x)
+        end
+        maximum(f, iterator)
+    end
+end

test/runtests.jl

@@ -10,6 +10,9 @@ using OffsetArrays
 using Random
 using Test
 
+include("common/ULPError.jl")
+using .ULPError
+
 Random.seed!(1234)
 
 include("basicfuns.jl")