multi-platform-plugin-template/build.gradle at main · sVoxelDev/multi-platform-plugin-template · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
buildscript {
    repositories {
        mavenCentral()
    }
}

plugins {
    id 'com.github.johnrengelman.shadow' version '7.1.0' apply false
    id 'kr.entree.spigradle' version '2.2.4' apply false
    id 'io.freefair.lombok' version '6.3.0' apply false
    id 'org.cadixdev.licenser' version '0.6.1' apply false
}

subprojects {
    apply plugin: 'com.github.johnrengelman.shadow'
    apply plugin: 'io.freefair.lombok'
    apply plugin: 'org.cadixdev.licenser'
    apply plugin: 'jacoco'
    apply plugin: 'java-library'
    apply plugin: 'java-test-fixtures'
    apply plugin: 'idea'

    apply from: "$rootDir/gradle/jacoco.gradle"
    apply from: "$rootDir/gradle/publish.gradle"

    if (project.hasProperty("local_script")) {
        apply from: file(local_script + "/build.local.gradle")
    }

    sourceCompatibility = 17
    targetCompatibility = 17

    archivesBaseName = project.property("pluginName")
    group project.property("group")

    ext {
        mcVersion = project.property("mcVersion")
    }

    compileJava {
        options.encoding = 'UTF-8'
        options.compilerArgs += ["-parameters"]
        options.fork = true
        options.forkOptions.executable = 'javac'
    }

    repositories {
        mavenLocal()
        mavenCentral()
        maven { url = 'https://jitpack.io' }
        maven { url = "https://oss.sonatype.org/content/repositories/snapshots/" }
    }

    dependencies {
        api 'net.kyori:adventure-api:4.9.3'

        implementation 'org.jetbrains:annotations:22.0.0'

        // Test dependencies
        testImplementation 'org.junit.jupiter:junit-jupiter:5.8.1'
        testImplementation 'org.mockito:mockito-core:4.0.0'
        testImplementation 'org.assertj:assertj-core:3.21.0'

        testFixturesImplementation 'org.mockito:mockito-core:4.0.0'
        testFixturesImplementation 'org.assertj:assertj-core:3.21.0'
        testFixturesImplementation 'org.apache.commons:commons-lang3:3.12.0'
    }

    test {
        useJUnitPlatform()
        testLogging {
            events "skipped", "failed"
        }
        ignoreFailures = false
    }

    processResources {
        project.properties.put("version", this.version)
        expand project.properties
    }

    license {
        header = rootProject.file("HEADER.txt")
        include '**/*.java'
        newLine = true
    }

    defaultTasks 'licenseFormat', 'build'
}