Two keyboard matrix

[Romek1234]

Thanks to Pieter P. for a wonderful library, for the great contribution of your work!

I have this problem - I would like to add a second matrix keyboard but sending MIDI messages on a different channel.
The following code is for one keyboard:

#include <Control_Surface.h>
 
//USBMIDI_Interface midi;
 
// The note numbers corresponding to the buttons in the matrix
const AddressMatrix<4, 8> addresses = {{
  {  36,  37,  38, 39, 40, 41, 42, 43 },
  {  44,  45,  46, 47, 48, 49, 50, 51 },
  {  52,  53,  54, 55, 56, 57, 58, 59 },
  {  60,  61,  62, 63, 64, 65, 66, 67 },
}};
 
NoteButtonMatrix<4, 8> buttonmatrix = {
  {A0, A1, A2, A3}, // row pins
  {3, 4, 5, 6, 7, 8, 9, 10},    // column pins
  addresses,    // address matrix
  CHANNEL_1,    // channel and cable number
};
 
void setup() {
  Control_Surface.begin();
}
 
void loop() {
  Control_Surface.loop();
}

I added a second keyboard using the code from the Controller.h library but unfortunately it doesn't work. It does not send any MIDI messages. Can it be done and how it can be done in Control_Surface.h library?
Thanks in advance!

Here is an old broken code:

#include <Controller.h>

/*
The diodes conduct towards the pins A0, A1...

This is an example code of the "ButtonMatrix" class of the MIDI_controller library
in
https://github.com/tttapa/MIDI_controller
Thanks Pieter P.
*/

#include "MIDI_Controller.h" // Include the library

const uint8_t velocity = 0b1111111; // Maximum velocity (0b1111111 = 0x7F = 127)
const uint8_t addresses1[2][2] = {   // 4 wiersze 8 kolumn the note numbers corresponding to the buttons in the matrix

  { 58, 59 },
  { 66, 67 }
  
};
const uint8_t addresses[4][8] = {   // 4 wiersze 8 kolumn the note numbers corresponding to the buttons in the matrix
  {  36,  37,  38, 39, 40, 41, 42, 43 },
  {  44,  45,  46, 47, 48, 49, 50, 51 },
  {  52,  53,  54, 55, 56, 57, 58, 59 },
  {  60,  61,  62, 63, 64, 65, 66, 67 }
};

// Create a new instance of the class 'ButtonMatrix', called 'buttonmatrix', with dimensions 4 rows and 3 columns, with the rows connected to pins 2, 3, 4 and 5
// and the columns connected to pins 6, 7 and 8, that sends MIDI messages with the notes specified in 'addresses' on MIDI channel 1, with velocity 127
ButtonMatrix<4, 8> buttonmatrix( {A0, A1, A2, A3}, {3, 4, 5, 6, 7, 8, 9, 10}, addresses, 2, velocity);
ButtonMatrix<2, 2> buttonmatrix1( {A4, A5}, {11, 12}, addresses1, 1, velocity);
void setup() {}

void loop() {
  // Refresh the buttons (check whether the states have changed since last time, if so, send it over MIDI)
  MIDI_Controller.refresh();
}

[tttapa]

At least one problem with your Control Surface code is that you commented out the MIDI interface. If you don't define any MIDI interfaces, Control_Surface.begin() will fail.

Instantiating more than one button matrices should not be an issue.

[Romek1234]

Thank you so much Pieter P.
Now my code for one matrix - looks like this and it works:

#include <Control_Surface.h>
 
//USBMIDI_Interface midi;
HardwareSerialMIDI_Interface serialmidi = {Serial, MIDI_BAUD};
// The note numbers corresponding to the buttons in the matrix
const AddressMatrix<4, 8> addresses = {{
   {  36,  37,  38, 39, 40, 41, 42, 43 },
  {  44,  45,  46, 47, 48, 49, 50, 51 },
  {  52,  53,  54, 55, 56, 57, 58, 59 },
  {  60,  61,  62, 63, 64, 65, 66, 67 },
}};
 
NoteButtonMatrix<4, 8> buttonmatrix = {
  {A0, A1, A2, A3}, // row pins
  {3, 4, 5, 6, 7, 8, 9, 10},    // column pins
  addresses,    // address matrix
  CHANNEL_1,    // channel and cable number
};
 
void setup() {
  Control_Surface.begin();
}
 
void loop() {
  Control_Surface.loop();
}

I still don't know how to instantiate more than one button matrix.
I have tried so, but it doesn't compile for arduino Nano:

#include <Control_Surface.h>
 
//USBMIDI_Interface midi;
HardwareSerialMIDI_Interface serialmidi = {Serial, MIDI_BAUD};
// The note numbers corresponding to the buttons in the matrix
const AddressMatrix<4, 8> addresses = {{
  {  36,  37,  38, 39, 40, 41, 42, 43 },
  {  44,  45,  46, 47, 48, 49, 50, 51 },
  {  52,  53,  54, 55, 56, 57, 58, 59 },
  {  60,  61,  62, 63, 64, 65, 66, 67 },
}};

 const AddressMatrix1<2, 2> addresses1 = {{
  {  36,  37 },
  {  44,  45 },

}};

NoteButtonMatrix<4, 8> buttonmatrix = {
  {A0, A1, A2, A3}, // row pins
  {3, 4, 5, 6, 7, 8, 9, 10},    // column pins
  addresses,    // address matrix
  CHANNEL_1,    // channel and cable number
};

NoteButtonMatrix<2, 2> buttonmatrix1 = {
  {A4, A5}, // row pins
  {11, 12},    // column pins
  addresses1,    // address matrix
  CHANNEL_2,    // channel and cable number
}; 
void setup() {
  Control_Surface.begin();
}
 
void loop() {
  Control_Surface.loop();
}

[tttapa]

I'd highly recommend following a C++ tutorial first.

AddressMatrix is a type provided by the Control Surface library. AddressMatrix1 does not exist.

Try this instead:

const AddressMatrix<2, 2> addresses1 {{
  ... 
}};

This is a variable declaration of a variable of type const AddressMatrix<2, 2> with name addresses1. You can pick whatever name you want (as long as it's a valid C++ identifier), but the data type has to be correct, it must be an existing data type.

[Romek1234]

Thanks!
You've helped me a lot. Pieter P. Thanks again.

Ps. that I did not find this error myself. But it's all working now!