Analog input and output on ESP32

[flows0247]

Hi,
Im wondering if I should be able to use AnalogAudioStream for both TX and RX on ESP32 but not at the same time.
To .end() TX and .begin() RX and vice versa.

For example like the following code:
void record_start(){
copier.end();
adc.end();
auto cfg = adc.defaultConfig(RX_MODE);
cfg.copyFrom(info);
adc.begin(cfg);

void record_end(){
copier.end();
adc.end();
auto cfg = adc.defaultConfig(TX_MODE);
cfg.copyFrom(info);
adc.begin(cfg);

BR
Fredrik

[pschatzmann]

No you can't use the DAC and ADC at the same time!
You can use them in sequence but since audio requires a lot of space you need to store it on a SD drive or eventually PSRAM which will be filled quite quickly

[flows0247]

When i run record_start() and record_end() in sequence i get the following output:
SD_MMC Card Size: 971MB
Initialization done.
Recording...
[E] AnalogDriverESP32V1.h : 646 - perimanClearPinBus failed!
Playing...
Replay...
Replay...
E (8904) dac_continuous: dac_continuous_del_channels(298): dac continuous output not disabled yet
[E] AnalogDriverESP32V1.h : 478 - adc unit 0 continuous is already initialized. Please call end() first!
Recording...
E (11200) dac_continuous: dac_continuous_new_channels(211): DMA already in use
[E] AnalogDriverESP32V1.h : 448 - new_channels
Playing...
[E] AnalogDriverESP32V1.h : 478 - adc unit 0 continuous is already initialized. Please call end() first!
Recording...

It's playing the recorded sound the first time(but in higher speed) but not the following times.
It seems like the .end() function is failing to reset adc/dac and dma.
I'm very grateful for any suggestions on how I can proceed.
BR Fredrik

[pschatzmann]

I committed a correction. Can you double check ?

[flows0247]

Thank you for commiting!

It's still only playing the recorded sound the first time(but in higher speed) but not the following times.
The difference now is that i can hear low background noise when playing the recorded sound the second time and following times. Before there was complete silence in second time and follwing times play of the recorded sound.

Log:
Initialization done.
Recording...
[E] AnalogDriverESP32V1.h : 659 - perimanClearPinBus failed!
Playing...
Replay...
Replay...
Replay...
[E] AnalogDriverESP32V1.h : 476 - adc unit 0 continuous is already initialized. Please call end() first!
Recording...
Playing...

BR Fredrik

[pschatzmann]

Please share the sketch!

[flows0247]

Here is the sketch:

/**
 * @file streams-audiokit-sd-audiokit.ino
 * @author Phil Schatzmann
 * @brief We record the input from the microphone to a file and constantly repeat to play the file
 * The input is triggered by pressing key 1. Recording stops when key 1 is released!
 * @version 0.1
 * @date 2022-09-01
 * 
 * @copyright Copyright (c) 2022
 * 
 */
#include "AudioTools.h"
#include <SPI.h>
#include "FS.h"
#include "SD_MMC.h"


const char *file_name = "/rec.raw";
AudioInfo info(20050, 1, 16);
AnalogAudioStream adc; 
File file;   // final output stream
StreamCopy copier; // copies data
bool recording = false;  // flag to make sure that close is only executed one

 

void record_start(){
  copier.end();
  adc.end();
  auto cfg = adc.defaultConfig(RX_MODE);
  cfg.copyFrom(info);
  adc.begin(cfg);

  Serial.println("Recording...");
  file = SD_MMC.open(file_name, FILE_WRITE);
  copier.begin(file, adc);  
  recording = true; 
}

void record_end(){
  if (recording == true){
    copier.end();
    adc.end();
    auto cfg = adc.defaultConfig(TX_MODE);
    cfg.copyFrom(info);
    adc.begin(cfg);

    Serial.println("Playing...");
    file.close();
    recording = false;
    file = SD_MMC.open(file_name); // reopen in read mode
    copier.begin(adc, file);  // start playback
  }
}

void setup(){
  pinMode(15, INPUT_PULLUP);
  pinMode(2, INPUT_PULLUP);
  pinMode(4, INPUT_PULLUP);
  pinMode(12, INPUT_PULLUP);
  pinMode(13, INPUT_PULLUP);

  Serial.begin(115200);
  while(!Serial); 
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Warning);  

  if(!SD_MMC.begin()){
      Serial.println("Card Mount Failed");
      return;
  }
  uint64_t cardSize = SD_MMC.cardSize() / (1024 * 1024);
  Serial.printf("SD_MMC Card Size: %lluMB\n", cardSize);

  Serial.println("Initialization done.");
}

void loop(){
  copier.copy();  

  if (!recording && file.size()>0 && file.available()==0){
      file.seek(0);
      Serial.println("Replay...");
  }

  if (Serial.available() > 0) {
    char receivedChar = Serial.read();
    if (recording == true){
      record_end();
    }
    else{
      record_start();
    }
  }
}

[pschatzmann]

I have the impression that there is some strange bug in the Espressif code. I tried to circumvent it, and made sure that there are no errors any more. Could you retry if it is working now.

The following test sketch is running now w/o giving any errors:

#include "AudioTools.h"

AnalogAudioStream analog;

void setup() {
  Serial.begin(115200);
  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);
  for (int j = 0; j < 5; j++) {
    Serial.println("Recording...");
    assert(analog.begin(adc.defaultConfig(RX_MODE)));
    delay(1000);
    Serial.println("end...");
    analog.end();
    Serial.println("Playing...");
    assert(adc.begin(analog.defaultConfig(TX_MODE)));
    delay(1000);
    Serial.println("end...");
    analog.end();
  }
}

void loop() {
}

[flows0247]

Thank you very much! It is recording and playing now without errors!
I will play around with samplerates to try get normal speed playback.

[dkaukov]

@pschatzmann It seems like this approach is corrupting ConverterAutoCenter. As a quick workaround, I modified begin() to only recreate the converter if channels or bits_per_sample actually change:

void begin(int channels, int bitsPerSample, bool isDynamic = false) {
    if ((this->channels != channels) || (this->bits_per_sample != bitsPerSample)) { 
        this->channels = channels;
        this->bits_per_sample = bitsPerSample;
        if (p_converter != nullptr) delete p_converter;
        switch (bits_per_sample) {
            case 8:
                p_converter = new ConverterAutoCenterT<int8_t>(channels, isDynamic);
                break;
            case 16:
                p_converter = new ConverterAutoCenterT<int16_t>(channels, isDynamic);
                break;
            case 24:
                p_converter = new ConverterAutoCenterT<int24_t>(channels, isDynamic);
                break;
            case 32:
                p_converter = new ConverterAutoCenterT<int32_t>(channels, isDynamic);
                break;
        }
    }
}

This prevents unnecessary deletions and reallocation if nothing changes.