musinsa_server/build.gradle at develop · molcham/musinsa_server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
plugins {
    id 'java'
    id 'org.springframework.boot' version '3.5.6'
    id 'io.spring.dependency-management' version '1.1.7'
    id 'jacoco'
}


group = 'com.musinsa'
version = '0.0.1-SNAPSHOT'
description = 'server'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    // Spring Boot Starters
    implementation "me.paulschwarz:spring-dotenv:4.0.0"
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-websocket'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'
    implementation 'org.springframework.boot:spring-boot-starter-batch'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'

    // MyBatis
    implementation 'org.mybatis.spring.boot:mybatis-spring-boot-starter:3.0.5'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'


    //QueryDSL
    implementation 'com.querydsl:querydsl-jpa:5.1.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:5.1.0:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    // Database
    runtimeOnly 'com.mysql:mysql-connector-j'

    // Jaeger
    implementation 'io.micrometer:micrometer-observation'
    implementation("io.micrometer:micrometer-tracing-bridge-otel")
    implementation("io.opentelemetry:opentelemetry-exporter-otlp")

    // Lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // JWT
    implementation 'io.jsonwebtoken:jjwt-api:0.12.6'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.12.6'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.12.6'

    // Swagger (SpringDoc OpenAPI)
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.7.0'

    // Test
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.mybatis.spring.boot:mybatis-spring-boot-starter-test:3.0.5'
    testImplementation 'org.springframework.security:spring-security-test'
    testImplementation 'org.springframework.batch:spring-batch-test'
    runtimeOnly 'com.h2database:h2'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    testImplementation 'org.reflections:reflections:0.10.2'

    // Test - Lombok
    testCompileOnly 'org.projectlombok:lombok'
    testAnnotationProcessor 'org.projectlombok:lombok'

    // https://mvnrepository.com/artifact/com.google.firebase/firebase-admin
    implementation 'com.google.firebase:firebase-admin:9.7.0'

    implementation platform("software.amazon.awssdk:bom:2.25.65") // 버전은 상황에 맞게
    implementation "software.amazon.awssdk:s3"

    // https://mvnrepository.com/artifact/com.squareup.okhttp3/okhttp
    implementation 'com.squareup.okhttp3:okhttp:5.2.1'
    implementation 'io.micrometer:micrometer-registry-prometheus'

    // broker test
    implementation 'org.springframework.kafka:spring-kafka'               // KafkaTemplate
    implementation 'org.springframework.boot:spring-boot-starter-amqp'    // AmqpTemplate (RabbitMQ)
    implementation 'org.springframework.boot:spring-boot-starter-reactor-netty'

    // redission (분산락)

    implementation 'org.redisson:redisson-spring-boot-starter:3.23.5'
}


jacoco {
    toolVersion = "0.8.13"
    reportsDirectory = layout.buildDirectory.dir('customJacocoReportDir')
}

tasks.named('test') {
    useJUnitPlatform()
    // ignoreFailures = true
    finalizedBy jacocoTestReport
}

def jacocoIncludes = ['com/mudosa/musinsa/product/**']
def jacocoExcludes = ['**/Q*.*']

jacocoTestReport {
    reports {
        xml.required = false
        csv.required = false
        html.outputLocation = layout.buildDirectory.dir('jacoco')
    }

    dependsOn test

    classDirectories.setFrom(
            files(classDirectories.files.collect { dir ->
                fileTree(
                        dir: dir,
                        include: jacocoIncludes,
                        exclude: jacocoExcludes
                )
            })
    )
}


jacocoTestCoverageVerification {

    classDirectories.setFrom(
            files(classDirectories.files.collect { dir ->
                fileTree(
                        dir: dir,
                        include: jacocoIncludes,
                        exclude: jacocoExcludes
                )
            })
    )

    violationRules {
        rule {
            enabled = true
            element = 'CLASS' // 클래스 단위 기준

            limit {
                counter = 'METHOD'
                value = 'COVEREDRATIO'
                minimum = 0.5
            }
        }
    }
}


clean {
    delete file('src/main/generated')
}