Repository navigation
Expand file tree
/
Copy pathCMakeLists.txt
More file actions
139 lines (123 loc) · 4.21 KB
/
Copy pathCMakeLists.txt
File metadata and controls
139 lines (123 loc) · 4.21 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
cmake_minimum_required(VERSION 3.12...3.31)
if (${CMAKE_VERSION} VERSION_GREATER_EQUAL "3.20")
cmake_policy(SET CMP0115 NEW)
endif()
if(NOT DEFINED SHOTCUT_VERSION)
string(TIMESTAMP SHOTCUT_VERSION "%y.%m.%d")
# Remove leading zeros from each digit group
string(REGEX REPLACE "0*([0-9]+)" "\\1" SHOTCUT_VERSION "${SHOTCUT_VERSION}")
endif()
project(shotcut
VERSION ${SHOTCUT_VERSION}
DESCRIPTION "cross-platform (Qt), open-source (GPLv3) video editor"
HOMEPAGE_URL "https://www.shotcut.org"
LANGUAGES CXX
)
if(WIN32)
option(WINDOWS_DEPLOY "Install exes/libs directly to prefix (no subdir /bin)" ON)
endif()
option(CLANG_FORMAT "Enable Clang Format" ON)
option(BUILD_DOCS "Build QDoc API documentation" OFF)
option(EXTERNAL_LAUNCHERS "Whether include features to launch external programs; for example, this should be off for Flatpak due to sandbox." ON)
option(USE_VULKAN "Whether to use Vulkan for hardware video decoding" OFF)
if (UNIX AND NOT APPLE)
option(BUILD_MINIMAL_MEDIA_BACKEND "Whether to build the `minimal` Qt media backend for Linux/BSD" OFF)
endif()
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
include(FeatureSummary)
set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)
set(CMAKE_AUTOUIC ON)
set(CMAKE_INCLUDE_CURRENT_DIR ON)
find_package(Qt6 6.4 REQUIRED
COMPONENTS
Charts
Multimedia
Network
OpenGL
OpenGLWidgets
QuickControls2
QuickWidgets
Sql
WebSockets
Widgets
Xml
)
if(Qt6_VERSION VERSION_GREATER_EQUAL "6.9.0")
find_package(Qt6 6.4 REQUIRED GuiPrivate)
endif()
if(UNIX AND NOT APPLE)
find_package(Qt6 6.4 REQUIRED COMPONENTS DBus)
# X11 for WindowPicker (Linux/X11)
find_package(X11 REQUIRED)
endif()
find_package(PkgConfig REQUIRED)
pkg_check_modules(mlt++ REQUIRED IMPORTED_TARGET mlt++-7>=7.36.0)
pkg_check_modules(FFTW IMPORTED_TARGET fftw3)
if(NOT FFTW_FOUND)
pkg_check_modules(FFTW REQUIRED IMPORTED_TARGET fftw)
endif()
add_subdirectory(CuteLogger)
add_subdirectory(src)
add_subdirectory(translations)
if(UNIX AND NOT APPLE AND BUILD_MINIMAL_MEDIA_BACKEND)
add_subdirectory(MinimalMediaBackend)
endif()
option(SHOTCUT_BUILD_TESTS "Build unit tests" OFF)
if(SHOTCUT_BUILD_TESTS)
enable_testing()
add_subdirectory(tests)
endif()
feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
add_custom_target(codespell COMMAND
cd "${CMAKE_SOURCE_DIR}" &&
codespell -w -q 3
-L shotcut,uint,seeked,really,prevent
-S export-chapters.js,export-edl.js,CuteLogger,drmingw,node_modules,moc_*,index.theme,*.ts,three.min.js,three.js,jquery.js,rangy-*.js,Makefile,shotcut.pro,*.desktop
)
if(CLANG_FORMAT)
# Formatting may change with different versions of clang-format.
# Test new versions before changing the allowed version here to avoid
# accidental broad changes to formatting.
find_package(ClangFormat 14 EXACT)
if(ClangFormat_FOUND)
file(GLOB_RECURSE FORMAT_FILES "src/*.h" "src/*.c" "src/*.cpp")
# exclude 3rd party & generated source from format checking
list(FILTER FORMAT_FILES EXCLUDE REGEX "/.*/spatialmedia/")
list(FILTER FORMAT_FILES EXCLUDE REGEX "/.*/defaultlayouts.h")
list(FILTER FORMAT_FILES EXCLUDE REGEX "/.*/*_autogen/")
add_custom_target(clang-format COMMAND
${CLANGFORMAT_EXECUTABLE} -style=file -i ${FORMAT_FILES}
)
add_custom_target(clang-format-check COMMAND
${CLANGFORMAT_EXECUTABLE} --dry-run --Werror -style=file -i ${FORMAT_FILES}
)
else()
set(CLANG_FORMAT OFF)
endif()
endif()
file(GLOB_RECURSE QML_SRC "src/qml/*.qml")
add_custom_target(qmlformat COMMAND
${CMAKE_PREFIX_PATH}/bin/qmlformat -i ${QML_SRC}
)
if(BUILD_DOCS)
find_program(QDOC_EXECUTABLE qdoc
PATHS
"${Qt6_DIR}/../../.."
"${CMAKE_PREFIX_PATH}"
PATH_SUFFIXES bin
)
if(NOT QDOC_EXECUTABLE)
message(FATAL_ERROR "qdoc not found. Install Qt documentation tools or set Qt6_DIR correctly.")
endif()
add_custom_target(docs
COMMAND ${CMAKE_COMMAND} -E remove_directory ${CMAKE_SOURCE_DIR}/docs/qml-api
COMMAND ${QDOC_EXECUTABLE} ${CMAKE_SOURCE_DIR}/docs/qml-api.qdocconf
WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
COMMENT "Generating QDoc API documentation"
VERBATIM
)
endif()