build.gradle

/*
 * Copyright (c) 2021 Worksoft, Inc.
 *
 * gradle build
 *
 * @author rrinehart
 */

buildscript {
    // These are the list of remote repositories where Gradle Plugins can be found
    repositories {
        maven {
            url 'https://plugins.gradle.org/m2/'
        }
        // These are Gradle Plugins this build uses.  See also the plugins block below
        dependencies {
            classpath 'net.saliman:gradle-properties-plugin:1.5.1'
        }
    }
}

plugins {
    id 'groovy'
    id 'org.jenkins-ci.jpi' version '0.50.0'
    id 'com.github.onslip.gradle-one-jar' version '1.0.5'
}

apply plugin: 'maven-publish'
apply plugin: 'idea'

// Where to resolve external dependencies.
repositories {
    mavenCentral()
    maven {
        url('https://repo.jenkins-ci.org/public/')
    }
}

group = 'org.jenkins-ci.plugins'
//group = 'io.jenkins.plugins'
description = 'Adds build step(s) for interacting with Worksoft Continuous Test Manager.'

project.ext {
    buildUser = { ->
        return System.env.USERNAME
    }
}


apply plugin: 'net.saliman.properties'

jenkinsPlugin {
    //jenkinsVersion="${jenkinsBaseVersion}.${jenkinsPatchVersion}"
    jenkinsVersion="2.440.3"
    displayName = "Worksoft Continuous Test Manager Plugin"
    shortName = "ws-ctm"
    
    // URL for plugin on Jenkins wiki or elsewhere
    url = "https://github.com/jenkinsci/ws-ctm-plugin"

    repoUrl = 'https://repo.jenkins-ci.org/releases'
    snapshotRepoUrl = 'https://repo.jenkins-ci.org/snapshots'

    // enable injection of additional tests for checking the syntax of Jelly and other things
    disabledTestInjection = false

// disable configuration of Maven Central, the local Maven cache and the Jenkins Maven repository, defaults to true
    configureRepositories = false

    // skip configuration of publications and repositories for the Maven Publishing plugin, defaults to true
    configurePublishing = false

    // plugin file extension, either 'jpi' or 'hpi', defaults to 'hpi'
    fileExtension = 'hpi'

    developers {
        developer {
            id = "worksoft"
            name = "Worksoft, Inc."
            email = "jenkins-maintainers@worksoft.com"
        }
    }
    licenses {
        license {
            name = "MIT license"
            distribution "repo"
        }
    }
}

dependencies {
    api platform("io.jenkins.tools.bom:bom-2.440.x:${jenkinsBomVersion}")
    compileOnly  'org.jenkins-ci.plugins:credentials'   // This is should be change from "compileOnly" to "implementation" while building code locally
    compileOnly  'org.jenkins-ci.plugins:structs'       // This is should be change from "compileOnly" to "implementation" while building code locally
    implementation 'org.jodd:jodd-http:5.0.1'
    implementation "org.codehaus.groovy:groovy-all:${groovyVersion}"
    implementation 'com.github.jnr:jnr-ffi:2.2.17'
}


idea{
    module{
        inheritOutputDirs = false
        outputDir = compileJava.destinationDir
        testOutputDir = compileTestJava.destinationDir
    }
}

//compileJava {
//    options.compilerArgs << '-Xlint:deprecation'
//}

task listSrc(group: 'debugging', description: 'list project source') {
    doLast { task ->
        println "Project $task.project.name Source Sets:"

        task.project.sourceSets.each { srcSet ->
            println " - SourceSet: $srcSet.name"
            srcSet.allSource.each { file ->
                println "    - ${file}"
            }
        }
    }
}
// Below code should be uncomment while building code using gradle locally. 
/*
tasks.withType(Test).each { task ->
    task.enabled = false
}
*/
task listCompile(group: 'debugging', description: 'show compile configuration') {
    doLast {
        configurations.each { conf ->
            println "Configuration $conf"
            println "              $conf.allDependencies"
        }
    }
}

publishing {
        publications {
            maven(MavenPublication) {
                from components.java
            }
        }

        repositories {
            maven {
                name 'jenkins'
                if (project.version.toString().endsWith('-SNAPSHOT')) {
                    url System.properties['jpi.snapshotRepoUrl'] ?: 'https://repo.jenkins-ci.org/snapshots'
                } else {
                    url System.properties['jpi.repoUrl'] ?: 'https://repo.jenkins-ci.org/releases'
                }
                credentials {
                    //username = "notspecified"
                    //password = "notspecified"
                }
            }
        }
    }
//password = "hrBcJCotgbKEEp"
//username = project.stringProp(“jenkins.username”)
//password = project.stringProp(“jenkins.password”)

tasks.named('server').configure {
    execSpec {
        debugOptions {
            port.set(5005)
            suspend.set(false)
        }
    }
}