Justfile

default: dev

build:
    npm run build

# Fast local dev — skips fetch-data, assumes static/feeds and static/data are already present.
# Use this for hot-reload iteration. Run `just serve` once first to populate cached data.
# Pass extra args: `just dev --port 3001`
dev *ARGS:
    npx docusaurus start --host 0.0.0.0 {{ARGS}}

# Full start: fetch all data then launch dev server.
serve:
    npm run start

# Fetch all remote data (feeds, images, SBOMs, contributors, etc.)
fetch-data:
    npm run fetch-data

# Fetch SBOM attestation cache only (fast, use after SBOM pipeline updates)
fetch-sbom:
    npm run fetch-sbom

# Fetch image catalog (images.json) from GHCR + SBOM cache
fetch-images:
    npm run fetch-github-images

# Force-refresh image catalog regardless of cache age
fetch-images-force:
    npm run fetch-github-images -- --force

# Run TypeScript type check
typecheck:
    npm run typecheck

# Pre-commit gate per projectbluefin/common: typecheck + lint + unit tests
check: typecheck
    npm run lint
    npm test

# Clear Docusaurus build cache — fixes rspack "Dependency with ID not found" panics
clear:
    npx docusaurus clear

# Safe dev: clears rspack persistent cache first, then starts hot-reload server.
# Use this when dev crashes with signal 6 (SIGABRT) or "pack is released and deleted" errors.
# Pass extra args: `just dev-safe --port 3001`
dev-safe *ARGS:
    npx docusaurus clear
    npx docusaurus start --host 0.0.0.0 {{ARGS}}