String and regex replacements

[Brixy]

Hi folks,

I have rewritten all my javascript files from Deno to V, and it's been a breeze!

The only thing I am struggling with is a combination of a string + regex replacements for a sanitizing function.

function sanitize(query) {
	let sanitized = query
		.replaceAll('ä', 'ae') // example for string replacement
		.replace(/[^\w.]+/g, '-') // example for regex replacement
	return sanitized;
}

What is the best way to do this in V. In the original script there are a dozen replacements.

Thank you very much!

[medvednikov]

Glad you enjoy it!

@penguindark what would be the best way to do this?

[penguindark]

@Brixy I'm supposing that \g is the global flag form PHP regex, then a possible code can be:

import regex
fn sanitize(query string) string {
	mut re_sanitize := regex.regex_opt(r'[^\w.]+') or { panic(0) }
	return re_sanitize.replace(query.replace('ä', 'ae'), '-')
}

fn main() {
	println(sanitize("bäest everum.bat gones_cedum.jpg poster@conen # pero^märcio"))
}
// Output: baeest-everum-gones_cedum-poster-conen-pero-maercio

This code is only an example, it can be optimized better, anyway I'm not sure that regex is the
right solution for this task.

[Brixy]

Excellent, guys. Thanks a lot. Now everything is running perfectly.

One more question.

It’s easily possible to chain

query.to_lower().replace('ä', 'ae').replace('ü', 'ue')

Is something similar possible with the regex library (similar to chaining .replace(/…/g) in JS), or would you use regex.regex_opt() multiple times?

Glad you enjoy it!

Just loving V! Congratulations and all the best to you all and V, @medvednikov.

[penguindark]

I'll answer in two points:

• Chaining: Yes, you ca chain call to replace like: query.to_lower().replace('ä', 'ae').replace('ü', 'ue')
• Regex: No, you can not chain regex, at least at the present time, in future may be.

About regex, it is a "small" interpreter that run in your program, it needs to compile your query before execute it.
Thus it need all the regex_opt stuff.
Have it inside the function is a waste of cpu because it will compile the query every call to the function.
V has not globals, to overcome the problem you can pass a "context" to your function where there are the compiled regex query.
Anyway i suggest you to replace the regex query '[^\w.]+' with a more simple function that replace the chars, it will increase your speed a lot.
For example:

fn my_replace(in_txt string, repl_ch u8) string {
	mut buf := []u8{cap:in_txt.len + 1} // buffer for the new string
	mut match_seq := 0 // match sequence counter
	for ch in in_txt {
		// Equivalent of [^\w.]
		if (ch >=`a` && ch <=`z`) || (ch >=`A` && ch <=`Z`) || ch == `_` || ch == `.` {
			if match_seq > 0 {
				//  insert a replacement char
				buf << repl_ch
				match_seq = 0
			}
			buf << ch
			continue
		}
		match_seq++
	}
	// If the we are in a match_sequence insert a replacement char
	if match_seq > 0 {
		buf << repl_ch
	}
	buf << 0 // C stringterminator 0
	
	return unsafe{cstring_to_vstring(buf.data)}
}

This function is very fast then regex and do the same job of your query in an imperative way.

[Brixy]

Excellent. Thank you very much!

Ad hoc I'm not quite sure what repl_ch exactly does, but I'll find out.

Thank you!