feat(front): add members download button

- Add members download button on people page
- Implement export members as csv endpoint
- Add export members test

Author: loadez

front/lib/front_web/controllers/people_controller.ex

@@ -24,8 +24,12 @@ defmodule FrontWeb.PeopleController do
   plug(FetchPermissions, [scope: "org"] when action in @person_action)
   plug(PageAccess, [permissions: "organization.view"] when action in @person_action)
 
-  plug(FetchPermissions, [scope: "org"] when action in [:organization])
-  plug(PageAccess, [permissions: "organization.view"] when action in [:organization])
+  plug(FetchPermissions, [scope: "org"] when action in [:organization, :organization_users])
+
+  plug(
+    PageAccess,
+    [permissions: "organization.view"] when action in [:organization, :organization_users]
+  )
 
   plug(
     FetchPermissions,
@@ -1061,6 +1065,51 @@ defmodule FrontWeb.PeopleController do
     end)
   end
 
+  def organization_users(conn, _params) do
+    Watchman.benchmark("people.organization_users.duration", fn ->
+      org_id = conn.assigns.organization_id
+
+      page_size = 100
+
+      data =
+        Stream.unfold(0, fn
+          nil ->
+            nil
+
+          page_no ->
+            case Members.list_org_members(org_id, page_no: page_no, page_size: page_size) do
+              {:ok, {members, total_pages}} ->
+                {members, next_valid_page_or_nil(total_pages, page_no)}
+
+              _ ->
+                nil
+            end
+        end)
+        |> Enum.flat_map(& &1)
+        |> Enum.map(fn e ->
+          %{
+            "name" => e.name,
+            "email" => e.email,
+            "github_login" => e.github_login,
+            "bitbucket_login" => e.bitbucket_login,
+            "gitlab_login" => e.gitlab_login
+          }
+        end)
+        |> CSV.encode(
+          headers: [
+            "name",
+            "email",
+            "github_login",
+            "bitbucket_login",
+            "gitlab_login"
+          ]
+        )
+        |> Enum.to_list()
+
+      send_download(conn, {:binary, data}, filename: "users.csv")
+    end)
+  end
+
   def sync(conn, %{"format" => "json"}) do
     Watchman.benchmark("sync.organization.duration", fn ->
       org_id = conn.assigns.organization_id
@@ -1213,4 +1262,14 @@ defmodule FrontWeb.PeopleController do
     email_regex = ~r/^[^\s@]+@[^\s@]+\.[^\s@]+$/
     Regex.match?(email_regex, email)
   end
+
+  defp next_valid_page_or_nil(total_pages, page) do
+    next_page_no = page + 1
+
+    if next_page_no <= total_pages do
+      next_page_no
+    else
+      nil
+    end
+  end
 end

front/lib/front_web/router.ex

@@ -152,6 +152,7 @@ defmodule FrontWeb.Router do
 
     scope "/people" do
       get("/", PeopleController, :organization)
+      get("/export", PeopleController, :organization_users)
       post("/", PeopleController, :create)
       post("/refresh", PeopleController, :refresh)
       post("/assign_role", PeopleController, :assign_role)

front/lib/front_web/templates/people/members/members_list.html.eex

@@ -32,7 +32,15 @@
           <div class="b">People</div>
         </div>
       </div>
-      <%= render "members/_add_people_button.html", conn: @conn, org_scope?: @org_scope?, permissions: @permissions %>
+      <div class="flex">
+      <%= if @org_scope? do %>
+        <%= link to: people_path(@conn, :organization_users), class: "pointer flex items-center btn-secondary btn nowrap mr2", aria_label: "Download members as CSV", title: "Download members as CSV" do %>
+          <span class="material-symbols-outlined ">download</span>
+          Download .csv
+        <% end %>
+      <% end %>
+        <%= render "members/_add_people_button.html", conn: @conn, org_scope?: @org_scope?, permissions: @permissions %>
+      </div>
     </div>
 
     <div id="members">

front/test/front_web/controllers/people_controller_test.exs

@@ -36,6 +36,47 @@ defmodule FrontWeb.PeopleControllerTest do
     ]
   end
 
+  describe "GET organization_users" do
+    test "when the user can't access the org => returns 404", %{
+      conn: conn
+    } do
+      PermissionPatrol.remove_all_permissions()
+
+      conn =
+        conn
+        |> get("/people/export")
+
+      assert html_response(conn, 404) =~ "404"
+    end
+
+    test "when the user can access the org => send csv", %{
+      conn: conn,
+      organization: organization
+    } do
+      conn =
+        conn
+        |> get("/people/export")
+
+      assert response_content_type(conn, :csv)
+
+      rows =
+        conn.resp_body
+        |> String.split("\r\n", trim: true)
+        |> CSV.decode!(validate_row_length: true, headers: true)
+        |> Enum.to_list()
+
+      assert length(rows) == 8
+
+      first = List.first(rows)
+
+      assert Map.has_key?(first, "name")
+      assert Map.has_key?(first, "email")
+      assert Map.has_key?(first, "github_login")
+      assert Map.has_key?(first, "bitbucket_login")
+      assert Map.has_key?(first, "gitlab_login")
+    end
+  end
+
   describe "GET show" do
     test "when the user can't access the org => returns 404", %{
       conn: conn,