Add fnRegsFromStruct for comptime-generation of Lua function registrations

Author: nurpax

src/lib.zig

@@ -5408,3 +5408,38 @@ pub fn exportFn(comptime name: []const u8, comptime func: anytype) CFn {
         }
     }.luaopen;
 }
+
+/// Generates a list of Lua function registrations (`FnReg`) from all
+/// pub declarations in a struct type `T`.
+///
+/// Example:
+///
+/// ```zig
+/// const MyLib = struct {
+///     fn someHelper(...) { ... }   // non-pub funcs skipped
+///     pub fn foo(l: *Lua) void { ... }
+///     pub fn bar(l: *Lua) void { ... }
+///
+/// };
+///
+/// const funcs = fnRegsFromStruct(MyLib);
+/// lua.newLib(funcs);
+/// lua.setGlobal("mylib"); // mylib.foo, mylib.bar now visible
+/// ```
+pub inline fn fnRegsFromStruct(comptime T: type) []const FnReg {
+    comptime {
+        const decls = switch (@typeInfo(T)) {
+            .@"struct" => |info| info.decls,
+            else => @compileError("Expected struct, found '" ++ @typeName(T) ++ "'"),
+        };
+        var funcs: [decls.len]FnReg = undefined;
+        for (decls, 0..) |d, i| {
+            funcs[i] = .{
+                .name = d.name,
+                .func = wrap(@field(T, d.name)),
+            };
+        }
+        const final = funcs;
+        return &final;
+    }
+}

src/tests.zig

@@ -3093,3 +3093,29 @@ test "checkNumeric and toNumeric" {
         _ = std.mem.indexOf(u8, string, error_msg) orelse return error.BadErrorMessage;
     }
 }
+
+test "function registration with fnRegsFromStruct" {
+    const lua: *Lua = try .init(testing.allocator);
+    defer lua.deinit();
+
+    const MyLib = struct {
+        pub fn add(l: *Lua) i32 {
+            const a = l.toInteger(1) catch 0;
+            const b = l.toInteger(2) catch 0;
+            l.pushInteger(a + b);
+            return 1;
+        }
+        pub fn neg(l: *Lua) i32 {
+            const a = l.toInteger(1) catch 0;
+            l.pushInteger(-a);
+            return 1;
+        }
+    };
+
+    // Construct function registration table at comptime from
+    // public decls on MyLib.
+    lua.newLib(zlua.fnRegsFromStruct(MyLib));
+    lua.setGlobal("fnregs");
+    try lua.doString("res = fnregs.add(100, fnregs.neg(25))");
+    try expectEqual(75, lua.get(i32, "res"));
+}