shiggy/linker.ld at main · sylvessa/shiggy · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
ENTRY(kmain)
SECTIONS
{
    . = 0x20000;

    PROVIDE(kernel_start_addr = .);

    .text : {
        *(.text.unlikely .text.*_unlikely .text.unlikely.*)
        *(.text.exit .text.exit.*)
        *(.text.startup .text.startup.*)
        *(.text.hot .text.hot.*)
        *(.text .stub .text.* .gnu.linkonce.t.*)
    }
    PROVIDE(etext = .);

    .rodata : {
        *(.rodata .rodata.* .gnu.linkonce.r.*)
        *(.data.rel.ro.local* .gnu.linkonce.d.rel.ro.local.*)
        *(.data.rel.ro .data.rel.ro.* .gnu.linkonce.d.rel.ro.*)
    }

    .cmds : {
        __start_cmds = .;
        KEEP(*(.cmds))
        __stop_cmds = .;
    }

    . = ALIGN(4096);

    PROVIDE(start_data = .);
    .data : {
        *(.data .data.* .gnu.linkonce.d.*)
        SORT(CONSTRUCTORS)
    }
    PROVIDE(edata = .);

    .bss : {
        *(.bss .bss.* .gnu.linkonce.b.*)
    }
    PROVIDE(end = .);

    PROVIDE(kernel_end_addr = .);
    PROVIDE(__free_memory_start = .);

    .boot_info (NOLOAD) : {
        *(.boot_info)
    }

    /DISCARD/ : { *(.eh_frame .note.GNU-stack) }
}