add Nix flake

this commit adds a Nix flake [1] into the repository. it contains
several notable things:

- llm-d-inference-sim as a Nix package
- inference-perf as a Nix package
- a venv-enabled dev shell containing python, pdm, pyright and
  llm-d-inference-sim

if Nix is present in your environment, you may enter the dev shell using
`nix develop` (requires flakes to be enabled).

the GitHub Actions uses this file to install the necessary dependencies
to run end-to-end tests.

[1]: https://wiki.nixos.org/wiki/Flakes

Author: diamondburned

flake.lock

@@ -0,0 +1,134 @@
+{
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
+    flake-parts.url = "github:hercules-ci/flake-parts";
+
+    pyproject-nix.url = "github:pyproject-nix/pyproject.nix";
+    pyproject-nix.inputs.nixpkgs.follows = "nixpkgs";
+
+    inference-perf.url = "github:kubernetes-sigs/inference-perf";
+    inference-perf.flake = false;
+  };
+
+  outputs =
+    {
+      self,
+      nixpkgs,
+      flake-parts,
+      pyproject-nix,
+      inference-perf,
+      ...
+    }@inputs:
+    flake-parts.lib.mkFlake { inherit inputs; } (
+      { config, ... }:
+      {
+        systems = [
+          "x86_64-linux"
+        ];
+        flake = {
+          lib = {
+            pyproject = pyproject-nix.lib.project.loadPyproject {
+              projectRoot = inference-perf;
+            };
+          };
+        };
+        perSystem =
+          { pkgs, self', ... }@systemInputs:
+          let
+            python = pkgs.python3;
+          in
+          {
+            devShells.default = pkgs.mkShell {
+              # PATH-only packages:
+              packages =
+                with pkgs;
+                with python3Packages;
+                with self'.packages;
+                [
+                  llm-d-inference-sim
+                  pdm
+
+                  # choose either python-lsp-server or pyright:
+                  basedpyright
+                  # python-lsp-server
+                  # pylsp-mypy
+                ];
+
+              buildInputs =
+                with pkgs;
+                with python3Packages;
+                [
+                  numpy
+                  torch
+                  venvShellHook
+                ];
+
+              venvDir = "venv";
+            };
+
+            packages = rec {
+              default = inference-perf;
+
+              inference-perf =
+                let
+                  buildAttrs = self.lib.pyproject.renderers.buildPythonPackage {
+                    inherit python;
+                  };
+                in
+                python.pkgs.buildPythonPackage (buildAttrs // { });
+
+              llm-d-inference-sim = pkgs.buildGoModule rec {
+                pname = "llm-d-inference-sim";
+                version = "0.6.1";
+
+                src = pkgs.fetchFromGitHub {
+                  owner = "llm-d";
+                  repo = "llm-d-inference-sim";
+                  tag = "v${version}";
+                  hash = "sha256-KdA7dgdy1jGjRhrqXfkg4Z9V3SXPcKp1FnTtm+e5DSA=";
+                };
+                vendorHash = "sha256-MINH7J2ozTORFK/KgZvXBlwThYRISL1wlHebdZxvuvw=";
+
+                nativeBuildInputs = with pkgs; [
+                  pkg-config
+                ];
+
+                buildInputs = with pkgs; [
+                  zeromq
+                  libtokenizers
+                ];
+
+                # several tests require networking.
+                doCheck = false;
+
+                meta = {
+                  description = "A light weight vLLM simulator, for mocking out replicas";
+                  homepage = "https://github.com/llm-d/llm-d-inference-sim";
+                  license = with nixpkgs.lib.licenses; asl20;
+                  mainProgram = "llm-d-inference-sim";
+                };
+              };
+
+              libtokenizers = pkgs.rustPlatform.buildRustPackage rec {
+                pname = "libtokenizers";
+                version = "1.22.1"; # keep same as llm-d-inference-sim's version
+
+                src = pkgs.fetchFromGitHub {
+                  owner = "daulet";
+                  repo = "tokenizers";
+                  tag = "v${version}";
+                  hash = "sha256-unGAXpD4GHWVFcXAwd0zU/u30wzH909tDcRYRPsSKwQ=";
+                };
+                cargoHash = "sha256-rY3YAcCbbx5CY6qu44Qz6UQhJlWVxAWdTaUSagHDn2o=";
+
+                meta = {
+                  description = "Go bindings for Tiktoken & HuggingFace Tokenizer";
+                  homepage = "https://github.com/daulet/tokenizers";
+                  license = with nixpkgs.lib.licenses; mit;
+                };
+              };
+            };
+          };
+      }
+    );
+}