meson.build

subdir('icons')
subdir('resources')
# Desktop file
desktop_conf = configuration_data()
desktop_conf.set('icon', application_id)
desktop_file = i18n.merge_file(
  type: 'desktop',
  input: configure_file(
    input: '@0@.desktop.in.in'.format(base_id),
    output: '@BASENAME@',
    configuration: desktop_conf
  ),
  output: '@0@.desktop'.format(application_id),
  po_dir: podir,
  install: true,
  install_dir: datadir / 'applications'
)
# Validate Desktop file
if desktop_file_validate.found()
  test(
    'validate-desktop',
    desktop_file_validate,
    args: [
      desktop_file.full_path()
    ],
    depends: desktop_file,
  )
endif

# Appdata
appdata_conf = configuration_data()
appdata_conf.set('app-id', application_id)
appdata_conf.set('gettext-package', gettext_package)
appdata_file = i18n.merge_file(
  input: configure_file(
    input: '@0@.metainfo.xml.in.in'.format(base_id),
    output: '@BASENAME@',
    configuration: appdata_conf
  ),
  output: '@0@.metainfo.xml'.format(application_id),
  po_dir: podir,
  install: true,
  install_dir: datadir / 'metainfo'
)
# Validate Appdata
if appstreamcli.found()
  test(
    'validate-appdata', appstreamcli,
    args: [
      'validate', '--no-net', '--explain', appdata_file.full_path()
    ],
    depends: appdata_file,
  )
endif

# GSchema
gschema_conf = configuration_data()
gschema_conf.set('app-id', application_id)
gschema_conf.set('gettext-package', gettext_package)
configure_file(
  input: '@0@.gschema.xml.in'.format(base_id),
  output: '@0@.gschema.xml'.format(application_id),
  configuration: gschema_conf,
  install: true,
  install_dir: datadir / 'glib-2.0' / 'schemas'
)

# Validate GSchema
if glib_compile_schemas.found()
  test(
    'validate-gschema', glib_compile_schemas,
    args: [
      '--strict', '--dry-run', meson.current_build_dir()
    ],
  )
endif

# DBus service
# install_data('net.nokyan.Resources.conf', install_dir : datadir / 'dbus-1' / 'system.d')

# systemd Service file
#service_conf = configuration_data()
#service_conf.set('bindir', bindir)
#configure_file(
#  input: '@0@.service.in'.format(base_id),
#  output: '@0@.service'.format(application_id),
#  configuration: service_conf,
#  install: true,
#  install_dir: prefix / 'lib' / 'systemd' / 'system'
#)

# polkit Policy file
policy_conf = configuration_data()
policy_conf.set('libexecdir', libexecdir)
policy_conf.set('gettext-package', gettext_package)
i18n.merge_file(
  input: configure_file(
    input: '@0@.policy.in.in'.format(base_id),
    output: '@BASENAME@',
    configuration: policy_conf,
  ),
  output: '@0@.policy'.format(application_id),
  po_dir: podir,
  data_dirs: podir,
  install: true,
  install_dir: datadir / 'polkit-1' / 'actions'
)