Add fetch_server_status/1 (#9)

Author: aaronrenner

lib/web_driver_client.ex

@@ -16,6 +16,7 @@ defmodule WebDriverClient do
   alias WebDriverClient.KeyCodes
   alias WebDriverClient.LogEntry
   alias WebDriverClient.ProtocolMismatchError
+  alias WebDriverClient.ServerStatus
   alias WebDriverClient.Session
   alias WebDriverClient.Size
   alias WebDriverClient.UnexpectedResponseError
@@ -782,6 +783,31 @@ defmodule WebDriverClient do
     end
   end
 
+  @doc """
+  Fetches server status
+  """
+  @spec fetch_server_status(Config.t()) :: {:ok, ServerStatus.t()} | {:error, reason}
+  def fetch_server_status(%Config{protocol: protocol} = config) do
+    with {:ok, http_response} <-
+           send_request_for_protocol(protocol,
+             jwp: fn -> JWPCommands.FetchServerStatus.send_request(config) end,
+             w3c: fn -> W3CCommands.FetchServerStatus.send_request(config) end
+           ) do
+      parse_with_fallbacks(
+        http_response,
+        protocol,
+        [
+          jwp: &JWPCommands.FetchServerStatus.parse_response/1,
+          w3c: &W3CCommands.FetchServerStatus.parse_response/1
+        ],
+        fn
+          {:ok, server_status} -> {:ok, to_server_status(server_status)}
+          {:error, error} -> {:error, to_error(error)}
+        end
+      )
+    end
+  end
+
   @spec to_log_entry(JSONWireProtocolClient.LogEntry.t()) :: LogEntry.t()
   defp to_log_entry(%JSONWireProtocolClient.LogEntry{} = log_entry) do
     log_entry
@@ -810,6 +836,22 @@ defmodule WebDriverClient do
     |> (&struct!(Cookie, &1)).()
   end
 
+  @spec to_server_status(
+          W3CWireProtocolClient.ServerStatus.t()
+          | JSONWireProtocolClient.ServerStatus.t()
+        ) :: ServerStatus.t()
+  defp to_server_status(%JSONWireProtocolClient.ServerStatus{} = server_status) do
+    server_status
+    |> Map.from_struct()
+    |> (&struct!(ServerStatus, &1)).()
+  end
+
+  defp to_server_status(%W3CWireProtocolClient.ServerStatus{} = server_status) do
+    server_status
+    |> Map.from_struct()
+    |> (&struct!(ServerStatus, &1)).()
+  end
+
   defp to_error(%JSONWireProtocolClient.WebDriverError{reason: reason}) do
     reason =
       case reason do

lib/web_driver_client/json_wire_protocol_client.ex

@@ -20,6 +20,7 @@ defmodule WebDriverClient.JSONWireProtocolClient do
   alias WebDriverClient.JSONWireProtocolClient.Commands
   alias WebDriverClient.JSONWireProtocolClient.Cookie
   alias WebDriverClient.JSONWireProtocolClient.LogEntry
+  alias WebDriverClient.JSONWireProtocolClient.ServerStatus
   alias WebDriverClient.JSONWireProtocolClient.UnexpectedResponseError
   alias WebDriverClient.JSONWireProtocolClient.WebDriverError
   alias WebDriverClient.KeyCodes
@@ -529,4 +530,17 @@ defmodule WebDriverClient.JSONWireProtocolClient do
       :ok
     end
   end
+
+  @doc """
+  Fetches the current server status
+
+  Specification: https://github.com/SeleniumHQ/selenium/wiki/JsonWireProtocol#get-status
+  """
+  @spec fetch_server_status(Config.t()) :: {:ok, ServerStatus.t()} | {:error, basic_reason()}
+  def fetch_server_status(%Config{} = config) do
+    with {:ok, http_response} <- Commands.FetchServerStatus.send_request(config),
+         {:ok, server_status} <- Commands.FetchServerStatus.parse_response(http_response) do
+      {:ok, server_status}
+    end
+  end
 end

lib/web_driver_client/json_wire_protocol_client/commands/fetch_server_status.ex

@@ -0,0 +1,38 @@
+defmodule WebDriverClient.JSONWireProtocolClient.Commands.FetchServerStatus do
+  @moduledoc false
+
+  alias WebDriverClient.Config
+  alias WebDriverClient.ConnectionError
+  alias WebDriverClient.HTTPResponse
+  alias WebDriverClient.JSONWireProtocolClient.ResponseParser
+  alias WebDriverClient.JSONWireProtocolClient.ServerStatus
+  alias WebDriverClient.JSONWireProtocolClient.TeslaClientBuilder
+  alias WebDriverClient.JSONWireProtocolClient.UnexpectedResponseError
+  alias WebDriverClient.JSONWireProtocolClient.WebDriverError
+
+  @spec send_request(Config.t()) :: {:ok, HTTPResponse.t()} | {:error, ConnectionError.t()}
+  def send_request(%Config{} = config) do
+    client = TeslaClientBuilder.build_simple(config)
+
+    case Tesla.get(client, "/status") do
+      {:ok, env} ->
+        {:ok, HTTPResponse.build(env)}
+
+      {:error, reason} ->
+        {:error, reason}
+    end
+  end
+
+  @spec parse_response(HTTPResponse.t()) ::
+          {:ok, ServerStatus.t()} | {:error, UnexpectedResponseError.t() | WebDriverError.t()}
+  def parse_response(%HTTPResponse{} = http_response) do
+    # The spec says a 200 response indicates the server is ready (the "ready" key
+    # returned by some implementations doesn't matter). This implementation also ensures
+    # a valid jwp response and status code.
+
+    with {:ok, jwp_response} <- ResponseParser.parse_response(http_response),
+         :ok <- ResponseParser.ensure_successful_jwp_status(jwp_response) do
+      {:ok, %ServerStatus{ready?: true}}
+    end
+  end
+end

lib/web_driver_client/json_wire_protocol_client/server_status.ex

@@ -0,0 +1,14 @@
+# credo:disable-for-this-file Credo.Check.Readability.ModuleDoc
+import WebDriverClient.CompatibilityMacros
+
+defmodule WebDriverClient.JSONWireProtocolClient.ServerStatus do
+  prerelease_moduledoc """
+  A server status response
+  """
+
+  @type t :: %__MODULE__{
+          ready?: boolean
+        }
+
+  defstruct [:ready?]
+end

lib/web_driver_client/server_status.ex

@@ -0,0 +1,11 @@
+defmodule WebDriverClient.ServerStatus do
+  @moduledoc """
+  A server status response
+  """
+
+  @type t :: %__MODULE__{
+          ready?: boolean
+        }
+
+  defstruct [:ready?]
+end

lib/web_driver_client/w3c_wire_protocol_client.ex

@@ -23,6 +23,7 @@ defmodule WebDriverClient.W3CWireProtocolClient do
   alias WebDriverClient.W3CWireProtocolClient.Cookie
   alias WebDriverClient.W3CWireProtocolClient.LogEntry
   alias WebDriverClient.W3CWireProtocolClient.Rect
+  alias WebDriverClient.W3CWireProtocolClient.ServerStatus
   alias WebDriverClient.W3CWireProtocolClient.UnexpectedResponseError
   alias WebDriverClient.W3CWireProtocolClient.WebDriverError
 
@@ -517,4 +518,17 @@ defmodule WebDriverClient.W3CWireProtocolClient do
       :ok
     end
   end
+
+  @doc """
+  Fetches the server status
+
+  Specification: https://w3c.github.io/webdriver/#status
+  """
+  @spec fetch_server_status(Config.t()) :: {:ok, ServerStatus.t()} | {:error, basic_reason()}
+  def fetch_server_status(%Config{} = config) do
+    with {:ok, http_response} <- Commands.FetchServerStatus.send_request(config),
+         {:ok, server_status} <- Commands.FetchServerStatus.parse_response(http_response) do
+      {:ok, server_status}
+    end
+  end
 end

lib/web_driver_client/w3c_wire_protocol_client/commands/fetch_server_status.ex

@@ -0,0 +1,36 @@
+defmodule WebDriverClient.W3CWireProtocolClient.Commands.FetchServerStatus do
+  @moduledoc false
+
+  alias WebDriverClient.Config
+  alias WebDriverClient.ConnectionError
+  alias WebDriverClient.HTTPResponse
+  alias WebDriverClient.W3CWireProtocolClient.ResponseParser
+  alias WebDriverClient.W3CWireProtocolClient.ServerStatus
+  alias WebDriverClient.W3CWireProtocolClient.TeslaClientBuilder
+  alias WebDriverClient.W3CWireProtocolClient.UnexpectedResponseError
+  alias WebDriverClient.W3CWireProtocolClient.WebDriverError
+
+  @spec send_request(Config.t()) :: {:ok, HTTPResponse.t()} | {:error, ConnectionError.t()}
+  def send_request(%Config{} = config) do
+    client = TeslaClientBuilder.build_simple(config)
+    url = "/status"
+
+    case Tesla.get(client, url) do
+      {:ok, env} ->
+        {:ok, HTTPResponse.build(env)}
+
+      {:error, reason} ->
+        {:error, reason}
+    end
+  end
+
+  @spec parse_response(HTTPResponse.t()) ::
+          {:ok, ServerStatus.t()} | {:error, UnexpectedResponseError.t() | WebDriverError.t()}
+  def parse_response(%HTTPResponse{} = http_response) do
+    with {:ok, w3c_response} <- ResponseParser.parse_response(http_response),
+         :ok <- ResponseParser.ensure_successful_response(w3c_response),
+         {:ok, server_status} <- ResponseParser.parse_server_status(w3c_response) do
+      {:ok, server_status}
+    end
+  end
+end

lib/web_driver_client/w3c_wire_protocol_client/response_parser.ex

@@ -12,6 +12,7 @@ defmodule WebDriverClient.W3CWireProtocolClient.ResponseParser do
   alias WebDriverClient.W3CWireProtocolClient.LogEntry
   alias WebDriverClient.W3CWireProtocolClient.Rect
   alias WebDriverClient.W3CWireProtocolClient.Response
+  alias WebDriverClient.W3CWireProtocolClient.ServerStatus
   alias WebDriverClient.W3CWireProtocolClient.UnexpectedResponseError
   alias WebDriverClient.W3CWireProtocolClient.WebDriverError
 
@@ -182,6 +183,17 @@ defmodule WebDriverClient.W3CWireProtocolClient.ResponseParser do
     end
   end
 
+  @spec parse_server_status(Response.t()) ::
+          {:ok, ServerStatus.t()} | {:error, UnexpectedResponseError.t()}
+  def parse_server_status(%Response{body: %{"value" => %{"ready" => ready?}}})
+      when is_boolean(ready?) do
+    {:ok, %ServerStatus{ready?: ready?}}
+  end
+
+  def parse_server_status(%Response{body: body}) do
+    {:error, UnexpectedResponseError.exception(response_body: body)}
+  end
+
   defp do_parse_elements(elements) do
     elements
     |> Enum.reduce_while([], fn

lib/web_driver_client/w3c_wire_protocol_client/server_status.ex

@@ -0,0 +1,14 @@
+# credo:disable-for-this-file Credo.Check.Readability.ModuleDoc
+import WebDriverClient.CompatibilityMacros
+
+defmodule WebDriverClient.W3CWireProtocolClient.ServerStatus do
+  prerelease_moduledoc """
+  A server status response
+  """
+
+  @type t :: %__MODULE__{
+          ready?: boolean
+        }
+
+  defstruct [:ready?]
+end

mix.exs

@@ -67,6 +67,7 @@ defmodule WebDriverClient.MixProject do
           WebDriverClient.Element,
           WebDriverClient.LogEntry,
           WebDriverClient.ProtocolMismatchError,
+          WebDriverClient.ServerStatus,
           WebDriverClient.Session,
           WebDriverClient.Size,
           WebDriverClient.UnexpectedResponseError,

test/integration/status_test.exs

@@ -0,0 +1,35 @@
+defmodule WebDriverClient.Integration.StatusTest do
+  use ExUnit.Case, async: false
+
+  alias WebDriverClient.ConnectionError
+  alias WebDriverClient.IntegrationTesting.Scenarios
+  alias WebDriverClient.IntegrationTesting.TestGenerator
+  alias WebDriverClient.ProtocolMismatchError
+  alias WebDriverClient.ServerStatus
+
+  require TestGenerator
+
+  @moduletag :integration
+  @moduletag :capture_log
+
+  TestGenerator.generate_describe_per_scenario do
+    test "checking server status", %{scenario: scenario} do
+      config = Scenarios.get_config(scenario)
+
+      assert {:ok, %ServerStatus{ready?: true}} =
+               config
+               |> WebDriverClient.fetch_server_status()
+               |> unwrap_protocol_mismatch_error()
+
+      assert {:error, %ConnectionError{}} =
+               config
+               |> struct!(base_url: "http://does-not-exist-123")
+               |> WebDriverClient.fetch_server_status()
+    end
+  end
+
+  defp unwrap_protocol_mismatch_error({:error, %ProtocolMismatchError{response: response}}),
+    do: response
+
+  defp unwrap_protocol_mismatch_error(response), do: response
+end

test/support/json_wire_protocol_client/test_responses.ex

@@ -59,6 +59,15 @@ defmodule WebDriverClient.JSONWireProtocolClient.TestResponses do
     |> map(&Jason.encode!/1)
   end
 
+  def fetch_server_status_response do
+    one_of([
+      fixed_map(%{"ready" => boolean()}),
+      constant(%{})
+    ])
+    |> jwp_response()
+    |> map(&Jason.encode!/1)
+  end
+
   def end_session_response do
     nil
     |> jwp_response()

test/support/w3c_wire_protocol_client/test_responses.ex

@@ -72,6 +72,12 @@ defmodule WebDriverClient.W3CWireProtocolClient.TestResponses do
     |> map(&Jason.encode!/1)
   end
 
+  def fetch_server_status_response do
+    %{"value" => fixed_map(%{"ready" => boolean()})}
+    |> fixed_map()
+    |> map(&Jason.encode!/1)
+  end
+
   def end_session_response do
     constant(%{"value" => nil}) |> map(&Jason.encode!/1)
   end