build.gradle

buildscript {
  repositories {
    mavenLocal()
    maven { url "https://plugins.gradle.org/m2/" }
    maven { url "https://repo.grails.org/grails/core" }
  }
  dependencies {
    classpath "org.grails:grails-gradle-plugin:$grailsGradlePluginVersion"
    classpath "org.yakworks:gradle-plugins:$vShipyak"
    classpath "io.github.gradle-nexus:publish-plugin:$vMavenNexus"
    classpath "org.grails.plugins:views-gradle:$vViews"
    classpath "com.github.spotbugs.snom:spotbugs-gradle-plugin:4.7.9"
    classpath "org.grails.plugins:hibernate5:7.3.0"
    classpath "com.bertramlabs.plugins:asset-pipeline-gradle:3.4.6"
  }
}

//our opinionated defaults for gradle groovy & grails projects
//NOTE: uses shipyak to pulls info for build from build.yml too.
apply plugin: 'yakworks.shipyak'
apply plugin: "io.github.gradle-nexus.publish-plugin"

//reads props from each sub-project gradle.props and sets up repos and java and groovy compile settings
apply from: "${rootProject.projectDir}/gradle/compile.gradle"
//sets us the sonatype/nexus publishing for nexus:publish-plugin for any project that has isPublishable in gradle.props
apply from: "${rootProject.projectDir}/gradle/publish.gradle"

allprojects {
  repositories {
    mavenLocal()
    mavenCentral()
    maven { url "https://repo.grails.org/grails/core" }
    maven { url "https://repo.spring.io/snapshot" }
    maven {
      url "http://repo.9ci.com/oss-snapshots"
      allowInsecureProtocol = true
      mavenContent {
        snapshotsOnly()
      }
    }
    maven { url "http://repo.9ci.com/public-libs"; allowInsecureProtocol = true }
  }
}

subprojects { subprj ->

  repositories {

    maven { url "https://jaspersoft.jfrog.io/jaspersoft/third-party-ce-artifacts/" }
  }

  if (isGrailsLibrary) {
    apply from: "${rootProject.projectDir}/gradle/grails-lib.gradle"
  }
  apply from: "${rootProject.projectDir}/gradle/test-unit.gradle"

  // if (isExample) {
  //   dependencies {
  //     implementation "org.springframework.boot:spring-boot-starter-logging"
  //     implementation "org.springframework.boot:spring-boot-starter-tomcat"
  //     implementation "org.grails:grails-plugin-services"
  //   }
  // }

  ext {
      codenarcRuleset = '''
        //getRule('CyclomaticComplexity').enabled = false
        //getRule('NoWildcardImports').enabled = false
        getRule('FieldName').enabled = false
        getRule('VariableName').enabled = false
        getRule('UnnecessaryDotClass').enabled = false
        getRule('FieldName').enabled = false
      '''
  }

}