forked from apertium/apertium-kaz
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathapertium-kaz.kaz.rlx
1645 lines (1207 loc) · 43.7 KB
/
apertium-kaz.kaz.rlx
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
# ============================================================================ #
# A COMMENTARY ON FORMATTING OF MAJORITY OF RULES
# (read: a wannabe FORMATTING GUIDELINES)
# ============================================================================ #
# Lines do not exceed 79 characters.
#
# Rule layout
# ===========
#
# There are two alternative layouts for writing a rule. An example for the
# first one (of course the body of the rule won't be commented out):
#
# # INPUT: ^терістік/тер<v><tv><coop><ifi><p1><pl>/терістік<n><attr>/
# # терістік<n><nom>$ ^бетіндегі/бет<n><px3sp><loc><attr>/
# # бет<n><px3sp><loc><subst><nom>/$
# # OUTPUT: [0]^терістік/терістік<n><attr>/терістік<n><nom>$
# ^бетіндегі/бет<n><px3sp><loc><attr>...$
# REMOVE V IF
# (0 PRE-N)
# (1C N)
# ;
# # any additional comments here (if necessary)
#
# An abstract example of the second layout:
#
# # An explanation of what the rule does (if it's not obvious from
# # code!), a name or any other comment that clarifies its purpose
# SELECT ABC IF
# (0 DEF)
# (1 GHI)
# ;
# ## A sentence with the [0]form the rule was written for.
# ## (!) A corner-case-sentence: the rule mispredicted on it initially
# ## but was modified accordingly (additional constraints etc.); or the
# ## rule still mispredicts on it, but this kind of sentences aren't
# ## that frequent. (Alternatively, place the corner-case sentence on
# ## the same line as the additional constraint).
#
# The first layout is more appropriate when you come up with a rule inductively
# (i.e. you see a sentence badly translated because of errors in disambiguation
# and want to fix it), the second one when you arrived at it deductively. E.g:
#
# # Participle appears immediately before a verb (verbal adverb doesn't)
# REMOVE Participle IF
# (NOT 1C V OR Vaux)
# ;
# ## Есік [0]ашып, ол үйге кірді.
#
# In context of apertium-kaz, the difference between a participle and a verbal
# adverb is that participle immediately precedes a verb and verbal adverb
# doesn't. We know this even without looking at tests, but it is a good idea
# to back up the rule with a test case.
#
# Sometimes you can't fully disambiguate a form with only one rule. In that
# case, several rules dealing with the same thing can be grouped together:
#
# # What the rule does?
# SELECT ABC IF
# (0 DEF)
# (1 KLM)
# ;
# REMOVE XYZ IF
# (0 DEF)
# (1 NOP)
# (2 QRS)
# ;
# ## Example sentences for both of the rules.
# ## Another example sentence.
#
# Where a rule is placed?
# =======================
# Any context involved?
# / \
# YES NO
# / \
# Disambiguates a particular wordform? "Heuristics" section
# / \ at the end of the file
# YES NO
# / \
# "Wordform/lemma specific rules" Readings of
# section different POS?
# / \
# YES NO
# / \
# "POS marking" \
# at the beginning \
# Corresponding section
# ("Verbs", "Adjectives" etc.)
# ============================ #
# END OF FORMATTING GUIDELINES #
# ============================ #
# ========== #
# Delimiters #
# ========== #
DELIMITERS = "<.>" "<!>" "<?>" "<...>" "<¶>";
SOFT-DELIMITERS = "<,>" ;
SUBREADINGS = LTR ; # Alternate, left-to-right (main reading on the left)
# ============= #
# Tags and sets #
# ============= #
SETS
LIST BOS = (>>>) ;
LIST EOS = (<<<) ;
# First-level/Parts-of-speech tags
# ================================
LIST A = adj ;
LIST Adv = adv ;
LIST Pron = prn ;
LIST Pron-Pers = (prn pers) ;
LIST N = n ;
LIST IJ = ij ;
LIST Prop = np ;
LIST V = v ;
LIST Vaux = vaux ;
LIST Cop = cop ;
LIST Det = det ;
LIST CC = cnjcoo ;
LIST CS = cnjsub ;
LIST Interj = ij ;
LIST Pres = pres ;
LIST Num = num ;
LIST Post = post ;
LIST Postadv = postadv ;
LIST FinalClitic = mod_ass mod_emo mod qst emph ;
LIST Sent = sent ;
LIST Cm = cm ;
LIST Adv = adv ;
LIST Rquot = rquot ;
LIST Excl = "!" ;
LIST Guio = guio ;
# POS sub-categories
# ==================
LIST Pers = pers ;
LIST Interr = itg ;
LIST Dem = dem ;
LIST IV = iv ;
LIST TV = tv ;
LIST Pass = pass ;
LIST Caus = caus ;
LIST Coop = coop ;
LIST ORD = ord ;
# "Syntactic" tags
# ================
LIST Advl = advl ;
LIST Attr = attr ;
LIST Subst = subst ;
LIST N-LIKE = subst n np prn ; # Actually, see NOMINAL
# Morphosyntactic properties # if you find yourself embracing the same tag in
# ========================== # brackets over and over again, you may want to
# add it here
LIST Sg = sg ;
LIST Pl = pl ;
LIST Nom = nom ;
LIST Gen = gen ;
LIST Dat = dat ;
LIST Acc = acc ;
LIST Abl = abl ;
LIST Loc = loc ;
LIST Ins = ins ;
LIST P1 = p1 ;
LIST P2 = p2 ;
LIST P3 = p3 ;
LIST PersonalPossessives = px1sg px2sg px3sp px1pl px2pl ;
LIST Imp = imp ;
# Specific lexemes
# ==========================
LIST Year = "жылғы"i "жыл"i ;
LIST Colon = ":" ;
LIST Qayda = "қайда"i ;
LIST MONTH = "қаңтар"i "ақпан"i "наурыз"i "сәуір"i "мамыр"i "маусым"i "шілде"i "тамыз"i "қыркүйек"i "қазан"i "қараша"i "желтоқсан"i ;
LIST QUANTITY = "есе"i "пайыз"i ;
# Noun sets
# ==============
SET NGDAALI = Nom | Dat | Dat | Acc | Abl | Loc | Ins ;
# Adjective sets
# ==============
LIST A/Advl = (adj advl) ;
LIST A/Subst = (adj subst nom) ;
SET A1-Nom = A/Advl | A/Subst ;
# Verb sets
# =========
LIST FiniteVerb = pres aor past ifi ifi_evid fut fut_plan imp opt pih ;
LIST V-P3 = (v p3) (vaux p3) (cop p3) ;
LIST Gerund = ger ger_ppot ger_past ger_perf ger_impf ger_abs ;
SET V-NotGerund = V - Gerund ;
LIST Participle = prc_perf prc_impf prc_cond prc_vol prc_plan ;
LIST Prc-vol = prc_vol ;
LIST VerbalAdverb = gna_perf gna_cond gna_until gna_after ;
LIST VerbalAdjective = gpr_past gpr_fut gpr_pot gpr_impf ;
LIST FourAuxiliaries = "тұр" "жүр" "отыр" "жат" ;
LIST V-IV = (v iv) ;
LIST V-TV = (v tv) ;
LIST Err/Orth = err_orth ;
# All possible word categories
# ============================
SET WORD = N | V | A | Post | Postadv | Pron | Det | Adv | CC | CS | Interj |
Num | ("\?") ;
SET PRE-N = A | Det | Postadv | Num | (n gen) | (prn gen) | CC | (attr) ;
SET MARK = Cm | ("\\") | ("\;") | ("\(") ;
SET WORDMARK = WORD | MARK ;
SET N-MOD = A | Det | Num | (n gen) | (prn gen) ;
SET ADJ-MOD = Postadv | Adv ;
SET NPMARK = N-MOD | ADJ-MOD ;
SET NOMINAL = N | Prop | Pron | Subst | Gerund ;
# Categories which cannot be part of a noun phrase
# ================================================
SET NPNH = WORDMARK - PRE-N ;
SET NPNHA = WORDMARK - PRE-N - Adv ;
SET NOT-ADV = WORDMARK - Adv ;
# Barriers
# ========
SET S-BOUNDARY = CS | Interr | EOS ;
# Universal Dependencies
# ======================
LIST @root = @root ; # The root of the sentence, often a finite verb
LIST @nsubj = @nsubj ; # The nominal subject of the sentence
LIST @amod = @amod ; #
LIST @advmod = @advmod ; # An adverbial modifier
LIST @case = @case ; # The relation of an adposition to its head
LIST @acl = @acl ; # A clause which modifies a nominal
LIST @nmod = @nmod ; # Nominal modifier
LIST @dobj = @dobj ; # The direct object of the sentence
LIST @punct = @punct ; # Any punctuation
LIST @cop = @cop ; #
LIST @nmod:poss = @nmod:poss ;
LIST @obl = @obl ;
LIST @obj = @obj ;
LIST @advcl = @advcl ;
LIST @aux = @aux ;
LIST @parataxis = @parataxis ;
LIST @det = @det ;
LIST @csubj = @csubj ;
LIST @nummod = @nummod ;
LIST @dep = @dep ; # Any remaining dependency
# ======= #
SECTION # repair
# ======= #
REMOVE SUB:1 Err/Orth ;
REMOVE Err/Orth ;
SELECT (pass) IF (0 ("жоспарлан")) ;
"<ерекше>"i REMOVE (equ) ;
# ======= #
SECTION # (COPULAS)
# ======= #
#
"<кейін>" SELECT Post IF
(-1 Abl)
;
## 23. Айгүл санап біткеннен кейін айналасына қарады.
# INPUT: ^оның/ол<prn><dem><gen>/он<num><subst><px2sg><nom>/
# ол<prn><pers><p3><sg><gen>$ ^үйі/үй<n><px3sp><nom>$
# OUTPUT: [0]^ол<prn><pers><p3><sg><gen>$ ^үй<n><px3sp><nom>$
SELECT Pron-Pers IF
(0 ("<оның>"i))
(1 (n px3sp nom))
;
REMOVE SUB:1 Cop IF
(NOT 1 EOS OR MARK OR ("де"))
;
REMOVE SUB:1 Cop IF
(-1 BOS OR MARK) ## Headings or enumerations
(NOT 1 EOS)
;
##
## Example: handle 'орында' in
## Қазақстанның басқа қалаларымен салыстырғанда тұрғыны жөнінен 3-ші орында ( Алматы мен Астанадан кейін ) .
SELECT SUB:1 Cop IF
(1 (lpar))
(2* (rpar) BARRIER EOS)
(NOT -1 Colon)
;
#
SELECT SUB:1 Cop IF
(1 MARK)
(2*/1 Cop BARRIER EOS)
(NOT 0 Interj) ## Дұрыс, оның мысығы бар.
(NOT 0 FiniteVerb) ## 74 ... барлығы 53 ел [0]қатысты.
(NOT 2 N)
;
## Жоқ, Айгүлдің күшігі [0]жоқ, оның мысығы [0]бар.
SELECT SUB:1 Cop IF
(1 EOS)
(NOT 0 V OR Vaux)
;
# ======= #
SECTION
# ======= #
# POS marking
# ===========
REMOVE A IF
(0 ("қол"i))
(1 ("жу"i))
;
"<қандай>" REMOVE N ;
SELECT N IF
(0 ("сурет"i))
(-1 (adj advl) OR Det OR A)
;
#INPUT: ^Сіздің/сіз<prn><pers><p2><sg><frm><gen>$ ^атыңыз/ат<v><tv><imp><p2><frm><sg>/ат<n><px2sg><frm><nom>/ат<n><px2sg><frm><nom>+е<cop><aor><p3><pl>/ат<n><px2sg><frm><nom>+е<cop><aor><p3><sg>$ ^кім/кім<det><itg>/кім<prn><itg><nom>/кім<prn><itg><nom>+е<cop><aor><p3><pl>/кім<prn><itg><nom>+е<cop><aor><p3><sg>$^?/?<sent>$^./.<sent>$
#OUPUT: ^Сіздің/сіз<prn><pers><p2><sg><frm><gen>$ ^атыңыз/ат<n><px2sg><frm><nom>$ ^кім/кім<det><itg>$^?/?<sent>$^./.<sent>$
SELECT N IF
(0 ("ат"i))
(-1 (prn pers))
;
# This rule is too general, breaks a few things.Corrected
#INPUT: ^әдемі/әдемі<adj>
#^жер/же<v><tv><gpr_fut>/жер<n><nom>/жер<n><attr>/же<v><tv><fut><p3><pl>/же<v><tv><fut><p3><sg>/же<v><tv><gpr_fut><subst><nom>/жер<v><iv><imp><p2><sg>/жер<v><tv><imp><p2><sg>/жер<n><nom>+е<cop><aor><p3><pl>/жер<n><nom>+е<cop><aor><p3><sg>$
#OUPUT: ^әдемі/әдемі<adj>
#^жер/жер<n><nom>$
SELECT N IF
(0 ("жер"))
(-1 A)
;
# INPUT: for examle: "ата келді" translated as "grandfather come"
SELECT N IF
(0 ("ата"))
( (NOT -1 N) OR (NOT -1 BOS))
( (NOT -1 (Nacc)) OR (NOT -1 BOS))
;
# INPUT: for examle: "Мен жазуым мүмкін" translated as "I may write"
# SELECT V IF
# (-1 Pron-Pers)
# (NOT 0 ("сол"))
#;
#
# this rule fails several times when tested against puupankki corpus
#INPUT: ^ластай/лас<n><sim>/лас<adj><subst><sim>/ласта<v><tv><prc_impf>$ ^аласың/ал<vaux><aor><p2><sg>/ал<v><tv><aor><p2><sg>/ала<adj>+е<cop><aor><p2><sg>/ала<adj><subst><nom>+е<cop><aor><p2><sg>$
#OUTPUT:^ластай/ласта<v><tv><prc_impf>$ ^аласың/ал<vaux><aor><p2><sg>
SELECT Participle IF (1 Vaux)
;
# INPUT: "жүз теңге" translated as "hundred coins", екі жүз адам "two handred people"
#"адамдардың жүзі" translated a "face of people"
# ^жүз/жүз<num>/жүз<n><nom>/жүз<n><attr>/жүз<num><subst><nom>/жүз<v><iv><imp><p2><sg>/жүз<n><nom>+е<cop><aor><p3><pl>/жүз<n><nom>+е<cop><aor><p3><sg>/жүз<num><subst><nom>+е<cop><aor><p3><pl>/жүз<num><subst><nom>+е<cop><aor><p3><sg>$^
SELECT Num IF
((0 Num) OR (-1 ))
(1 N)
(NOT 0 ("бірге"))
(NOT -1 A)
(NOT 0 ("бір"))
(NOT 0 ("ол"))
(NOT 0 ("біреу"))
(NOT 0 ("үшін"))
;
#
# exceptions are added to handle e.g. 'мысығымен бірге үйде отыр', 'ол бір дыбысты естиді', 'үлкен бір ағаш'
REMOVE SUB:1 FinalClitic IF
(NOT 1 EOS)
;
## Балықшы бұл ақшаға үй тұрғызды.
SELECT FiniteVerb IF
(1 EOS OR ("де"i)) # FIXME s/.*/SentenceBoundary/
(NOT 0 ("шығар"i) OR ("бар"i)) # FIXME a better way?
(NOT 0/1 Cop)
;
## (!) 40 . Мүмкін бұл Азамат [0]шығар?
## (!) 13 . Жоқ, Айгүлдің күшігі жоқ, оның мысығы [0]бар.
## Мағынасы төңкеріліп [0]кетті деп ойламағаным үшін ғафу етіңіз.
#
SELECT Interj OR (cnjadv) IF
(-1 BOS)
(1 Cm)
;
## "Мысалы, ежелгі заманның өзінде Арал теңізі көп елдерге мәлім болған."
# INPUT: ^Мен/Мен<cnjcoo>/Мен<post>/Мен<prn><pers><p1><sg><nom>$
# ^қазақпын/қазақ<n><nom>+е<cop><p1><sg>$
# OUTPUT: [0]^Мен/Мен<cnjcoo>/Мен<prn><pers><p1><sg><nom>$
# ^қазақпын/қазақ<n><nom>+е<cop><p1><sg>$
REMOVE Post IF
(NOT -1 NOMINAL)
(NOT -1 ("\*.+"r))
;
#
# An adjective ending with -LI is ambiguous with: 1) a noun or adjective in
# accusative, and 2) with a verb in <ifi> form.
REMOVE Acc IF
(0 (n acc) OR (adj subst nom))
(0 A)
(NOT 1 V)
;
REMOVE V IF
(0 A)
(0 (ifi))
(NOT 1 EOS OR Cm)
;
SELECT A IF
(-1 ("аса"i) OR ("өте"i))
(0 A)
(0 (n acc))
;
# Proper noun or not?
SELECT Prop IF
(0 ("[:upper:]+[:lower:]*"r))
(NOT -1 BOS)
(NOT 0 ("Кеңес"))
(NOT 0 ("Отан"))
(NOT 0 ("сен"))
;
## 108. Өйткені бүгінгі [0]Арал деген атау сол XVII ғасырдан бергі жерге берілген.
SELECT Prop IF
(0 Prop)
(0 ("<[:upper:][:upper:]+>"r))
;
## [0]АЗАМАТ ҚАЙДА?
SELECT Prop IF
(1 ("мен") + Post)
(2 Prop)
;
## [0]Азамат пен Айгүл бақшада.
### : for "Алма мен Аян"-cnjcoo
SELECT CC IF (-1 N)(0 CC)(1 N);
### : for "қысқа ай"-adj
SELECT A IF (0 N + Dat)(1 N );
#
SELECT Pron IF
(0C Det OR Pron)
(1C Adv)
;
## 44 . [0]Ол енді ол дыбысты анығырақ ести бастады.
# INPUT: ^терістік/тер<v><tv><coop><ifi><p1><pl>/терістік<n><attr>/
# терістік<n><nom>$ ^бетіндегі/бет<n><px3sp><loc><attr>/
# бет<n><px3sp><loc><subst><nom>/$
# OUTPUT: [0]^терістік/терістік<n><attr>/терістік<n><nom>$
# ^бетіндегі/бет<n><px3sp><loc><attr>...$
REMOVE V IF
(0 PRE-N)
(1C N)
(NOT 0 Gerund)
(NOT 0 VerbalAdjective)
;
#
# failed for a gerund 'өлшеу' in 'Радианның басқа да бұрышты өлшеу бірліктерімен арақатынасын мына формуламен сипатталады' => excluded gerunds and verbal adjectives in the rule
# INPUT: ^бақша/бақша<n><nom>$ ^арқылы/арқылы<post>/арқылы<adv>$
# OUTPUT: ^бақша<n><nom>$ [0]^арқылы<post>$
REMOVE Adv IF
(0 Post)
(-1 N)
(NOT 0 ("бірге"i)) # мысығымен бірге<post> үйде<n>
# бақшада бірге<adv> ойнайды<v>
# бақша арқылы<post> барамын<v>
(NOT 0 ("бұрын")) # Төстік бұрын ағалары бар екенін естіген жоқ екен .
(NOT 1 A)
;
#kaz-eng
# INPUT: ^заңды/заң<n><acc>/заңды<adj>/заң<n>+лы<post>$
# INPUT: ^заңды/заң<n><acc>/заңды<adj>/заң<n>+лы<post>$
# REMOVE Sub:1 Post IF
# (0 N)
# (0 A)
#;
SELECT (cnjcoo) OR (cnjadv) IF
(-1 BOS)
(0 ("әлде"))
;
REMOVE IJ IF
(0 A)
(1 N)
;
# e.g., дұрыс! (<ij>) | дұрыс жерден (<adj>)
SELECT Adv + Attr IF (1 NOMINAL) ;
# Determiners
# ===========
# FIXME removes determiner even when there is a noun 1 to the right
# FIXED JNW 2017-08-12
REMOVE Det IF
(0 Det OR Pron) # ADDED JNW 2017-08-11
(NOT 1 N OR Subst)
(NEGATE 1 A LINK 1 N OR Subst)
;
# 44 . Ол енді ол дыбысты анығырақ ести бастады.
# (!) 34 . Ол Азаматтың қайда екенін білсе де айтқысы келген жоқ.
# Nouns
# =====
#
REMOVE Attr IF
(0 N OR Prop)
(NOT 0 Loc)
(NOT 1 N OR Prop)
;
## 176. Орталықта Түркістанның төл тарихына арналған музейлік [0]экспозиция жасақталған.
## (!) 184 . Үшінші қабатта «Тәуелсіз [0]Қазақстандағы жаңа Түркістан» атты экспозициялар қойылған.
# Select nominative reading of the first noun of the II izafet construct
# (as Tatar grammars call it)
SELECT Nom IF
(0C N OR Prop)
(1 N OR Prop OR Subst)
(1 (px3sp))
;
# Was: SELECT 'Attr'
#
# this rule didn't work for 'қазба' in:
# Оған ежелгі қоныстарға жүргізілген археологиялық қазба жұмыстары кезінде табылған мәдениет мұралары дәлел бола алады.
## 111. Түркияның оңтүстік-шығысындағы [0]Газиантеп қаласында кеше болған жарылыстан қаза тапқандар саны 9-ға жетті.
# If a former gerund or verbal adjective was lexicalized as a noun, select noun
# SELECT N IF
# (0 N)
# (0 Gerund OR (gpr_pot))
#;
# the rule contradicts with some of the analyzes in puupankki, which is considered to be 'gold' standard
#
## professions, such as "оқушы"; -U gerunds , in theory other gerunds too
SELECT Det IF
(0 Det)
(0 (gpr_ppot))
;
## жетерлік has both readings, but we almost always want to translate it as det
REMOVE PersonalPossessives IF
(0 NOMINAL)
(NOT 0 (gen))
(1C (px3sp))
;
## only indefinite possessors can leave off the genitive suffix, and something possessed itself has to be definite,
## so: something possessed can only possess something else if it has gen case,
## so: px* with no gen cannot precede px3sp, so if that's one of the possible readings, you probably don't want it.
## 1929 ж. сырттай өлім жазасына кесілді.
"<қысым>" REMOVE PersonalPossessives ;
# Adjectives
# ==========
# select adverbial reading of adjectives if any verbal form except gerund follows
# FIXME CHECK it might be a gerund as well
SELECT Advl OR Adv IF
(1C V-NotGerund)
#(NOT 1C Participle)
(NOT 1 ("бол"))
(NOT 0 ("балама"))
(NOT 1 ("де"))
;
##
# example: in 'балама үйретейін' the 'балама' shouldn't be treated as adj.advl (equivalent), it should be n.px1sq.dat (to my son)
REMOVE Advl IF (1 NOMINAL) ;
# select adj+cop reading at the end of a sentence
SELECT Sub:1 Cop IF
(0C A1-Nom)
(1 EOS OR MARK)
;
REMOVE Subst IF # we want adj+cop reading here, not adj.subst+cop
(0C A1-Nom)
(1 EOS OR MARK)
;
## 19 . Ол еш нәрсені көріп тұрған [0]жоқ, ол санап жатыр.
#
REMOVE SUB:1 P3 IF
(0/1 Cop)
(0/1 P1)
;
## "Біз [0]қуаныштымыз."
REMOVE A IF
(0 Subst)
(0 Pron)
(0 NGDAALI)
;
## "[0]түгелімен."
# Postpositions
# =============
#
"<қатар>" SELECT Post IF
(-1 Pron + Ins)
;
## 174 . Орталық сонымен [0]қатар оқушыларға тәрбие беруде де маңызды рөл атқарады.
## 148 . Ол АҚШ үкіметін WikiLeaks сайтын қудалауын тоқтатуға шақырып,
## өзін ресейлік Pussy Riot панк тобымен және New York Times басылымымен [0]қатар қойды.
#
"<қарай>" SELECT Post IF
(-1 Dat)
;
##
#
"<қарағанда>" SELECT Post IF
(-1 Dat)
;
##
#
"<қарамастан>" SELECT Post IF
(-1 Dat)
;
##
#
"<дейін>" SELECT Post IF
(-1 Dat)
;
##
#
"<бері>" SELECT Post IF
(-1 Abl)
;
##
# бірге is an adverb, since dropping it results in grammatically correct phrase
#
# "<бірге>" SELECT Post IF
# (-1 Ins)
#;
##
#
"<қоса>" SELECT Post IF
(-1 Dat)
;
##
# Verbs
# =====
#
REMOVE Participle IF
(NOT 1C V OR Vaux)
;
##
# <prc_cond> vs. <gna_cond>
REMOVE (prc_cond) IF
(NOT 1 ("бол") + V)
;
## 34 . Ол Азаматтың қайда екенін [0]білсе де айтқысы келген жоқ.
#
SELECT Participle IF
(0C Participle OR VerbalAdverb)
(NOT 0C (prc_cond) OR (gna_cond))
(1 Vaux)
;
## 16 . Азамат ескі үлкен бір ағашқа қарай қатты [?]жүгіріп бара жатыр, ол сол
## ағаштың артына Айгүлден [0]жасырынып жатыр.
#
REMOVE Vaux IF
(NOT -1 Participle)
;
SELECT Vaux IF
(-1C Participle)
(NOT 1 Vaux)
;
## 187 . Біздің дәуірімізден 1 миллион жыл бұрын өмір сүрген "тік жүретін адамнан" [0]бастап, өз замандастарына дейінгі
## кезеңдерді қамтитын, ... орталықтың экспозициясы негізгі сегіз ірі бөлімнен тұрады.
# REMOVE Vaux IF
# (0 Vaux OR V)
# (1 Vaux)
#;
#
# counterexample: 'таба алмай жатыр', the word 'алмай' should be <vaux>
# Imperative or not?
# ------------------
# <Vaux p3> is more common, so let's set it as default
# Rules for selecting imperative reading of these three (if any) must be placed
# before this rule
SELECT (vaux p3) IF
(-1 (prc_perf) OR (prc_plan) OR (prc_impf))
(0 ("<жүр>") OR ("<тұр>") OR ("<отыр>"))
;
## 15. Олардың анасы мысығымен бірге үйде, ол терезеден Азамат пен Айгүлдің
## ойнағанына қарап [0]тұр.
## 36 . Әлі де болса Азаматты табуға әрекет етіп [0]жүр.
# 2p sg imperative form is a bare stem, so it is often ambigious with other
# parts of speech
REMOVE (imp) IF
(NOT 1 EOS OR MARK OR ("де") OR Rquot OR (guio))
;
## 96 . Ал оң жақ жағалауы батпақты, онда [0]қалың орман өскен.
## [0]Бар деп айттым мен оған.
# ----------
#
SELECT (gpr_past) IF
(0 (ger_past) + Nom)
(1C N)
(NOT 0 Det)
;
## 172 . Сот арқылы немесе өзгеде осындай құзыреті бар мемлекеттік органдардың
## шешімі арқылы тәркіленген мұражайлық маңызы бар жинақтардың немесе
## [0]жекелеген заттардың есебінен;
# Numerals
# ========
# ^Еуровидение/Еуровидение<np><al><nom>$ *^2010/2010<num>/2010<num><ord>$* ^ән/ән<n><nom>$ ^конкурсы/конкурс<n><px3sp><nom>$
SELECT ORD IF (-1 Prop) ;
REMOVE ORD IF (1 QUANTITY) ;
################### TO BE DONE ####################
# Deciding about the number of a verb or copula in the 3 person
# Basic idea is to remove plural reading if subject is not in plural,
# but there a lot of corner cases, which lead to lots of mispredictions.
#
# In Tatar, when the subject indicates the number, this LAR affix for the verbs
# in 3 person is kind of optional too, so singular reading will work/is right for
# the majority of cases.
#REMOVE Pl IF (0 V OR Vaux OR Cop) (0 P3) ;
# Thought that the above rule should cover copulas, seems that sometimes it doesn't
REMOVE SUB:1 Pl IF
(0/1 Cop)
(0/1 P3)
;
# Wordform/lemma-specific rules # Adding new stuff here is discouraged.
# ============================= # Try to generalize, if possible, existing
# rules.
#
"<өте>" SELECT Adv IF (1 A) ;
## Бірақ кеше _өте_ суық еді!
# ugly and RISKY
"<сол>" SELECT Det IF
(NOT 1 ("қол"i) OR ("жақ"i))
;
## (!) Күйеуім - сол жақтың қазағы.
#
"<аса>" SELECT Adv IF
(1 A)
;
## "Әл-Истахри келтірген мәліметтер аса құнды саналады."
#
"<ал>" REMOVE CC IF
(NOT -1 BOS OR Cm )
;
## Бөлмеде шкаф бар, содан бiр кiтап ал.
#
"<жылы>" SELECT N IF
(-1 Num)
;
##
"<теңге>" SELECT N IF
(0 A)
;
#
"<жылы>" SELECT N IF
(-1 A)
;
#
"<қарасты>" SELECT A IF
(-1 (dat))
;
## 177. Орталыққа _қарасты_ Түркістан қаласында Н.Оңдасынов атындағы
## тарихи-мемориалдық мұражайы атты филиал жұмыс жасайды.
#
"<қайта>" SELECT Adv IF
(1C V)
;
## 41 . Ол дыбыс қайта естіледі!
## Ол қайта алмайды.
#
"<енді>" SELECT Adv IF
(1* Acc BARRIER EOS)
(1* V BARRIER EOS)
;
##
#
"<көптеген>" SELECT Det IF
(1 N + Pl)
;
##
# ambigious with v.pass
"<құрал>" SELECT N IF
(-1 A OR (n attr))
;
##
# UGLY
# "сый" is certainly not <v.iv.imp> in the following example,
# I don't think that сый<imp> is ever used
"<сый>" SELECT N
;
## 171. Жеке және заңды тұлғалардан _сый_ немесе мұра ретінде қабылданған заттар
## есебінен.
# imperative of "ісу" ("to swell") - just like "<сый>" above sounds odd,
# but let's try to deal with it in a less ugly way
"<іс>" SELECT N IF
(-1 A)
;
## 178. ...тәрбиелік мәні бар іс-шараларды бірге ұйымдастыру...
# FIXME: could be achieved with a more general rule I think
"<көрме>" SELECT N IF
(1 ("зал"i))
;
## 181. Ғимарат 3 қабаттан, 5 көрме залынан, конференция залынан,
## қолөнершілердің шеберханасы...