[BUG] neo-tree fails to open log file when checking build.tests

[0xda157]

Plugin

neo-tree

Nixpkgs Release

unstable

Home Manager Release

None

I have read the FAQ

• I have read the FAQ and my bug is not listed there.

Description

running nix flake check on the below flake with neo-tree enabled results in

ERROR: [Neo-tree WARN] Could not open log file: /build/.local/share/nvim/neo-tree.nvim.log /build/.local/share/nvim/neo-tree.nvim.log: No such file or directory

Minimal, Reproducible Example (MRE)

{
  inputs = {
    nixpkgs.follows = "nixvim/nixpkgs";

    nixvim.url = "github:nix-community/nixvim";
  };

  outputs =
    {
      self,
      nixpkgs,
      nixvim,
    }:
    let
      inherit (nixpkgs) lib;
      forEachPkgs = f: lib.genAttrs lib.systems.flakeExposed (system: f nixpkgs.legacyPackages.${system});
    in
    {
      checks = forEachPkgs (pkgs: {
        default =
          (nixvim.lib.evalNixvim {
            inherit (pkgs) system;
            modules = lib.singleton {
              plugins.neo-tree.enable = true;
            };
          }).config.build.test;
      });
    };
}

[GaetanLepage]

What happens here is that the test that you run starts a Neovim instance in the nix sandbox.
In this isolated environment, there is no home directory, so telescope will not be able to write its logfile to ~/.local/share/nvim/neo-tree.nvim.log.

This is the very reason why we set settings.log_to_file to false in our test suite:

nixvim/tests/test-sources/plugins/by-name/neo-tree/default.nix

Lines 8 to 11 in 7408b72

	# Otherwise fail at opening the log file
	# ERROR: [Neo-tree WARN] Could not open log file: /build/.local/share/nvim/neo-tree.nvim.log
	# /build/.local/share/nvim/neo-tree.nvim.log: No such file or directory
	settings.log_to_file = false;

[0xda157]

What happens here is that the test that you run starts a Neovim instance in the nix sandbox. In this isolated environment, there is no home directory, so telescope will not be able to write its logfile to ~/.local/share/nvim/neo-tree.nvim.log.

I am aware of this, I suppose I was wondering if there was a way to work around this e.g. disable writing to a log file only while running the tests, but that would kinda defeat the point of having tests. I guess the solutions are disable logging to a file or implement an option to not warn on readonly log file upstream while keeping the log file when it's writable.

[MattSturgeon]

disable writing to a log file only while running the tests

In the "legacy" nixvim world, we have lib.nixvim.enableExceptInTests. We haven't yet figured out how that should work with more idiomatic module-system usage, so it doesn't work well with the experimental flake-parts template style.

Essentially what you want is to use one nixvim configuration for your builds, then extend that configuration for your tests. Your extension can import modules that mkForce specific options that don't work well under test.

The idiomatic way is using extendModules:

let
  nixvimConfiguration = nixvim.lib.evalNixvim {
    inherit (pkgs) system;
    modules = lib.singleton {
      plugins.neo-tree.enable = true;
    };
  };
  testConfiguration = nixvimConfiguration.extendModules {
    modules = lib.singleton {
      # Otherwise fail at opening the log file 
      # ERROR: [Neo-tree WARN] Could not open log file: /build/.local/share/nvim/neo-tree.nvim.log 
      # /build/.local/share/nvim/neo-tree.nvim.log: No such file or directory 
      plugins.neo-tree.settings.log_to_file = false; 
    };
  };
in

I'm imagining we may be able to offer a test.extraModules option, and have the test.build option use an extended configuration internally. We could also preserve the old enableExceptInTests by overriding specialArgs.lib in that extension, but IDK how idiomatic that is... (The test option using an extension is possible because evalModules is available via module args).

[MattSturgeon]

disable writing to a log file only while running the tests

In the "legacy" nixvim world, we have lib.nixvim.enableExceptInTests. We haven't yet figured out how that should work with more idiomatic module-system usage, so it doesn't work well with the experimental flake-parts template style.

With #3952 merged, lib.nixvim.utils.enableExceptInTests should work in all scenarios. No need to manually extend.

I'd still like suggestions (ideas, discussions, issues, PRs) on better or more idiomatic approaches. Maybe a test.module (deferred module) option?