pydantic-async-validation/justfile at main · ddanier/pydantic-async-validation · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
default:
    just --list

[unix]
_install-prek:
    #!/usr/bin/env bash
    if ( which prek > /dev/null 2>&1 )
    then
        prek install --prepare-hooks
    else
        echo "-----------------------------------------------------------------"
        echo "prek is not installed - cannot enable prek hooks!"
        echo "Recommendation: Install prek ('brew install prek')."
        echo "-----------------------------------------------------------------"
    fi

[windows]
_install-prek:
    #!powershell.exe
    Write-Host "Please ensure prek hooks are installed using 'prek install --prepare-hooks'"

install: (uv "sync" "--group" "dev" "--all-extras") && _install-prek

update: (uv "sync" "--group" "dev" "--all-extras")

uv *args:
    uv {{args}}

test *args: (uv "run" "pytest" "--cov=pydantic_async_validation" "--cov-report" "term-missing:skip-covered" args)

test-all: (uv "run" "tox")

ruff *args: (uv "run" "ruff" "check" "pydantic_async_validation" "tests" args)

pyright *args: (uv "run" "pyright" "pydantic_async_validation" args)

lint: ruff pyright

qa: lint test

qa-all: lint test-all

release version: (uv "version" version)
    git add pyproject.toml
    git commit -m "release: 🔖 v$(uv version --short)" --no-verify
    git tag "v$(uv version --short)"
    git push
    git push --tags

version-bump version_bump: (uv "version" "--bump" version_bump)
    git add pyproject.toml
    git commit -m "release: 🔖 v$(uv version --short)" --no-verify
    git tag "v$(uv version --short)"
    git push
    git push --tags