MODULE.bazel

module(
    name = "twitter_text_rs",
    version = "0.3.1",
)

# Check that Ruby 3.4.1+ is on PATH (required for rules_ruby with version="system")
ruby_version_check = use_repo_rule("//tools:ruby_version_check.bzl", "ruby_version_check")

ruby_version_check(name = "ruby_version_check")

###############################################################################
# Bazel Dependencies
###############################################################################

bazel_dep(name = "bazel_skylib", version = "1.9.2")
bazel_dep(name = "googletest", version = "1.18.0.bcr.1")
bazel_dep(name = "rules_rust", version = "0.74.0")
bazel_dep(name = "rules_rust_wasm_bindgen", version = "0.74.0")

# apple_support MUST come before rules_cc for proper toolchain selection on macOS
bazel_dep(name = "apple_support", version = "2.10.1")
bazel_dep(name = "rules_cc", version = "0.2.26")
bazel_dep(name = "cxx.rs", version = "1.0.205")
bazel_dep(name = "rules_ruby", version = "1.0.0-rc1")
bazel_dep(name = "rules_apple", version = "5.3.0")

# Apple CC toolchain for macOS (required for swift_test with XCTest)
apple_cc_configure = use_extension(
    "@apple_support//crosstool:setup.bzl",
    "apple_cc_configure_extension",
)
use_repo(apple_cc_configure, "local_config_apple_cc", "local_config_apple_cc_toolchains")

bazel_dep(name = "rules_java", version = "9.9.0")
bazel_dep(name = "rules_jvm_external", version = "7.2")
bazel_dep(name = "rules_python", version = "2.4.2")
bazel_dep(name = "rules_shell", version = "0.8.0")
bazel_dep(name = "rules_swift", version = "4.2.1")

# nlohmann_json needs a .bcr.N revision that adds the cc_library load for Bazel 9
bazel_dep(name = "nlohmann_json", version = "3.12.0.bcr.2")
bazel_dep(name = "platforms", version = "1.1.0")

# yams 6.2.2 ships the rules_cc load and swift_interop_hint upstream, so the
# local patch that used to add them is no longer needed.
bazel_dep(name = "yams", version = "6.2.2")
bazel_dep(name = "aspect_rules_js", version = "3.5.1")
bazel_dep(name = "rules_nodejs", version = "6.7.6")

###############################################################################
# Java Toolchains and Maven Dependencies
###############################################################################

java_toolchains = use_extension("@rules_java//java:extensions.bzl", "toolchains")

maven = use_extension("@rules_jvm_external//:extensions.bzl", "maven")
maven.install(
    artifacts = [
        "junit:junit:4.13.2",
        "com.fasterxml.jackson.core:jackson-databind:2.22.3",
        "com.fasterxml.jackson.core:jackson-core:2.22.3",
        "com.fasterxml.jackson.core:jackson-annotations:2.22",
        "com.fasterxml.jackson.dataformat:jackson-dataformat-yaml:2.22.3",
        "com.google.code.findbugs:jsr305:3.0.2",
    ],
    # rules_rust_wasm_bindgen pulls in protobuf, which also contributes to the
    # "maven" repository; acknowledging it silences rules_jvm_external's warning.
    known_contributing_modules = ["protobuf"],
    lock_file = "//:maven_install.json",
    repositories = [
        "https://repo1.maven.org/maven2",
    ],
)
use_repo(maven, "maven")

http_archive = use_repo_rule("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

###############################################################################
# C Libraries for Ruby
###############################################################################

http_archive(
    name = "libyaml",
    build_file_content = """
cc_library(
    name = "yaml",
    srcs = glob(["src/*.c"]),
    hdrs = glob(["include/**/*.h"]),
    includes = ["include"],
    visibility = ["//visibility:public"],
)
    """,
    sha256 = "c642ae9b75fee120b2d96c712538bd2cf283228d2337df2cf2988e3c02678ef4",
    strip_prefix = "libyaml-0.2.5",
    urls = ["https://github.com/yaml/libyaml/archive/refs/tags/0.2.5.tar.gz"],
)

http_archive(
    name = "zlib",
    build_file_content = """
cc_library(
    name = "zlib",
    srcs = glob(["*.c"]),
    hdrs = glob(["*.h"]),
    includes = ["."],
    visibility = ["//visibility:public"],
)
    """,
    sha256 = "bb329a0a2cd0274d05519d61c667c062e06990d72e125ee2dfa8de64f0119d16",
    strip_prefix = "zlib-1.3.2",
    urls = ["https://github.com/madler/zlib/releases/download/v1.3.2/zlib-1.3.2.tar.gz"],
)

http_archive(
    name = "readline",
    build_file_content = """
cc_library(
    name = "readline",
    srcs = glob(["*.c"]),
    hdrs = glob(["*.h"]),
    includes = ["."],
    visibility = ["//visibility:public"],
    linkopts = ["-lncurses"],
)
    """,
    sha256 = "fe5383204467828cd495ee8d1d3c037a7eba1389c22bc6a041f627976f9061cc",
    strip_prefix = "readline-8.3",
    urls = ["https://ftp.gnu.org/gnu/readline/readline-8.3.tar.gz"],
)

###############################################################################
# Swift Toolchains
###############################################################################

# rules_swift >= 4.0.0 ships a standalone toolchain extension (upstream PR
# #1630), which replaces the hand-rolled http_archive + swift_toolchain wrapper
# that used to live in //tools/swift, along with the local patch that added a
# `toolchain_files` attribute to support it.
#
# macOS keeps using the Xcode toolchain that rules_swift configures natively;
# only the Linux platforms are pinned here.
SWIFT_VERSION = "6.4.0"

swift = use_extension("@rules_swift//swift:extensions.bzl", "swift")

# platform_sha256 restricts the generated toolchains to the Linux platforms
# used here (without it rules_swift declares one per platform it knows). The
# checksums come from rules_swift's swift_release_metadata.json.
swift.toolchain(
    name = "swift_toolchain",
    platform_sha256 = {
        "ubuntu22.04": "bce85ea80f1471b85f39993f9285dbc798ec8e1eac5f677e24b2ac693856f9f8",
        "ubuntu22.04-aarch64": "28c28acb2b91ed0e3beff5e6ba3695a785e645d9bd374adcaa3b7c2a901bc763",
    },
    swift_version = SWIFT_VERSION,
)
use_repo(
    swift,
    "swift_toolchain",
    "swift_toolchain_ubuntu22.04",
    "swift_toolchain_ubuntu22.04-aarch64",
)

register_toolchains("@swift_toolchain//:swift_toolchain_exec_ubuntu22.04")

###############################################################################
# Hermetic LLVM Toolchain
###############################################################################

# Sysroot for the hermetic LLVM toolchain, assembled from Debian bookworm
# (12.15) packages. This used to be Chromium's prebuilt bullseye sysroot, but
# that is still glibc 2.31 with GCC 10's libstdc++, which lacks symbols the
# static Swift 6.4 runtime references, and Chromium doesn't publish anything
# newer. Bookworm's glibc 2.36 keeps the binaries runnable on Ubuntu 24.04.
#
# Paths and checksums come from dists/bookworm/main/binary-amd64/Packages.
# deb.debian.org drops superseded files at the next point release, so
# snapshot.debian.org is the fallback.
debian_sysroot = use_repo_rule("//tools:debian_sysroot.bzl", "debian_sysroot")

debian_sysroot(
    name = "linux_sysroot",
    mirrors = [
        "https://deb.debian.org/debian",
        "https://snapshot.debian.org/archive/debian/20261015T000000Z",
    ],
    packages = {
        # glibc, kernel headers, libcrypt
        "pool/main/g/glibc/libc6_2.36-9+deb12u14_amd64.deb": "ba4f88f73dbc3ae9055f3c20f4523bfdbaf1ad13ff95e258924f77d20b4fbedf",
        "pool/main/g/glibc/libc6-dev_2.36-9+deb12u14_amd64.deb": "0218fc2befcd784c1b0c6292c0a137ce89fad054efaa579ad083bee0f2c01aae",
        "pool/main/l/linux/linux-libc-dev_6.1.176-1_amd64.deb": "8bb258735b9dffbb111da778ebdd024750878e435ffd9dfcadcb6762ede6b4cf",
        "pool/main/libx/libxcrypt/libcrypt1_4.4.33-2_amd64.deb": "f5f60a5cdfd4e4eaa9438ade5078a57741a7a78d659fcb0c701204f523e8bd29",
        "pool/main/libx/libxcrypt/libcrypt-dev_4.4.33-2_amd64.deb": "81ccd29130f75a9e3adabc80e61921abff42f76761e1f792fa2d1bb69af7f52f",
        # GCC 12 runtime: crt objects, libgcc, libatomic, libstdc++ and headers
        "pool/main/g/gcc-12/gcc-12-base_12.2.0-14+deb12u1_amd64.deb": "1896a2aacf4ad681ff5eacc24a5b0ca4d5d9c9b9c9e4b6de5197bc1e116ea619",
        "pool/main/g/gcc-12/libgcc-s1_12.2.0-14+deb12u1_amd64.deb": "3016e62cb4b7cd8038822870601f5ed131befe942774d0f745622cc77d8a88f7",
        "pool/main/g/gcc-12/libgcc-12-dev_12.2.0-14+deb12u1_amd64.deb": "d720259380a84f2ffc6fe516eff5cbe9c8a005138e8d6a5748747ba4b3404a82",
        "pool/main/g/gcc-12/libatomic1_12.2.0-14+deb12u1_amd64.deb": "fbd4e154a6b444229ea002cc209df099209c0adc09102e5fd21239a3d2b55e2d",
        "pool/main/g/gcc-12/libstdc++6_12.2.0-14+deb12u1_amd64.deb": "5cd3171216d4ab0fc911cfe9c35509bf2dd8f47761c43b7f6a4296701551a24d",
        "pool/main/g/gcc-12/libstdc++-12-dev_12.2.0-14+deb12u1_amd64.deb": "d28def6c23630432b57cb38a4c2fd67a79d4e0484027386ca6e8d6005c3d7a73",
        # Libraries the Swift static runtime link and the Ruby readline build pull in
        "pool/main/c/curl/libcurl4_7.88.1-10+deb12u15_amd64.deb": "3042904de01f9c4fbdcf1452b8f81abedcf2b015f9b9deba109063322b5bd68b",
        "pool/main/c/curl/libcurl4-openssl-dev_7.88.1-10+deb12u15_amd64.deb": "dbd69b15ecb49331f53fbc3483b0508997e2fab551e48c53951391f254b73890",
        "pool/main/libx/libxml2/libxml2_2.9.14+dfsg-1.3~deb12u6_amd64.deb": "4460e39dda10a815881374217cde08474747cfa018358cd8612c14b390eff53b",
        "pool/main/libx/libxml2/libxml2-dev_2.9.14+dfsg-1.3~deb12u6_amd64.deb": "e8ceacf656b1720e7a310e1d159439a356bfcb9f5fb0325907f26aa8590e5f70",
        "pool/main/n/ncurses/libtinfo6_6.4-4_amd64.deb": "072d908f38f51090ca28ca5afa3b46b2957dc61fe35094c0b851426859a49a51",
        "pool/main/n/ncurses/libncurses6_6.4-4_amd64.deb": "72300f09f02669c06c99b641ea795d52300ec7eb65eaccddf7bc3b72934f0ef5",
        "pool/main/n/ncurses/libncurses-dev_6.4-4_amd64.deb": "2ad228835756feb118bb131b32834bd23a09047e4de408cc5204cbb5dce0e4bb",
        "pool/main/z/zlib/zlib1g_1.2.13.dfsg-1_amd64.deb": "d7dd1d1411fedf27f5e27650a6eff20ef294077b568f4c8c5e51466dc7c08ce4",
        "pool/main/z/zlib/zlib1g-dev_1.2.13.dfsg-1_amd64.deb": "f9ce531f60cbd5df37996af9370e0171be96902a17ec2bdbd8d62038c354094f",
    },
)

bazel_dep(name = "toolchains_llvm", version = "1.11.3")

llvm = use_extension("@toolchains_llvm//toolchain/extensions:llvm.bzl", "llvm")
llvm.toolchain(
    cxx_builtin_include_directories = {
        "": [
            "/usr/include",
            "/usr/local/include",
        ],
    },
    llvm_version = "17.0.6",
    sha256 = {"": "884ee67d647d77e58740c1e645649e29ae9e8a6fe87c1376be0f3a30f3cc9ab3"},
    strip_prefix = {
        "": "clang+llvm-17.0.6-x86_64-linux-gnu-ubuntu-22.04",
    },
    urls = {
        "": ["https://github.com/llvm/llvm-project/releases/download/llvmorg-17.0.6/clang+llvm-17.0.6-x86_64-linux-gnu-ubuntu-22.04.tar.xz"],
    },
)
llvm.sysroot(
    label = "@linux_sysroot//:sysroot",
    targets = ["linux-x86_64"],
)
use_repo(llvm, "llvm_toolchain")
use_repo(llvm, "llvm_toolchain_llvm")

# Register Apple CC toolchain first so it takes precedence on macOS
register_toolchains("@local_config_apple_cc_toolchains//:all")

register_toolchains("@llvm_toolchain//:all")

###############################################################################
# Rust Toolchains
###############################################################################

RUST_EDITION = "2021"

RUST_VERSION = "1.99.1"

# rules_rust 0.74.0 predates this release and has no checksums for it. Taken
# from the xz_hash fields of static.rust-lang.org/dist/channel-rust-stable.toml.
RUST_SHA256S = {
    "rustc-1.99.1-aarch64-apple-darwin.tar.xz": "23948a0a9c162fd2952defb3fb0462c44e8fcfd1a4ab8a274a1e1bdb2cf810a3",
    "rustc-1.99.1-x86_64-apple-darwin.tar.xz": "203feef2c2165d7dda1f30ccf75590f72a6abc52ce259ed1c418de84a6887698",
    "rustc-1.99.1-x86_64-unknown-linux-gnu.tar.xz": "2ff05ff9c08a90861e7f6e4065b40a8b87463b4576186fd613871c3e37f2091f",
    "rustc-1.99.1-aarch64-unknown-linux-gnu.tar.xz": "acdcdfe09ae1f103aa9a2b7f88903a9588bc2e99288af10e6fbf5514e2e49f25",
    "cargo-1.99.1-aarch64-apple-darwin.tar.xz": "685e563d94db1f003ffa5f5831439eec02569b9950b69867953c8213269c1eaf",
    "cargo-1.99.1-x86_64-apple-darwin.tar.xz": "6636dabcec164909d1c6eb9e2c596148787c84f7d3a02ff68a141569077f80b5",
    "cargo-1.99.1-x86_64-unknown-linux-gnu.tar.xz": "53f3521949404d595efb06a55c12c5658d4ed1c75566f33d3d514eaebe70bd8a",
    "cargo-1.99.1-aarch64-unknown-linux-gnu.tar.xz": "5156832e0c1254e9b49a79edabdc6d4c35f32f8fc1cf3ca700f268ff96087ab0",
    "clippy-1.99.1-aarch64-apple-darwin.tar.xz": "c463f31831196702fc544900a0dc4c1837905327507fbec751fe46e59ca098bf",
    "clippy-1.99.1-x86_64-apple-darwin.tar.xz": "b5810174b696eaa05dd4ffd5b24c40a33c6d4bccc05fb72264006b7bfefb8c5d",
    "clippy-1.99.1-x86_64-unknown-linux-gnu.tar.xz": "458339712a058e52cc4522ff9ef8b59cd1ea1340312216cd94194c464a3f6dc5",
    "clippy-1.99.1-aarch64-unknown-linux-gnu.tar.xz": "3bea76c26dcf30c176c0a8a8cc283eb59fabd754e24a68b4ca0701e5f3245f6b",
    "rustfmt-1.99.1-aarch64-apple-darwin.tar.xz": "8b80dda570f140ee9ced8799294e812bba847a025f185bae4cba85a2ba235570",
    "rustfmt-1.99.1-x86_64-apple-darwin.tar.xz": "06491b425e02612479c30ad9a49f72f88bc8e033310ec8cc238a15eafecf91b7",
    "rustfmt-1.99.1-x86_64-unknown-linux-gnu.tar.xz": "e3b36c4c7ec3486c059d8067ff48787676612007123aad7a4e8ec12c48ee9ba2",
    "rustfmt-1.99.1-aarch64-unknown-linux-gnu.tar.xz": "26b3200b1461921415927abf7fe410202a6eda2db3e419abde59e0abfcd93fc2",
    "llvm-tools-1.99.1-aarch64-apple-darwin.tar.xz": "b348db9d79666aee4b5e2ff4269029fffd16815cbd47f47018cd0b06e4f815f5",
    "llvm-tools-1.99.1-x86_64-apple-darwin.tar.xz": "3112e92b03b1cca4264a30ca602948d31976cd45db7de2bc7900efa25a39a045",
    "llvm-tools-1.99.1-x86_64-unknown-linux-gnu.tar.xz": "8429c5117debfb45c22cf2f97712ef00e0e94976c96cf92f661974a458ca7e84",
    "llvm-tools-1.99.1-aarch64-unknown-linux-gnu.tar.xz": "cd1818058908c1c4e99bd2843fe103df255157454e16186ec9cc3b5b5823b39c",
    "rust-std-1.99.1-aarch64-apple-darwin.tar.xz": "fe79d6ab5a0321de26463999d8c112b8ad3eafbcbcf822d66a2300b45dde1031",
    "rust-std-1.99.1-x86_64-apple-darwin.tar.xz": "484d5b88b424ddd29df196e1eb9420c8335bb5fac90a3c37140253345a8c65c4",
    "rust-std-1.99.1-x86_64-unknown-linux-gnu.tar.xz": "109b074225bf5b9ea3820890876bfdf4ed161adbfaf94b2b4b5984c85ee5d958",
    "rust-std-1.99.1-aarch64-unknown-linux-gnu.tar.xz": "e25668477083d6a9ddb87b9beb9c00742225f38233ccb4bfba3afa7a07427f52",
    "rust-std-1.99.1-wasm32-unknown-unknown.tar.xz": "5f628f857dd00a8aa3fcac2e275665d2782066a5795274ed124c5b560f46423c",
    "rust-src-1.99.1.tar.xz": "e485a88c45db546b73571df7bebfcb4454ba4fb552c492e25fc5b00eeb5bf22d",
}

rust_ext = use_extension("@rules_rust//rust:extensions.bzl", "rust")
rust_ext.toolchain(
    edition = RUST_EDITION,
    extra_target_triples = ["wasm32-unknown-unknown"],
    sha256s = RUST_SHA256S,
    versions = [RUST_VERSION],
)
use_repo(rust_ext, "rust_toolchains")

register_toolchains("@rust_toolchains//:all")

###############################################################################
# Python Toolchain (for PyO3)
###############################################################################

python = use_extension("@rules_python//python/extensions:python.bzl", "python")
python.toolchain(
    python_version = "3.12",
)
use_repo(python, "python_3_12", "python_versions")

register_toolchains("@python_3_12//:all")

pip = use_extension("@rules_python//python/extensions:pip.bzl", "pip")
pip.parse(
    hub_name = "tld_gen_deps",
    python_version = "3.12",
    requirements_lock = "//rust/conformance:tests/tld_gen_requirements.txt",
)
pip.parse(
    hub_name = "rust_python_test_deps",
    python_version = "3.12",
    requirements_lock = "//rust/python-bindings/test:requirements.txt",
)
use_repo(pip, "rust_python_test_deps", "tld_gen_deps")

###############################################################################
# Ruby Toolchain (for Magnus)
###############################################################################

ruby = use_extension("@rules_ruby//ruby:extensions.bzl", "ruby")
ruby.toolchain(
    name = "ruby",
    version = "system",
)
ruby.bundle_fetch(
    name = "bundle",
    gem_checksums = {
        "diff-lcs-1.6.2": "9ae0d2cba7d4df3075fe8cd8602a8604993efc0dfa934cff568969efb1909962",
        "rspec-3.13.2": "206284a08ad798e61f86d7ca3e376718d52c0bc944626b2349266f239f820587",
        "rspec-core-3.13.6": "a8823c6411667b60a8bca135364351dda34cd55e44ff94c4be4633b37d828b2d",
        "rspec-expectations-3.13.5": "33a4d3a1d95060aea4c94e9f237030a8f9eae5615e9bd85718fe3a09e4b58836",
        "rspec-mocks-3.13.8": "086ad3d3d17533f4237643de0b5c42f04b66348c28bf6b9c2d3f4a3b01af1d47",
        "rspec-support-3.13.7": "0640e5570872aafefd79867901deeeeb40b0c9875a36b983d85f54fb7381c47c",
        "yaml-0.4.0": "240e69d1e6ce3584d6085978719a0faa6218ae426e034d8f9b02fb54d3471942",
    },
    gemfile = "//:Gemfile",
    gemfile_lock = "//:Gemfile.lock",
)
use_repo(ruby, "bundle", "ruby", "ruby_toolchains")

register_toolchains("@ruby_toolchains//:all")

###############################################################################
# Rust Crates
###############################################################################

deps = use_extension("//:extensions.bzl", "rust_deps")
use_repo(
    deps,
    "twitter_text",
    "twitter_text__clap-4.6.7",
    "twitter_text__cxx-1.0.205",
    "twitter_text__emojis-0.9.1",
    "twitter_text__gungraun-0.20.0",
    "twitter_text__idna-1.1.0",
    "twitter_text__js-sys-0.3.98",
    "twitter_text__lazy_static-1.5.1",
    "twitter_text__libc-0.2.190",
    "twitter_text__log-0.4.34",
    "twitter_text__magnus-0.9.2",
    "twitter_text__memchr-2.8.3",
    "twitter_text__nom-8.0.0",
    "twitter_text__pest-2.9.3",
    "twitter_text__pest_derive-2.9.3",
    "twitter_text__phf-0.14.0",
    "twitter_text__proc-macro-error-1.0.4",
    "twitter_text__pyo3-0.30.1",
    "twitter_text__pyo3-macros-0.30.1",
    "twitter_text__serde-1.0.229",
    "twitter_text__serde_derive-1.0.229",
    "twitter_text__serde_json-1.0.154",
    "twitter_text__serde_yaml_ng-0.10.0",
    "twitter_text__unicode-normalization-0.1.26",
    "twitter_text__unicode_categories-0.1.1",
    "twitter_text__wasm-bindgen-0.2.121",
)

###############################################################################
# cxxbridge-cmd (codegen tool for cxx.rs)
###############################################################################

CXX_BRIDGE_VERSION = "1.0.205"

http_archive(
    name = "cxxbridge-cmd",
    build_file_content = """
load("@rules_rust//rust:defs.bzl", "rust_binary")
load("@cxxbridge_cmd_deps//:defs.bzl", "aliases", "all_crate_deps")

rust_binary(
    name = "cxxbridge-cmd",
    srcs = glob(["src/**/*.rs"]),
    aliases = aliases(),
    compile_data = glob(["src/**/*.h"]),
    # cxxbridge-cmd moved to the 2024 edition (it uses let chains).
    edition = "2024",
    visibility = ["//visibility:public"],
    deps = all_crate_deps(
        normal = True,
    ),
    version = "%s",
)
    """ % CXX_BRIDGE_VERSION,
    sha256 = "54a486ed16a3f2a053fe7f5b98db4c1a59846a23e8cb9e49f9d1bd48830d51a2",
    strip_prefix = "cxxbridge-cmd-" + CXX_BRIDGE_VERSION,
    type = "tar.gz",
    urls = ["https://static.crates.io/crates/cxxbridge-cmd/cxxbridge-cmd-" + CXX_BRIDGE_VERSION + ".crate"],
)

cxxbridge_cmd_deps = use_extension("@rules_rust//crate_universe:extensions.bzl", "crate")
cxxbridge_cmd_deps.splicing_config(
    repositories = ["cxxbridge_cmd_deps"],
    resolver_version = "2",
)
cxxbridge_cmd_deps.from_cargo(
    name = "cxxbridge_cmd_deps",
    cargo_lockfile = "//3rdparty/cxxbridge:Cargo.lock",
    manifests = ["@cxxbridge-cmd//:Cargo.toml"],
)
use_repo(
    cxxbridge_cmd_deps,
    "cxxbridge_cmd_deps",
)

###############################################################################
# C++ (yaml-cpp)
###############################################################################

http_archive(
    name = "com_github_jbeder_yaml_cpp",
    sha256 = "25cb043240f828a8c51beb830569634bc7ac603978e0f69d6b63558dadefd49a",
    strip_prefix = "yaml-cpp-yaml-cpp-0.9.0",
    urls = [
        "https://github.com/jbeder/yaml-cpp/archive/refs/tags/yaml-cpp-0.9.0.tar.gz",
    ],
)

###############################################################################
# Java (JDK 23 and jextract)
###############################################################################

jdk23_ext = use_extension("//tools:jdk23_and_jextract.bzl", "jdk23_ext")
jdk23_ext.add_jdk(
    name = "jdk23_macos_arm64",
    cpu = "arm64",
    os = "macos",
    sha256 = "61979887f7506a24a57439ff99adb8b3a7fc89977d9cfe3b8984f58a981b7b9d",
    strip_prefix = "jdk-25.0.4.1+1",
    urls = [
        "https://github.com/adoptium/temurin25-binaries/releases/download/jdk-25.0.4.1%2B1/OpenJDK25U-jdk_aarch64_mac_hotspot_25.0.4.1_1.tar.gz",
    ],
)
jdk23_ext.add_jdk(
    name = "jdk23_linux_x86_64",
    cpu = "x86_64",
    os = "linux",
    sha256 = "dbb698396d478e7fa2b1e50f4103324b2a99b90569ee27c33f2261f9215cf41e",
    strip_prefix = "jdk-25.0.4.1+1",
    urls = [
        "https://github.com/adoptium/temurin25-binaries/releases/download/jdk-25.0.4.1%2B1/OpenJDK25U-jdk_x64_linux_hotspot_25.0.4.1_1.tar.gz",
    ],
)
jdk23_ext.add_jdk(
    name = "jdk23_linux_arm64",
    cpu = "arm64",
    os = "linux",
    sha256 = "69df11a02cfa3ef7d7ca645e03edce6778ec090e100f6ae2b42097865730ac52",
    strip_prefix = "jdk-25.0.4.1+1",
    urls = [
        "https://github.com/adoptium/temurin25-binaries/releases/download/jdk-25.0.4.1%2B1/OpenJDK25U-jdk_aarch64_linux_hotspot_25.0.4.1_1.tar.gz",
    ],
)
jdk23_ext.add_jextract(
    name = "jextract_macos_arm64",
    cpu = "arm64",
    os = "macos",
    sha256 = "3dd1dd1bde059d271739e2cc2290c64f93f85488c86c01e566c0e374eece798f",
    strip_prefix = "jextract-25",
    urls = [
        "https://download.java.net/java/early_access/jextract/25/2/openjdk-25-jextract+2-4_macos-aarch64_bin.tar.gz",
    ],
)
jdk23_ext.add_jextract(
    name = "jextract_linux_x86_64",
    cpu = "x86_64",
    os = "linux",
    sha256 = "d0cc481abc1adb16fb9514e1c5e0bfc08d38c29228bece667fb5054ceaffaa42",
    strip_prefix = "jextract-25",
    urls = [
        "https://download.java.net/java/early_access/jextract/25/2/openjdk-25-jextract+2-4_linux-x64_bin.tar.gz",
    ],
)
jdk23_ext.add_jextract(
    name = "jextract_linux_arm64",
    cpu = "arm64",
    os = "linux",
    sha256 = "0e25e6f6efa042f8758eaec65a873887fd2247fcf2e3e22dcfd7e4179fc8b0ae",
    strip_prefix = "jextract-25",
    urls = [
        "https://download.java.net/java/early_access/jextract/25/2/openjdk-25-jextract+2-4_linux-aarch64_bin.tar.gz",
    ],
)
use_repo(
    jdk23_ext,
    "jdk23_linux_arm64_repo",
    "jdk23_linux_x86_64_repo",
    "jdk23_macos_arm64_repo",
    "jdk23_toolchains",
    "jextract_linux_arm64_repo",
    "jextract_linux_x86_64_repo",
    "jextract_macos_arm64_repo",
)

register_toolchains("@jdk23_toolchains//:all")

###############################################################################
# Node.js (for WASM tests)
###############################################################################

node = use_extension("@rules_nodejs//nodejs:extensions.bzl", "node")
node.toolchain(
    name = "nodejs",
    node_version = "24.22.0",
)
use_repo(node, "nodejs", "nodejs_toolchains")

register_toolchains("@nodejs_toolchains//:all")

npm = use_extension("@aspect_rules_js//npm:extensions.bzl", "npm")
npm.npm_translate_lock(
    name = "npm",
    pnpm_lock = "//:pnpm-lock.yaml",
)
use_repo(npm, "npm")