How to get tag content (encoding.xml) ?

[ginimod]

Hello,
I'm stuck ,i'm totally noob in V
i can't access the content of the tags with encoding.xml

8971

for fiche in doc.root.get_elements_by_tag("fiche") {
nid_fiche := fiche.get_elements_by_tag("id_fiche")
val := nid_fiche[0].children[0]
print("IDFiche ${val}")
}

i get
IDFiche xml.XMLNodeContents('8971')
but i cant acces the content with .text or .content
and it's driving me crazy.

[jorgeluismireles]

One can learn a lot by studying the library tests codes:

https://github.com/vlang/v/tree/master/vlib/encoding/xml/test/local

You can also provide your data file and code to get an idea of the problem.

[jorgeluismireles]

I think what you get still is a sum type.

Assume this is you xml:

<?xml version="1.0" encoding="UTF-8"?>
<fiche>
 <id_fiche>8971</id_fiche>
</fiche>

Then we parse the file until last node then do a match type string to get the number 8971:

import encoding.xml

doc := xml.XMLDocument.from_string('
<?xml version="1.0" encoding="UTF-8"?>
<fiche>
 <id_fiche>8971</id_fiche>
</fiche>')!

for fiche in doc.root.get_elements_by_tag("fiche") {
	nid_fiche := fiche.get_elements_by_tag("id_fiche")
	val := nid_fiche[0].children[0]
	println("sum type yet: ${val}") // sum type yet...
	match val {
		string {
			println('particular string type: ${val}') // string value
		}
		else { // else is mandatory to exhaust the sum type (the rest of other 3 types)
			
		}
	}
}

Result:

sum type yet: xml.XMLNodeContents('8971')
particular string type: 8971

Acording to the docs, children are of these four types:

pub type XMLNodeContents = XMLCData | XMLComment | XMLNode | string

You can find the code above here:

https://play.vlang.io/p/f690e2db6d

There you can test small codes within your browser, edit, click Run, click Share and paste the link.

[ginimod]

Salut,

Merci beaucoup !

for fiche in doc.root.get_elements_by_tag("fiche") {
 nid_fiche := fiche.get_elements_by_tag("id_fiche")
 val := nid_fiche[0].children[0]
 println("Val  : ${val}")
 println("type_name : ${val.type_name()}") // sum type yet...
match val {
 string {
  println('Node : ${nid_fiche[0].children[0]}')
   println('particular string type: ${val}') // string value
 }
else {}
}
}

Retour

Val  : xml.XMLNodeContents('8971')
type_name : string
Node : xml.XMLNodeContents('8971')
particular string type: 8971

So many question ?
match not only match but force the variable to act like a string but it's get a string type .
Okay maybe with the first println, i acces the container a xml.XMLNodeContents that containe a string so the match freeze (transtype) the behavior of a string et voilà !

for fiche in doc.root.get_elements_by_tag("fiche") {
 nid_fiche := fiche.get_elements_by_tag("id_fiche")
 val := nid_fiche[0].children[0]
 println("Val  : ${val}")
 println("type_name : ${val.type_name()}") // sum type yet...
 match nid_fiche[0].children[0] {
 string {
  println('Node : ${nid_fiche[0].children[0]}')
  println('particular string type: ${val}') // string value
 }
 else {}
}
}

retour

Val  : xml.XMLNodeContents('8971')
type_name : string
Node : xml.XMLNodeContents('8971')
particular string type: xml.XMLNodeContents('8971')

in this case i can't transtype nid_fiche[0].children[0] in string

Thank's a lot 4 your help !

[jorgeluismireles]

Yes, match forces the variable to become other type inside the block. We programmers can't shadow variables, but V says hold my beer, I can. Look how you can separate strings from comments. And since a comment have a field named text you can use c.text to get the value.

import encoding.xml

doc := xml.XMLDocument.from_string('
<?xml version="1.0" encoding="UTF-8"?>
<fiche>
 <id_fiche>8971</id_fiche>
 <id_fiche><!--This is a comment-->8972</id_fiche>
</fiche>')!

for fiche in doc.root.get_elements_by_tag("fiche") {
	nid_fiche := fiche.get_elements_by_tag("id_fiche")
	for f in nid_fiche {
		for c in f.children {
			match c {
				string { println('string: ${c}') }
				xml.XMLComment { println('comment: ${c.text}')}
				else { }
			}
		}
	}
}

Result:

string: 8971
comment: This is a comment
string: 8972

[ginimod]

waouh ! nice touch ...
I come from Python so I have to learn the subtleties
Thank's again