Function pattern doesn't work with exec.Run

[maxstepanov]

I'm using function pattern to run exec.Run and print the output but i get the default. I see that command runs but output is default.

You can see to "functions" _exec and _plain that i expect to return the same output but in_exec it doesn't unify with kind and default is used instead. I've spent hours trying to debug this with not success. I hope the community can help me out here.
Thanks in advance!

file: gen_tool.cue

package main

import (
	"tool/cli"
	"tool/exec"
)

_exec: {
	kind: string | *"some-default"

	_ex: exec.Run & {
		cmd: ["/bin/bash", "-c", "echo \(kind)"]
		stdout: string
	}
	result: _ex.stdout
}

_plain: {
	kind: string | *"some-default"
	result: kind
}

command: {
	generate: {
		printExec: cli.Print & {
			_res: (_exec & {kind: "value"}).result
			text: "Exec: \(_res)"
		}
		printPlain: cli.Print & {
			_res: (_plain & {kind: "value"}).result
			text: "Plain: \(_res)"
		}
	}
}

Output:

$ cue cmd -v generate
Plain: value #Works fine
Exec: some-default #Expected "value" but got the default

[infogulch]

One quirk about how cue cmd works is that each task you want to run has to have a unique path from command: to the task struct. If it's not actually present somewhere under command: then it cannot be run. This basically eliminates use of the function pattern for tasks entirely. And this is true for all tasks, not just exec.Run.

I think your example should work with something like this instead:

package main

import (
	"tool/cli"
	"tool/exec"
)

_exec: {
	kind: string | *"some-default"

	_ex: exec.Run & {
		cmd: ["/bin/bash", "-c", "echo \(kind)"]
		stdout: string
	}
	result: _ex.stdout
}

_plain: {
	kind: string | *"some-default"
	result: kind
}

command: {
	generate: {
		printExec: cli.Print & {
			_res_task: _exec & {kind: "value"} // I think this should work even though it's defined within another task
			text: "Exec: \(_res_task.result)"
		}
		printPlain: cli.Print & {
			_res_task: _plain & {kind: "value"}
			text: "Plain: \(_res_task.result)"
		}
	}
}

[maxstepanov]

Thanks @infogulch
sadly doesn't work :(
The thing is that command actually runs, I just can't get the concrete value from the commands .stdout :/

I've tried removing dynamic values, using aliases, having the function inside of command structure all kinds of variations i could come up with. No luck so far.

[myitcv]

As @infogulch alluded, the cue cmd workflow specification is a bit brittle in places. Noting #1325 as the tracking issue to fix/improve on that.

It appears that two things are proving to be your "undoing" here:

• the ().result pattern
• the use of _res to declare a task within the _printExec task

Consider the following fix (written as a testscript-txtar repro):

exec cue cmd generate
cmp stdout stdout.golden

-- fixed_tool.cue --
package main

import (
	"tool/cli"
	"tool/exec"
)

_exec: {
	kind: string | *"some-default"

	_ex: exec.Run & {
		cmd: ["/bin/bash", "-c", "echo \(kind)"]
		stdout: string
	}
	result: _ex.stdout
}

_plain: {
	kind:   string | *"some-default"
	result: kind
}

command: {
	generate: {
		_res: (_exec & {kind: "value"})
		printExec: cli.Print & {
			text: "Exec: \(_res.result)"
		}
		printPlain: cli.Print & {
			_res: (_plain & {kind: "value"})
			text: "Plain: \(_res.result)"
		}
	}
}
-- stdout.golden --
Plain: value
Exec: value

The diff with your original:

--- orig_tool.cue       2025-01-07 16:31:53.902985579 +0000
+++ fixed_tool.cue      2025-01-07 16:28:51.858517230 +0000
@@ -22,13 +22,13 @@

 command: {
        generate: {
+               _res: (_exec & {kind: "value"})
                printExec: cli.Print & {
-                       _res: (_exec & {kind: "value"}).result
-                       text: "Exec: \(_res)"
+                       text: "Exec: \(_res.result)"
                }
                printPlain: cli.Print & {
-                       _res: (_plain & {kind: "value"}).result
-                       text: "Plain: \(_res)"
+                       _res: (_plain & {kind: "value"})
+                       text: "Plain: \(_res.result)"
                }
        }
 }

[maxstepanov]

I understand what's the problem now! Restructured my code a bit and was able to incorporate this solution.
Thank you very much both of you!

[maxstepanov]

something like this, might be useful to somebody

package main

import (
	"tool/cli"
	"encoding/yaml"
	"encoding/json"
	"tool/exec"
)

workload: #Workload
command: {
	generate: {
		outputs: resources: {
			for name, res in workload.resources {
				(name): {
					_ex: exec.Run & {
						cmd: ["kubectl", "get", res.kind, "-o", "json"]
						stdout: string
					}
					krmObject: (json.Unmarshal(_ex.stdout)).items[0]
				}
			}
		}
		print: cli.Print & {
			text: yaml.Marshal(workload & outputs)
		}
	}
}