Add network % get_output() subroutine that returns a pointer to the outputs

Author: milancurcic

example/merge_networks.f90

@@ -5,7 +5,7 @@ program merge_networks
 
   type(network) :: net1, net2, net3
   real, allocatable :: x1(:), x2(:)
-  real, allocatable :: y1(:), y2(:)
+  real, pointer :: y1(:), y2(:)
   real, allocatable :: y(:)
   integer, parameter :: num_iterations = 500
   integer :: n, nn
@@ -44,19 +44,8 @@ program merge_networks
     call net2 % forward(x2)
 
     ! Get outputs of net1 and net2, concatenate, and pass to net3
-    ! A helper function could be made to take any number of networks
-    ! and return the concatenated output. Such function would turn the following
-    ! block into a one-liner.
-    select type (net1_output_layer => net1 % layers(size(net1 % layers)) % p)
-      type is (dense_layer)
-        y1 = net1_output_layer % output
-    end select
-
-    select type (net2_output_layer => net2 % layers(size(net2 % layers)) % p)
-      type is (dense_layer)
-        y2 = net2_output_layer % output
-    end select
-
+    call net1 % get_output(y1)
+    call net2 % get_output(y2)
     call net3 % forward([y1, y2])
 
     ! First compute the gradients on net3, then pass the gradients from the first

src/nf/nf_network.f90

@@ -33,6 +33,7 @@ module nf_network
     procedure, private :: forward_1d_int
     procedure, private :: forward_2d
     procedure, private :: forward_3d
+    procedure, private :: get_output_1d
     procedure, private :: predict_1d
     procedure, private :: predict_1d_int
     procedure, private :: predict_2d
@@ -42,6 +43,7 @@ module nf_network
 
     generic :: evaluate => evaluate_batch_1d
     generic :: forward => forward_1d, forward_1d_int, forward_2d, forward_3d
+    generic :: get_output => get_output_1d
     generic :: predict => predict_1d, predict_1d_int, predict_2d, predict_3d
     generic :: predict_batch => predict_batch_1d, predict_batch_3d
 
@@ -131,7 +133,7 @@ end subroutine forward_3d
 
   end interface forward
 
-  interface output
+  interface predict
 
     module function predict_1d(self, input) result(res)
       !! Return the output of the network given the input 1-d array.
@@ -169,9 +171,10 @@ module function predict_3d(self, input) result(res)
       real, allocatable :: res(:)
         !! Output of the network
     end function predict_3d
-  end interface output
 
-  interface output_batch
+  end interface predict
+
+  interface predict_batch
     module function predict_batch_1d(self, input) result(res)
       !! Return the output of the network given an input batch of 3-d data.
       class(network), intent(in out) :: self
@@ -191,7 +194,14 @@ module function predict_batch_3d(self, input) result(res)
       real, allocatable :: res(:,:)
         !! Output of the network; the last dimension is the batch
     end function predict_batch_3d
-  end interface output_batch
+  end interface predict_batch
+
+  interface get_output
+    module subroutine get_output_1d(self, output)
+      class(network), intent(in), target :: self
+      real, pointer, intent(out) :: output(:)
+    end subroutine get_output_1d
+  end interface get_output
 
   interface
 

src/nf/nf_network_submodule.f90

@@ -511,6 +511,28 @@ module subroutine print_info(self)
   end subroutine print_info
 
 
+  module subroutine get_output_1d(self, output)
+    class(network), intent(in), target :: self
+    real, pointer, intent(out) :: output(:)
+    integer :: last
+
+    last = size(self % layers)
+
+    select type(output_layer => self % layers(last) % p)
+      type is(dense_layer)
+        output => output_layer % output
+      type is(dropout_layer)
+        output => output_layer % output
+      type is(flatten_layer)
+        output => output_layer % output
+      class default
+        error stop 'network % get_output not implemented for ' // &
+          trim(self % layers(last) % name) // ' layer'
+    end select
+
+  end subroutine get_output_1d
+
+
   module function get_num_params(self)
     class(network), intent(in) :: self
     integer :: get_num_params