forked from gbenson/binutils-gdb
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathd-exp.y
1712 lines (1485 loc) · 45.6 KB
/
d-exp.y
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/* YACC parser for D expressions, for GDB.
Copyright (C) 2014-2015 Free Software Foundation, Inc.
This file is part of GDB.
This program is free software; you can redistribute it and/or modify
it under the terms of the GNU General Public License as published by
the Free Software Foundation; either version 3 of the License, or
(at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public License
along with this program. If not, see <http://www.gnu.org/licenses/>. */
/* This file is derived from c-exp.y, jv-exp.y. */
/* Parse a D expression from text in a string,
and return the result as a struct expression pointer.
That structure contains arithmetic operations in reverse polish,
with constants represented by operations that are followed by special data.
See expression.h for the details of the format.
What is important here is that it can be built up sequentially
during the process of parsing; the lower levels of the tree always
come first in the result.
Note that malloc's and realloc's in this file are transformed to
xmalloc and xrealloc respectively by the same sed command in the
makefile that remaps any other malloc/realloc inserted by the parser
generator. Doing this with #defines and trying to control the interaction
with include files (<malloc.h> and <stdlib.h> for example) just became
too messy, particularly when such includes can be inserted at random
times by the parser generator. */
%{
#include "defs.h"
#include <ctype.h>
#include "expression.h"
#include "value.h"
#include "parser-defs.h"
#include "language.h"
#include "c-lang.h"
#include "d-lang.h"
#include "bfd.h" /* Required by objfiles.h. */
#include "symfile.h" /* Required by objfiles.h. */
#include "objfiles.h" /* For have_full_symbols and have_partial_symbols */
#include "charset.h"
#include "block.h"
#define parse_type(ps) builtin_type (parse_gdbarch (ps))
#define parse_d_type(ps) builtin_d_type (parse_gdbarch (ps))
/* Remap normal yacc parser interface names (yyparse, yylex, yyerror, etc),
as well as gratuitiously global symbol names, so we can have multiple
yacc generated parsers in gdb. Note that these are only the variables
produced by yacc. If other parser generators (bison, byacc, etc) produce
additional global names that conflict at link time, then those parser
generators need to be fixed instead of adding those names to this list. */
#define yymaxdepth d_maxdepth
#define yyparse d_parse_internal
#define yylex d_lex
#define yyerror d_error
#define yylval d_lval
#define yychar d_char
#define yydebug d_debug
#define yypact d_pact
#define yyr1 d_r1
#define yyr2 d_r2
#define yydef d_def
#define yychk d_chk
#define yypgo d_pgo
#define yyact d_act
#define yyexca d_exca
#define yyerrflag d_errflag
#define yynerrs d_nerrs
#define yyps d_ps
#define yypv d_pv
#define yys d_s
#define yy_yys d_yys
#define yystate d_state
#define yytmp d_tmp
#define yyv d_v
#define yy_yyv d_yyv
#define yyval d_val
#define yylloc d_lloc
#define yyreds d_reds /* With YYDEBUG defined */
#define yytoks d_toks /* With YYDEBUG defined */
#define yyname d_name /* With YYDEBUG defined */
#define yyrule d_rule /* With YYDEBUG defined */
#define yylhs d_yylhs
#define yylen d_yylen
#define yydefre d_yydefred
#define yydgoto d_yydgoto
#define yysindex d_yysindex
#define yyrindex d_yyrindex
#define yygindex d_yygindex
#define yytable d_yytable
#define yycheck d_yycheck
#define yyss d_yyss
#define yysslim d_yysslim
#define yyssp d_yyssp
#define yystacksize d_yystacksize
#define yyvs d_yyvs
#define yyvsp d_yyvsp
#ifndef YYDEBUG
#define YYDEBUG 1 /* Default to yydebug support */
#endif
#define YYFPRINTF parser_fprintf
/* The state of the parser, used internally when we are parsing the
expression. */
static struct parser_state *pstate = NULL;
int yyparse (void);
static int yylex (void);
void yyerror (char *);
static int type_aggregate_p (struct type *);
%}
/* Although the yacc "value" of an expression is not used,
since the result is stored in the structure being created,
other node types do have values. */
%union
{
struct {
LONGEST val;
struct type *type;
} typed_val_int;
struct {
DOUBLEST dval;
struct type *type;
} typed_val_float;
struct symbol *sym;
struct type *tval;
struct typed_stoken tsval;
struct stoken sval;
struct ttype tsym;
struct symtoken ssym;
int ival;
int voidval;
struct block *bval;
enum exp_opcode opcode;
struct stoken_vector svec;
}
%{
/* YYSTYPE gets defined by %union */
static int parse_number (struct parser_state *, const char *,
int, int, YYSTYPE *);
%}
%token <sval> IDENTIFIER UNKNOWN_NAME
%token <tsym> TYPENAME
%token <voidval> COMPLETE
/* A NAME_OR_INT is a symbol which is not known in the symbol table,
but which would parse as a valid number in the current input radix.
E.g. "c" when input_radix==16. Depending on the parse, it will be
turned into a name or into a number. */
%token <sval> NAME_OR_INT
%token <typed_val_int> INTEGER_LITERAL
%token <typed_val_float> FLOAT_LITERAL
%token <tsval> CHARACTER_LITERAL
%token <tsval> STRING_LITERAL
%type <svec> StringExp
%type <tval> BasicType TypeExp
%type <sval> IdentifierExp
%type <ival> ArrayLiteral
%token ENTRY
%token ERROR
/* Keywords that have a constant value. */
%token TRUE_KEYWORD FALSE_KEYWORD NULL_KEYWORD
/* Class 'super' accessor. */
%token SUPER_KEYWORD
/* Properties. */
%token CAST_KEYWORD SIZEOF_KEYWORD
%token TYPEOF_KEYWORD TYPEID_KEYWORD
%token INIT_KEYWORD
/* Comparison keywords. */
/* Type storage classes. */
%token IMMUTABLE_KEYWORD CONST_KEYWORD SHARED_KEYWORD
/* Non-scalar type keywords. */
%token STRUCT_KEYWORD UNION_KEYWORD
%token CLASS_KEYWORD INTERFACE_KEYWORD
%token ENUM_KEYWORD TEMPLATE_KEYWORD
%token DELEGATE_KEYWORD FUNCTION_KEYWORD
%token <sval> DOLLAR_VARIABLE
%token <opcode> ASSIGN_MODIFY
%left ','
%right '=' ASSIGN_MODIFY
%right '?'
%left OROR
%left ANDAND
%left '|'
%left '^'
%left '&'
%left EQUAL NOTEQUAL '<' '>' LEQ GEQ
%right LSH RSH
%left '+' '-'
%left '*' '/' '%'
%right HATHAT
%left IDENTITY NOTIDENTITY
%right INCREMENT DECREMENT
%right '.' '[' '('
%token DOTDOT
%%
start :
Expression
| TypeExp
;
/* Expressions, including the comma operator. */
Expression:
CommaExpression
;
CommaExpression:
AssignExpression
| AssignExpression ',' CommaExpression
{ write_exp_elt_opcode (pstate, BINOP_COMMA); }
;
AssignExpression:
ConditionalExpression
| ConditionalExpression '=' AssignExpression
{ write_exp_elt_opcode (pstate, BINOP_ASSIGN); }
| ConditionalExpression ASSIGN_MODIFY AssignExpression
{ write_exp_elt_opcode (pstate, BINOP_ASSIGN_MODIFY);
write_exp_elt_opcode (pstate, $2);
write_exp_elt_opcode (pstate, BINOP_ASSIGN_MODIFY); }
;
ConditionalExpression:
OrOrExpression
| OrOrExpression '?' Expression ':' ConditionalExpression
{ write_exp_elt_opcode (pstate, TERNOP_COND); }
;
OrOrExpression:
AndAndExpression
| OrOrExpression OROR AndAndExpression
{ write_exp_elt_opcode (pstate, BINOP_LOGICAL_OR); }
;
AndAndExpression:
OrExpression
| AndAndExpression ANDAND OrExpression
{ write_exp_elt_opcode (pstate, BINOP_LOGICAL_AND); }
;
OrExpression:
XorExpression
| OrExpression '|' XorExpression
{ write_exp_elt_opcode (pstate, BINOP_BITWISE_IOR); }
;
XorExpression:
AndExpression
| XorExpression '^' AndExpression
{ write_exp_elt_opcode (pstate, BINOP_BITWISE_XOR); }
;
AndExpression:
CmpExpression
| AndExpression '&' CmpExpression
{ write_exp_elt_opcode (pstate, BINOP_BITWISE_AND); }
;
CmpExpression:
ShiftExpression
| EqualExpression
| IdentityExpression
| RelExpression
;
EqualExpression:
ShiftExpression EQUAL ShiftExpression
{ write_exp_elt_opcode (pstate, BINOP_EQUAL); }
| ShiftExpression NOTEQUAL ShiftExpression
{ write_exp_elt_opcode (pstate, BINOP_NOTEQUAL); }
;
IdentityExpression:
ShiftExpression IDENTITY ShiftExpression
{ write_exp_elt_opcode (pstate, BINOP_EQUAL); }
| ShiftExpression NOTIDENTITY ShiftExpression
{ write_exp_elt_opcode (pstate, BINOP_NOTEQUAL); }
;
RelExpression:
ShiftExpression '<' ShiftExpression
{ write_exp_elt_opcode (pstate, BINOP_LESS); }
| ShiftExpression LEQ ShiftExpression
{ write_exp_elt_opcode (pstate, BINOP_LEQ); }
| ShiftExpression '>' ShiftExpression
{ write_exp_elt_opcode (pstate, BINOP_GTR); }
| ShiftExpression GEQ ShiftExpression
{ write_exp_elt_opcode (pstate, BINOP_GEQ); }
;
ShiftExpression:
AddExpression
| ShiftExpression LSH AddExpression
{ write_exp_elt_opcode (pstate, BINOP_LSH); }
| ShiftExpression RSH AddExpression
{ write_exp_elt_opcode (pstate, BINOP_RSH); }
;
AddExpression:
MulExpression
| AddExpression '+' MulExpression
{ write_exp_elt_opcode (pstate, BINOP_ADD); }
| AddExpression '-' MulExpression
{ write_exp_elt_opcode (pstate, BINOP_SUB); }
| AddExpression '~' MulExpression
{ write_exp_elt_opcode (pstate, BINOP_CONCAT); }
;
MulExpression:
UnaryExpression
| MulExpression '*' UnaryExpression
{ write_exp_elt_opcode (pstate, BINOP_MUL); }
| MulExpression '/' UnaryExpression
{ write_exp_elt_opcode (pstate, BINOP_DIV); }
| MulExpression '%' UnaryExpression
{ write_exp_elt_opcode (pstate, BINOP_REM); }
UnaryExpression:
'&' UnaryExpression
{ write_exp_elt_opcode (pstate, UNOP_ADDR); }
| INCREMENT UnaryExpression
{ write_exp_elt_opcode (pstate, UNOP_PREINCREMENT); }
| DECREMENT UnaryExpression
{ write_exp_elt_opcode (pstate, UNOP_PREDECREMENT); }
| '*' UnaryExpression
{ write_exp_elt_opcode (pstate, UNOP_IND); }
| '-' UnaryExpression
{ write_exp_elt_opcode (pstate, UNOP_NEG); }
| '+' UnaryExpression
{ write_exp_elt_opcode (pstate, UNOP_PLUS); }
| '!' UnaryExpression
{ write_exp_elt_opcode (pstate, UNOP_LOGICAL_NOT); }
| '~' UnaryExpression
{ write_exp_elt_opcode (pstate, UNOP_COMPLEMENT); }
| CastExpression
| PowExpression
;
CastExpression:
CAST_KEYWORD '(' TypeExp ')' UnaryExpression
{ write_exp_elt_opcode (pstate, UNOP_CAST);
write_exp_elt_type (pstate, $3);
write_exp_elt_opcode (pstate, UNOP_CAST); }
/* C style cast is illegal D, but is still recognised in
the grammar, so we keep this around for convenience. */
| '(' TypeExp ')' UnaryExpression
{ write_exp_elt_opcode (pstate, UNOP_CAST);
write_exp_elt_type (pstate, $2);
write_exp_elt_opcode (pstate, UNOP_CAST); }
;
PowExpression:
PostfixExpression
| PostfixExpression HATHAT UnaryExpression
{ write_exp_elt_opcode (pstate, BINOP_EXP); }
;
PostfixExpression:
PrimaryExpression
| PostfixExpression '.' COMPLETE
{ struct stoken s;
mark_struct_expression (pstate);
write_exp_elt_opcode (pstate, STRUCTOP_STRUCT);
s.ptr = "";
s.length = 0;
write_exp_string (pstate, s);
write_exp_elt_opcode (pstate, STRUCTOP_STRUCT); }
| PostfixExpression '.' IDENTIFIER
{ write_exp_elt_opcode (pstate, STRUCTOP_STRUCT);
write_exp_string (pstate, $3);
write_exp_elt_opcode (pstate, STRUCTOP_STRUCT); }
| PostfixExpression '.' IDENTIFIER COMPLETE
{ mark_struct_expression (pstate);
write_exp_elt_opcode (pstate, STRUCTOP_STRUCT);
write_exp_string (pstate, $3);
write_exp_elt_opcode (pstate, STRUCTOP_STRUCT); }
| PostfixExpression INCREMENT
{ write_exp_elt_opcode (pstate, UNOP_POSTINCREMENT); }
| PostfixExpression DECREMENT
{ write_exp_elt_opcode (pstate, UNOP_POSTDECREMENT); }
| CallExpression
| IndexExpression
| SliceExpression
;
ArgumentList:
AssignExpression
{ arglist_len = 1; }
| ArgumentList ',' AssignExpression
{ arglist_len++; }
;
ArgumentList_opt:
/* EMPTY */
{ arglist_len = 0; }
| ArgumentList
;
CallExpression:
PostfixExpression '('
{ start_arglist (); }
ArgumentList_opt ')'
{ write_exp_elt_opcode (pstate, OP_FUNCALL);
write_exp_elt_longcst (pstate, (LONGEST) end_arglist ());
write_exp_elt_opcode (pstate, OP_FUNCALL); }
;
IndexExpression:
PostfixExpression '[' ArgumentList ']'
{ if (arglist_len > 0)
{
write_exp_elt_opcode (pstate, MULTI_SUBSCRIPT);
write_exp_elt_longcst (pstate, (LONGEST) arglist_len);
write_exp_elt_opcode (pstate, MULTI_SUBSCRIPT);
}
else
write_exp_elt_opcode (pstate, BINOP_SUBSCRIPT);
}
;
SliceExpression:
PostfixExpression '[' ']'
{ /* Do nothing. */ }
| PostfixExpression '[' AssignExpression DOTDOT AssignExpression ']'
{ write_exp_elt_opcode (pstate, TERNOP_SLICE); }
;
PrimaryExpression:
'(' Expression ')'
{ /* Do nothing. */ }
| IdentifierExp
{ struct bound_minimal_symbol msymbol;
char *copy = copy_name ($1);
struct field_of_this_result is_a_field_of_this;
struct block_symbol sym;
/* Handle VAR, which could be local or global. */
sym = lookup_symbol (copy, expression_context_block, VAR_DOMAIN,
&is_a_field_of_this);
if (sym.symbol && SYMBOL_CLASS (sym.symbol) != LOC_TYPEDEF)
{
if (symbol_read_needs_frame (sym.symbol))
{
if (innermost_block == 0
|| contained_in (sym.block, innermost_block))
innermost_block = sym.block;
}
write_exp_elt_opcode (pstate, OP_VAR_VALUE);
/* We want to use the selected frame, not another more inner frame
which happens to be in the same block. */
write_exp_elt_block (pstate, NULL);
write_exp_elt_sym (pstate, sym.symbol);
write_exp_elt_opcode (pstate, OP_VAR_VALUE);
}
else if (is_a_field_of_this.type != NULL)
{
/* It hangs off of `this'. Must not inadvertently convert from a
method call to data ref. */
if (innermost_block == 0
|| contained_in (sym.block, innermost_block))
innermost_block = sym.block;
write_exp_elt_opcode (pstate, OP_THIS);
write_exp_elt_opcode (pstate, OP_THIS);
write_exp_elt_opcode (pstate, STRUCTOP_PTR);
write_exp_string (pstate, $1);
write_exp_elt_opcode (pstate, STRUCTOP_PTR);
}
else
{
/* Lookup foreign name in global static symbols. */
msymbol = lookup_bound_minimal_symbol (copy);
if (msymbol.minsym != NULL)
write_exp_msymbol (pstate, msymbol);
else if (!have_full_symbols () && !have_partial_symbols ())
error (_("No symbol table is loaded. Use the \"file\" command"));
else
error (_("No symbol \"%s\" in current context."), copy);
}
}
| TypeExp '.' IdentifierExp
{ struct type *type = check_typedef ($1);
/* Check if the qualified name is in the global
context. However if the symbol has not already
been resolved, it's not likely to be found. */
if (TYPE_CODE (type) == TYPE_CODE_MODULE)
{
struct bound_minimal_symbol msymbol;
struct block_symbol sym;
const char *type_name = TYPE_SAFE_NAME (type);
int type_name_len = strlen (type_name);
char *name;
name = xstrprintf ("%.*s.%.*s",
type_name_len, type_name,
$3.length, $3.ptr);
make_cleanup (xfree, name);
sym =
lookup_symbol (name, (const struct block *) NULL,
VAR_DOMAIN, NULL);
if (sym.symbol)
{
write_exp_elt_opcode (pstate, OP_VAR_VALUE);
write_exp_elt_block (pstate, sym.block);
write_exp_elt_sym (pstate, sym.symbol);
write_exp_elt_opcode (pstate, OP_VAR_VALUE);
break;
}
msymbol = lookup_bound_minimal_symbol (name);
if (msymbol.minsym != NULL)
write_exp_msymbol (pstate, msymbol);
else if (!have_full_symbols () && !have_partial_symbols ())
error (_("No symbol table is loaded. Use the \"file\" command."));
else
error (_("No symbol \"%s\" in current context."), name);
}
/* Check if the qualified name resolves as a member
of an aggregate or an enum type. */
if (!type_aggregate_p (type))
error (_("`%s' is not defined as an aggregate type."),
TYPE_SAFE_NAME (type));
write_exp_elt_opcode (pstate, OP_SCOPE);
write_exp_elt_type (pstate, type);
write_exp_string (pstate, $3);
write_exp_elt_opcode (pstate, OP_SCOPE);
}
| DOLLAR_VARIABLE
{ write_dollar_variable (pstate, $1); }
| NAME_OR_INT
{ YYSTYPE val;
parse_number (pstate, $1.ptr, $1.length, 0, &val);
write_exp_elt_opcode (pstate, OP_LONG);
write_exp_elt_type (pstate, val.typed_val_int.type);
write_exp_elt_longcst (pstate,
(LONGEST) val.typed_val_int.val);
write_exp_elt_opcode (pstate, OP_LONG); }
| NULL_KEYWORD
{ struct type *type = parse_d_type (pstate)->builtin_void;
type = lookup_pointer_type (type);
write_exp_elt_opcode (pstate, OP_LONG);
write_exp_elt_type (pstate, type);
write_exp_elt_longcst (pstate, (LONGEST) 0);
write_exp_elt_opcode (pstate, OP_LONG); }
| TRUE_KEYWORD
{ write_exp_elt_opcode (pstate, OP_BOOL);
write_exp_elt_longcst (pstate, (LONGEST) 1);
write_exp_elt_opcode (pstate, OP_BOOL); }
| FALSE_KEYWORD
{ write_exp_elt_opcode (pstate, OP_BOOL);
write_exp_elt_longcst (pstate, (LONGEST) 0);
write_exp_elt_opcode (pstate, OP_BOOL); }
| INTEGER_LITERAL
{ write_exp_elt_opcode (pstate, OP_LONG);
write_exp_elt_type (pstate, $1.type);
write_exp_elt_longcst (pstate, (LONGEST)($1.val));
write_exp_elt_opcode (pstate, OP_LONG); }
| FLOAT_LITERAL
{ write_exp_elt_opcode (pstate, OP_DOUBLE);
write_exp_elt_type (pstate, $1.type);
write_exp_elt_dblcst (pstate, $1.dval);
write_exp_elt_opcode (pstate, OP_DOUBLE); }
| CHARACTER_LITERAL
{ struct stoken_vector vec;
vec.len = 1;
vec.tokens = &$1;
write_exp_string_vector (pstate, $1.type, &vec); }
| StringExp
{ int i;
write_exp_string_vector (pstate, 0, &$1);
for (i = 0; i < $1.len; ++i)
free ($1.tokens[i].ptr);
free ($1.tokens); }
| ArrayLiteral
{ write_exp_elt_opcode (pstate, OP_ARRAY);
write_exp_elt_longcst (pstate, (LONGEST) 0);
write_exp_elt_longcst (pstate, (LONGEST) $1 - 1);
write_exp_elt_opcode (pstate, OP_ARRAY); }
;
ArrayLiteral:
'[' ArgumentList_opt ']'
{ $$ = arglist_len; }
;
IdentifierExp:
IDENTIFIER
;
StringExp:
STRING_LITERAL
{ /* We copy the string here, and not in the
lexer, to guarantee that we do not leak a
string. Note that we follow the
NUL-termination convention of the
lexer. */
struct typed_stoken *vec = XNEW (struct typed_stoken);
$$.len = 1;
$$.tokens = vec;
vec->type = $1.type;
vec->length = $1.length;
vec->ptr = malloc ($1.length + 1);
memcpy (vec->ptr, $1.ptr, $1.length + 1);
}
| StringExp STRING_LITERAL
{ /* Note that we NUL-terminate here, but just
for convenience. */
char *p;
++$$.len;
$$.tokens = realloc ($$.tokens,
$$.len * sizeof (struct typed_stoken));
p = malloc ($2.length + 1);
memcpy (p, $2.ptr, $2.length + 1);
$$.tokens[$$.len - 1].type = $2.type;
$$.tokens[$$.len - 1].length = $2.length;
$$.tokens[$$.len - 1].ptr = p;
}
;
TypeExp:
'(' TypeExp ')'
{ /* Do nothing. */ }
| BasicType
{ write_exp_elt_opcode (pstate, OP_TYPE);
write_exp_elt_type (pstate, $1);
write_exp_elt_opcode (pstate, OP_TYPE); }
| BasicType BasicType2
{ $$ = follow_types ($1);
write_exp_elt_opcode (pstate, OP_TYPE);
write_exp_elt_type (pstate, $$);
write_exp_elt_opcode (pstate, OP_TYPE);
}
;
BasicType2:
'*'
{ push_type (tp_pointer); }
| '*' BasicType2
{ push_type (tp_pointer); }
| '[' INTEGER_LITERAL ']'
{ push_type_int ($2.val);
push_type (tp_array); }
| '[' INTEGER_LITERAL ']' BasicType2
{ push_type_int ($2.val);
push_type (tp_array); }
;
BasicType:
TYPENAME
{ $$ = $1.type; }
;
%%
/* Return true if the type is aggregate-like. */
static int
type_aggregate_p (struct type *type)
{
return (TYPE_CODE (type) == TYPE_CODE_STRUCT
|| TYPE_CODE (type) == TYPE_CODE_UNION
|| (TYPE_CODE (type) == TYPE_CODE_ENUM
&& TYPE_DECLARED_CLASS (type)));
}
/* Take care of parsing a number (anything that starts with a digit).
Set yylval and return the token type; update lexptr.
LEN is the number of characters in it. */
/*** Needs some error checking for the float case ***/
static int
parse_number (struct parser_state *ps, const char *p,
int len, int parsed_float, YYSTYPE *putithere)
{
ULONGEST n = 0;
ULONGEST prevn = 0;
ULONGEST un;
int i = 0;
int c;
int base = input_radix;
int unsigned_p = 0;
int long_p = 0;
/* We have found a "L" or "U" suffix. */
int found_suffix = 0;
ULONGEST high_bit;
struct type *signed_type;
struct type *unsigned_type;
if (parsed_float)
{
const struct builtin_d_type *builtin_d_types;
const char *suffix;
int suffix_len;
char *s, *sp;
/* Strip out all embedded '_' before passing to parse_float. */
s = (char *) alloca (len + 1);
sp = s;
while (len-- > 0)
{
if (*p != '_')
*sp++ = *p;
p++;
}
*sp = '\0';
len = strlen (s);
if (! parse_float (s, len, &putithere->typed_val_float.dval, &suffix))
return ERROR;
suffix_len = s + len - suffix;
if (suffix_len == 0)
{
putithere->typed_val_float.type
= parse_d_type (ps)->builtin_double;
}
else if (suffix_len == 1)
{
/* Check suffix for `f', `l', or `i' (float, real, or idouble). */
if (tolower (*suffix) == 'f')
{
putithere->typed_val_float.type
= parse_d_type (ps)->builtin_float;
}
else if (tolower (*suffix) == 'l')
{
putithere->typed_val_float.type
= parse_d_type (ps)->builtin_real;
}
else if (tolower (*suffix) == 'i')
{
putithere->typed_val_float.type
= parse_d_type (ps)->builtin_idouble;
}
else
return ERROR;
}
else if (suffix_len == 2)
{
/* Check suffix for `fi' or `li' (ifloat or ireal). */
if (tolower (suffix[0]) == 'f' && tolower (suffix[1] == 'i'))
{
putithere->typed_val_float.type
= parse_d_type (ps)->builtin_ifloat;
}
else if (tolower (suffix[0]) == 'l' && tolower (suffix[1] == 'i'))
{
putithere->typed_val_float.type
= parse_d_type (ps)->builtin_ireal;
}
else
return ERROR;
}
else
return ERROR;
return FLOAT_LITERAL;
}
/* Handle base-switching prefixes 0x, 0b, 0 */
if (p[0] == '0')
switch (p[1])
{
case 'x':
case 'X':
if (len >= 3)
{
p += 2;
base = 16;
len -= 2;
}
break;
case 'b':
case 'B':
if (len >= 3)
{
p += 2;
base = 2;
len -= 2;
}
break;
default:
base = 8;
break;
}
while (len-- > 0)
{
c = *p++;
if (c == '_')
continue; /* Ignore embedded '_'. */
if (c >= 'A' && c <= 'Z')
c += 'a' - 'A';
if (c != 'l' && c != 'u')
n *= base;
if (c >= '0' && c <= '9')
{
if (found_suffix)
return ERROR;
n += i = c - '0';
}
else
{
if (base > 10 && c >= 'a' && c <= 'f')
{
if (found_suffix)
return ERROR;
n += i = c - 'a' + 10;
}
else if (c == 'l' && long_p == 0)
{
long_p = 1;
found_suffix = 1;
}
else if (c == 'u' && unsigned_p == 0)
{
unsigned_p = 1;
found_suffix = 1;
}
else
return ERROR; /* Char not a digit */
}
if (i >= base)
return ERROR; /* Invalid digit in this base. */
/* Portably test for integer overflow. */
if (c != 'l' && c != 'u')
{
ULONGEST n2 = prevn * base;
if ((n2 / base != prevn) || (n2 + i < prevn))
error (_("Numeric constant too large."));
}
prevn = n;
}
/* An integer constant is an int or a long. An L suffix forces it to
be long, and a U suffix forces it to be unsigned. To figure out
whether it fits, we shift it right and see whether anything remains.
Note that we can't shift sizeof (LONGEST) * HOST_CHAR_BIT bits or
more in one operation, because many compilers will warn about such a
shift (which always produces a zero result). To deal with the case
where it is we just always shift the value more than once, with fewer
bits each time. */
un = (ULONGEST) n >> 2;
if (long_p == 0 && (un >> 30) == 0)
{
high_bit = ((ULONGEST) 1) << 31;
signed_type = parse_d_type (ps)->builtin_int;
/* For decimal notation, keep the sign of the worked out type. */
if (base == 10 && !unsigned_p)
unsigned_type = parse_d_type (ps)->builtin_long;
else
unsigned_type = parse_d_type (ps)->builtin_uint;
}
else
{
int shift;
if (sizeof (ULONGEST) * HOST_CHAR_BIT < 64)
/* A long long does not fit in a LONGEST. */
shift = (sizeof (ULONGEST) * HOST_CHAR_BIT - 1);
else
shift = 63;
high_bit = (ULONGEST) 1 << shift;
signed_type = parse_d_type (ps)->builtin_long;
unsigned_type = parse_d_type (ps)->builtin_ulong;
}
putithere->typed_val_int.val = n;
/* If the high bit of the worked out type is set then this number
has to be unsigned_type. */
if (unsigned_p || (n & high_bit))
putithere->typed_val_int.type = unsigned_type;
else
putithere->typed_val_int.type = signed_type;
return INTEGER_LITERAL;
}
/* Temporary obstack used for holding strings. */
static struct obstack tempbuf;
static int tempbuf_init;
/* Parse a string or character literal from TOKPTR. The string or
character may be wide or unicode. *OUTPTR is set to just after the
end of the literal in the input string. The resulting token is
stored in VALUE. This returns a token value, either STRING or
CHAR, depending on what was parsed. *HOST_CHARS is set to the
number of host characters in the literal. */
static int
parse_string_or_char (const char *tokptr, const char **outptr,
struct typed_stoken *value, int *host_chars)
{
int quote;
/* Build the gdb internal form of the input string in tempbuf. Note
that the buffer is null byte terminated *only* for the
convenience of debugging gdb itself and printing the buffer
contents when the buffer contains no embedded nulls. Gdb does
not depend upon the buffer being null byte terminated, it uses
the length string instead. This allows gdb to handle C strings
(as well as strings in other languages) with embedded null
bytes */
if (!tempbuf_init)
tempbuf_init = 1;
else
obstack_free (&tempbuf, NULL);
obstack_init (&tempbuf);
/* Skip the quote. */
quote = *tokptr;
++tokptr;
*host_chars = 0;
while (*tokptr)
{
char c = *tokptr;
if (c == '\\')
{
++tokptr;
*host_chars += c_parse_escape (&tokptr, &tempbuf);
}
else if (c == quote)
break;
else
{
obstack_1grow (&tempbuf, c);
++tokptr;
/* FIXME: this does the wrong thing with multi-byte host
characters. We could use mbrlen here, but that would
make "set host-charset" a bit less useful. */
++*host_chars;
}
}
if (*tokptr != quote)
{
if (quote == '"' || quote == '`')
error (_("Unterminated string in expression."));
else
error (_("Unmatched single quote."));
}
++tokptr;
/* FIXME: should instead use own language string_type enum
and handle D-specific string suffixes here. */
if (quote == '\'')
value->type = C_CHAR;