idorm-server/build.gradle at develop · idorm/idorm-server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
plugins {
    id 'org.springframework.boot' version '2.7.18'
    id 'io.spring.dependency-management' version '1.0.11.RELEASE'
    id 'java'
}

group = 'idorm'
version = '2.1.1-SNAPSHOT'
sourceCompatibility = '17'

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

jar {
    enabled = false
}

dependencies {
    // spring web
    implementation 'org.springframework.boot:spring-boot-starter-web'

    // spring data jpa
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'

    // spring database
    implementation 'org.springframework.boot:spring-boot-starter-data-jdbc'
    implementation 'org.springframework.boot:spring-boot-starter-jdbc'

    // spring validation
    implementation 'org.springframework.boot:spring-boot-starter-validation'

    // spring mail
    implementation 'org.springframework.boot:spring-boot-starter-mail'

    // spring security
    implementation 'org.springframework.boot:spring-boot-starter-security'

    // spring aop
    implementation 'org.springframework.boot:spring-boot-starter-aop'

    // sentry
    implementation 'io.sentry:sentry-spring-boot-starter:7.5.0'

    // crawling
    implementation 'org.jsoup:jsoup:1.15.3'

    // swagger ui
    implementation 'org.springdoc:springdoc-openapi-ui:1.7.0'

    // aws s3
    implementation 'com.amazonaws:aws-java-sdk-s3'
    implementation platform('com.amazonaws:aws-java-sdk-bom:1.11.1000')

    // fcm
    implementation 'com.google.firebase:firebase-admin:9.1.1'

    // jwt
    implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
    implementation 'io.jsonwebtoken:jjwt-impl:0.11.5'
    implementation 'io.jsonwebtoken:jjwt-jackson:0.11.5'

    // lombok
    annotationProcessor 'org.projectlombok:lombok'
    compileOnly 'org.projectlombok:lombok'

    // mysql
    runtimeOnly 'com.mysql:mysql-connector-j'

    // querydsl
    implementation "com.querydsl:querydsl-jpa"
    implementation "com.querydsl:querydsl-core"
    implementation "com.querydsl:querydsl-collections"
    annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jpa"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    // database migration
    implementation 'org.flywaydb:flyway-core:8.4.4'
    implementation 'org.flywaydb:flyway-mysql:8.4.4'

    // TODO: dev, prod 환경 반영 시 제거
    implementation 'com.github.gavlyukovskiy:p6spy-spring-boot-starter:1.5.8'

    // monitoring
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    runtimeOnly 'io.micrometer:micrometer-registry-prometheus'

    // spring test
    runtimeOnly 'com.h2database:h2'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

tasks.named('test') {
    useJUnitPlatform()
}

// Querydsl 설정 시작
def generated = 'src/main/generated'

tasks.withType(JavaCompile) {
    options.getGeneratedSourceOutputDirectory().set(file(generated))
}
sourceSets {
    main.java.srcDirs += [ generated ]
}
clean {
    delete file(generated)
}
// Querydsl 설정 끝

/**
 * 커맨드라인으로 주어진 파라미터로 도커 이미지 빌드 및 레지스트리 업로드를 설정합니다.
 */
bootBuildImage {
    imageName = "${project.findProperty("dockerImageName") ?: project.name}:${project.findProperty("dockerTag") ?: project.version}"

    if (project.findProperty("dockerUrl") != null) {
        print("[bootBuildImage] 이미지 이름: $imageName")
        publish = true
        docker {
            publishRegistry {
                url = project.findProperty("dockerUrl")
                username = project.findProperty("dockerUsername")
                password = project.findProperty("dockerPassword")
            }
        }
    }
}