Tiltfile

load('ext://uibutton', 'cmd_button', 'bool_input', 'location')
load('ext://namespace', 'namespace_create', 'namespace_inject')
namespace_create('meet')

def clean_old_images(image_name):
    local('docker images -q %s | tail -n +2 | xargs -r docker rmi' % image_name)

docker_build(
    'localhost:5001/meet-backend:latest',
    context='..',
    dockerfile='../Dockerfile',
    only=['./src/backend', './src/mail', './docker'],
    target = 'backend-production',
    live_update=[
        sync('../src/backend', '/app'),
        run(
            'pip install -r /app/requirements.txt',
            trigger=['./api/requirements.txt']
        )
    ]
)
clean_old_images('localhost:5001/meet-backend')

docker_build(
    'localhost:5001/meet-frontend:latest',
    context='..',
    dockerfile='../src/frontend/Dockerfile',
    only=['./src/frontend', './docker', './.dockerignore'],
    target = 'meet-dev',
    live_update=[
        sync('../src/frontend', '/home/frontend'),
    ]
)
clean_old_images('localhost:5001/meet-frontend')

docker_build(
    'localhost:5001/meet-summary:latest',
    context='../src/summary',
    dockerfile='../src/summary/Dockerfile',
    only=['.', '../../docker', '../../.dockerignore'],
    target = 'production',
    live_update=[
        sync('../src/summary', '/home/summary'),
    ]
)
clean_old_images('localhost:5001/meet-summary')

# Copy the mkcert root CA certificate to our Docker build context
# This is necessary because we need to inject the certificate into our LiveKit container
local_resource(
    'copy-root-ca',
    cmd='cp "$(mkcert -CAROOT)/rootCA.pem" ../docker/livekit/rootCA.pem',
    deps=[],  # No dependencies needed
)
# Build a custom LiveKit Docker image that includes our root CA certificate
# This allows LiveKit to trust our local development certificates
docker_build(
    'localhost:5001/meet-livekit:latest',
    context='../docker/livekit',
    dockerfile='./../docker/livekit/Dockerfile',
    only=['.'],
)
clean_old_images('localhost:5001/meet-livekit')

k8s_yaml(local('cd ../src/helm && helmfile -n meet -e ${DEV_ENV:-dev} template .'))

migration = '''
set -eu
# get k8s pod name from tilt resource name
POD_NAME="$(tilt get kubernetesdiscovery meet-backend -ojsonpath='{.status.pods[0].name}')"
kubectl -n meet exec "$POD_NAME" -- python manage.py makemigrations
'''
cmd_button('Make migration',
           argv=['sh', '-c', migration],
           resource='meet-backend',
           icon_name='developer_board',
           text='Run makemigration',
)

pod_migrate = '''
set -eu
# get k8s pod name from tilt resource name
POD_NAME="$(tilt get kubernetesdiscovery meet-backend -ojsonpath='{.status.pods[0].name}')"
kubectl -n meet exec "$POD_NAME" -- python manage.py migrate --no-input
'''
cmd_button('Migrate db',
           argv=['sh', '-c', pod_migrate],
           resource='meet-backend',
           icon_name='developer_board',
           text='Run database migration',
)