build.gradle

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'nexus-workflow'

ext.sha = 'git rev-parse --short HEAD'.execute().in.text.trim()

version = '0.1.1.' + (System.getenv("SNAP_PIPELINE_COUNTER") ?: sha)
project.group = 'org.javafunk'
archivesBaseName = "referee"

sourceCompatibility = '1.7'

defaultTasks('clean', 'test')

buildscript {
    repositories {
        maven  {
            url "http://repo1.maven.org/maven2"
        }
    }
    dependencies {
        classpath 'com.adaptc.gradle:nexus-workflow:0.6'
    }
}

repositories {
    maven  {
        url "http://repo1.maven.org/maven2"
    }
}

dependencies {
    compile 'org.javafunk.funk:funk:0.2.0.39'

    compile 'org.projectlombok:lombok:1.16.4'
    compile 'org.apache.commons:commons-lang3:3.4'

    testCompile 'org.yaml:snakeyaml:1.15'

    testCompile 'org.hamcrest:hamcrest-all:1.3'
    testCompile 'org.javafunk.matchbox:matchbox:0.1.5.2'
    testCompile 'org.testng:testng:6.8.21'
    testCompile 'junit:junit-dep:4.11'
    testCompile 'org.mockito:mockito-core:1.9.5'
}

project.tasks.withType(JavaCompile) {
    options.deprecation = true
    options.compilerArgs = ['-Xlint:none', '-Xlint:unchecked']
    options.fork(memoryMaximumSize: '1024m')
}

project.tasks.withType(Test) {
    minHeapSize = "2G"
    maxHeapSize = "2G"

    useTestNG {
        useDefaultListeners = true
    }

    testLogging {
        events 'failed', 'skipped'
    }
}

signing {
    sign configurations.archives
}

jar {
    manifest {
        attributes 'Implementation-Title': 'Referee', 'Implementation-Version': version
    }
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
    manifest {
        attributes 'Implementation-Title': 'Referee', 'Implementation-Version': version
    }
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
    manifest {
        attributes 'Implementation-Title': 'Referee', 'Implementation-Version': version
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '2.3'
}

artifacts {
    archives javadocJar, sourcesJar
}

uploadArchives {
    repositories {
        flatDir {
            dirs 'repos'
        }

        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(
                        userName: project.property("oss-releases.username"),
                        password: project.property("oss-releases.password"))
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(
                        userName: project.property("oss-releases.username"),
                        password: project.property("oss-releases.password"))
            }

            pom.project {
                name 'Referee'
                packaging 'jar'
                description 'Marshals between nested maps and Java object hierarchies.'
                url 'https://github.com/javafunk/referee'

                scm {
                    connection 'scm:git:git://github.com/javafunk/referee'
                    developerConnection 'scm:git:git://github.com/javafunk/referee/'
                    url 'https://github.com/javafunk/referee'
                }

                licenses {
                    license {
                        name 'BSD License'
                        url 'http://www.opensource.org/licenses/bsd-license.php'
                    }
                }

                developers {
                    developer {
                        id 'tobyclemson'
                        name 'Toby Clemson'
                        email 'tobyclemson@gmail.com'
                    }

                    developer {
                        id 'rafasf'
                        name 'Rafa Ferreira'
                        email 'rafaelsf@gmail.com'
                    }
                }
            }
        }
    }
}


idea {
    project {
        ipr {
            withXml {
                def ideaProject = it.asNode()

                // Automatically set up Git support
                ideaProject.append(node().component(name: 'VcsDirectoryMappings') {
                    mapping(directory: '$PROJECT_DIR$', vcs: 'Git')
                })

                // Turn on annotation processing
                ideaProject.component.find { it.@name == 'CompilerConfiguration' }['annotationProcessing'][0].replaceNode {
                    annotationProcessing {
                        profile(default: true, name: 'Default', useClasspath: 'true', enabled: true)
                    }
                }
            }
        }
    }
}

def node() {
    new NodeBuilder()
}