dgd/ifd.nix at main · dnr/dgd · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
defaultArgs:

{
  src,
  vendorHash ? null,
  subPackage ? "", # relative to module, do not include "./" prefix
  pkgs ? defaultArgs.pkgs,
  go ? pkgs.go,
  # 2.32 isn't needed here, but for consistency:
  innerNix ? pkgs.nixVersions.nix_2_32,
  env ? { },
}:

let
  argenv = env;
  processBuild = pkgs.callPackage ./process-build/package.nix { };
in
let
  proxyenv = argenv // {
    CGO_ENABLED = argenv.CGO_ENABLED or go.CGO_ENABLED;
  };
  env = proxyenv // {
    GOPROXY = "off";
  };

  splitmodsjoin =
    if vendorHash == null then
      null
    else
      let
        modpkg = pkgs.runCommand "dgd-deps" {
          inherit src go;
          env = proxyenv;
          outputHash = vendorHash;
          outputHashMode = "recursive";
        } (builtins.readFile ./script/download.sh);

        splitmodnix = pkgs.runCommandLocal "dgd-split-deps.nix" {
          inherit modpkg innerNix;
        } (builtins.readFile ./script/split.sh);
      in
      builtins.trace "importing splitmodnix: ${splitmodnix}" import splitmodnix {
        inherit pkgs modpkg;
      };

  nixexpr = pkgs.runCommand "dgd-drv.nix" {
    inherit
      src
      env
      go
      processBuild
      splitmodsjoin
      subPackage
      ;
  } (builtins.readFile ./script/build-n.sh);

  drv = builtins.trace "importing build: ${nixexpr}" import nixexpr {
    srcStr = builtins.toString src;
    goStr = builtins.toString go;
    envJson = builtins.toJSON env;
    pkgsPath = builtins.toString pkgs.path;
  };
in
drv