Add nvim-cmp support

Author: SevereOverfl0w

README.md

@@ -6,6 +6,7 @@ Provides async clojure completion for:
 * [ncm2][]
 * [asyncomplete.vim][]
 * [coc.nvim][]
+* [nvim-cmp][]
 
 Trying to use Fireplace's omnicompletion with auto-complete is painfully
 slow at times, making typing blocked. Using this module will be faster as
@@ -60,6 +61,19 @@ au User asyncomplete_setup call asyncomplete#register_source({
    Plug 'clojure-vim/async-clj-omni'
    ```
 
+### nvim-cmp
+
+1. Follow the install instructions for [nvim-cmp][].
+2. Add `{ name = 'async_clj_omni' }`, a complete example:
+   ```lua
+   cmp.setup({
+     sources = {
+       { name = 'async_clj_omni' },
+     }
+   })
+   ```
+3. Add `call async_clj_omni#cmp#register()` somewhere in your init.vim.
+
 ## Developing
 
 ### Deoplete
@@ -104,3 +118,4 @@ NVIM_PYTHON_LOG_FILE=logfile NVIM_PYTHON_LOG_LEVEL=DEBUG nvim
 [ncm2]: https://github.com/ncm2/ncm2
 [coc.nvim]: https://github.com/neoclide/coc.nvim
 [asyncomplete.vim]: https://github.com/prabirshrestha/asyncomplete.vim
+[nvim-cmp]: https://github.com/hrsh7th/nvim-cmp

autoload/async_clj_omni/cmp.vim

@@ -0,0 +1,65 @@
+let s:source = {}
+
+function! s:source.new() abort
+  return deepcopy(s:source)
+endfunction
+
+function! s:source.is_available()
+  if fireplace#op_available('complete')
+    return v:true
+  else
+    return v:false
+  endif
+endfunction
+
+function! s:source.get_keyword_pattern(params)
+  " Minimum 2 letters because completion on "y" doesn't resolve any
+  " namespaces, but "ya" will resolve on "yada".
+  return '\k\k\+'
+endfunction
+
+function! s:source.get_trigger_characters(params)
+  return ['/', '.', ':']
+endfunction
+
+" unfortunately f is for both function & static method.  to workaround, we'll
+" need to go to a lower level than fireplace#omnicomplete, which would lose us
+" the context of the completion from surrounding lines.
+let s:lsp_kinds = luaeval("
+\ (function()
+\  local cmp = require'cmp'
+\  return {f = cmp.lsp.CompletionItemKind.Function,
+\          m = cmp.lsp.CompletionItemKind.Function,
+\          v = cmp.lsp.CompletionItemKind.Variable,
+\          s = cmp.lsp.CompletionItemKind.Keyword,
+\          c = cmp.lsp.CompletionItemKind.Class,
+\          k = cmp.lsp.CompletionItemKind.Keyword,
+\          l = cmp.lsp.CompletionItemKind.Variable,
+\          n = cmp.lsp.CompletionItemKind.Module,
+\          i = cmp.lsp.CompletionItemKind.Field,
+\          r = cmp.lsp.CompletionItemKind.File,}
+\ end)()")
+
+function! s:coerce_to_lsp(vc)
+  return {'label': a:vc.word,
+        \ 'labelDetails': {
+        \   'detail': a:vc.menu,
+        \   },
+        \ 'documentation': a:vc.info,
+        \ 'kind': get(s:lsp_kinds, a:vc.kind, 1)
+        \ }
+endf
+
+function! s:source.complete(params, callback) abort
+  let l:kw = a:params.context.cursor_before_line[(a:params.offset-1):]
+
+  call fireplace#omnicomplete({candidates ->
+        \ a:callback(map(candidates,
+        \  {_, val -> s:coerce_to_lsp(val)}))
+        \ },
+        \ l:kw)
+endfunction
+
+function async_clj_omni#cmp#register()
+  call cmp#register_source('async_clj_omni', s:source.new())
+endf

plugin/cmp_fireplace.vim

@@ -0,0 +1,5 @@
+" cmp isn't guaranteed to be loaded before this file runs, which is why we
+" leave the option to manually register.
+if exists('*cmp#register_source')
+  call async_clj_omni#cmp#register()
+endif