stats/authors-per-year.plot at master · curl/stats · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
# SVG output
load "stats/terminal.include"

# title
set title "Commit authors per year" font ",48"
# where's the legend
set key top left

# Identify the axes
#set xlabel "Years"
set ylabel "Number of humans"

# for the boxes
set boxwidth 0.8 relative
set style fill solid 0.5

set grid ytics
unset border

# time formated using this format
set timefmt "%Y-%m-%d"
set xdata time

load "stats/logo.include"

# set the format of the dates on the x axis
set format x "%Y"
set datafile separator ";"

# start Y at 0
set yrange [0:]

# the dates need to be manipulated as strings - you can't do numerical arithmetic on them.
# / Lee Philips

dayoffset = '30'
set xrange ["2009-06-".dayoffset:]
set xtics rotate time 1 years nomirror out
unset mxtics
set ytics nomirror

plot ARG1.'/authors-per-year.csv' using 1:2 with boxes title "All authors" fc 'green', ARG1.'/authors-per-year.csv' using (strcol(1)[1:8].dayoffset):3 with boxes title "First-time authors", \
 ARG1.'/authors-per-year.csv' using 1:2:2 with labels title "" offset 0,.5 font ", 20" tc lt 1