backtalk/shared.gradle at master · trypsynth/backtalk · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
// For building the open-source release of TalkBack.

// Kotlin 2 compiles Compose through this compiler plugin instead of composeOptions.
apply plugin: 'org.jetbrains.kotlin.plugin.compose'

// With -PtestBuild, the app is fyi.quin.backtalk.test, named Backtalk Test, so that a build under
// test installs next to the usual one, with its own key and settings.
def testBuild = project.hasProperty('testBuild')

ext {
    talkbackApplicationId = testBuild ? "fyi.quin.backtalk.test" : "fyi.quin.backtalk"
}

android {
    compileSdk = 37
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }
    defaultConfig {
        vectorDrawables.useSupportLibrary = true
        multiDexEnabled = true
        minSdk = 26
        ndk {
            // x86_64 for emulators on Intel and AMD computers, such as Windows PCs,
            // whose plain Android images can't run ARM code.
            abiFilters "armeabi-v7a", "arm64-v8a", "x86_64"
        }
        // We generate a build config field holding the application ID so that
        // Java code can reference it.
        buildConfigField "String", "APPLICATION_ID", "\"" + talkbackApplicationId + "\""
        // We generate a string resource holding the application ID so that XML
        // resources can reference it.
        resValue "string", "app_id", talkbackApplicationId
    }
    flavorDimensions = ["target"]
    productFlavors {
        phone {
            dimension = "target"
        }
        wear {
            dimension = "target"
        }
    }
    buildFeatures {
        buildConfig = true
        compose = true
        resValues = true
    }
}

dependencies {

    // Google common
    // Text recognition is compiled against here and packaged by the app, which chooses the model in
    // Google Play services or the one built into the APK. The two have the same API.
    compileOnly libs.mlkit.text.recognition
    testImplementation libs.mlkit.text.recognition
    implementation libs.material

    // Support library
    implementation libs.androidx.annotation
    implementation libs.androidx.appcompat
    implementation libs.androidx.collection
    implementation libs.androidx.core
    implementation libs.androidx.core.i18n
    implementation libs.androidx.fragment
    implementation libs.androidx.lifecycle.service
    implementation libs.androidx.savedstate
    implementation libs.androidx.localbroadcastmanager
    implementation libs.androidx.preference
    implementation libs.androidx.recyclerview
    implementation libs.androidx.viewpager2

    // Guava and annotations used directly by the sources
    implementation libs.guava
    implementation libs.checker.qual
    implementation libs.errorprone.annotations

    // Auto-value
    implementation libs.auto.value.annotations
    annotationProcessor libs.auto.value
    implementation libs.javax.annotation.api

    // Wear
    implementation libs.androidx.wear
    implementation libs.androidx.wear.remote.interactions
    implementation libs.wearable.support
    implementation libs.zxing.core

    // Cloud services
    implementation libs.volley

    // Compose libraries for all form factors
    implementation libs.androidx.activity
    implementation libs.androidx.activity.compose
    implementation libs.compose.runtime
    implementation libs.compose.runtime.livedata
    implementation libs.compose.ui
    implementation libs.wear.compose.foundation
    implementation libs.wear.compose.material3
    implementation libs.compose.material.icons.core

    // Gemineye
    implementation libs.gson
    implementation libs.protobuf.javalite
    implementation libs.flexbox

    // Apache
    implementation libs.commons.text

}