build.gradle

apply plugin: 'java'
apply plugin: 'maven-publish'
apply plugin: 'signing'

group 'org.freeplane.bulenkov'
version '2021.7'

sourceCompatibility = 1.8
targetCompatibility = 1.8

tasks.withType(JavaCompile) { options.encoding = 'UTF-8' }

repositories {
  mavenCentral()
  flatDir { dirs 'libs' }
}

sourceSets {
  main.java.srcDirs = ['src']
  main.resources.srcDirs = ['res']
  test.java.srcDirs = ['test']
}

configurations { library }

jar { from { configurations.library.collect { it.isDirectory() ? it : zipTree(it) } } }


dependencies {
  library name: 'iconloader'
  library name: 'forms-rt-minimized'
  configurations.compileOnly.extendsFrom configurations.library
  implementation group: 'org.jetbrains', name: 'annotations', version: '16.0.1'
  testCompile group: 'junit', name: 'junit', version: '4.12'
}

task sourcesJar(type: Jar, dependsOn: classes) {
  classifier = 'sources'
  from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
  classifier = 'javadoc'
  from javadoc.destinationDir
}

publishing {
	publications {
		maven(MavenPublication.class) {
			from components.java
			groupId = group
			artifactId = project.name
			version = project.version
			artifact sourcesJar
			artifact javadocJar
            pom {
                name = project.name
                description = 'A darcula laf available on maven repositories'
                url = 'https://github.com/bulenkov/Darcula'

                scm {
                    url = 'https://github.com/freeplane/darcula'
                    connection = 'scm:git:https://github.com/freeplane/darcula.git'
                    developerConnection = 'scm:git:git@github.com:freeplane/darcula.git'
                }

                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer {
                        id = 'bulenkov'
                        name = 'Konstantin Bulenkov'
                        email = 'kb@jetbrains.com'
                    }
                    developer {
                        id = 'ice1000'
                        name = 'Tesla (Yinsen) Ice Zhang'
                        email = 'ice1000kotlin@foxmail.com'
                    }
                    developer {
                        id = 'dpolivaev'
                        name = 'Dimitry Polivaev'
                        email = 'dpolivaev@gmx.de'
                    }
                }
            }
 		}
	}
    repositories {
        maven {
            url = 'https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/'
            credentials {
                username ossrhUsername
                password ossrhPassword
            }
        }
        maven { 
			 url  = "${project.gradle.gradleUserHomeDir}/local-artifacts"
		}
    }
}
signing {
    sign publishing.publications.maven
}