don't raise SelectionChanged during parent-child synchronization

If a previously valid DateTime was selected (e.g. Jan 1 2019, 12:00AM), when
we change the DateTime interval (e.g. Jan 1 2020, 1:00AM - Dec 31 2020, 11:59PM)
to exclude the selection, Date selection is cleared but Time selection is not
cleared (remains 12:00AM) instead having TimePicker disabled.

When we make a new valid selection on Date (e.g. Jan 1 2020), since previously
selected Time (12:00AM) no longer falls within the interval (1:00AM - 11:59PM),
TimePicker, once received the updated interval, will clear the selected Time.
But between DateTimePicker updates Date selection and the updated interval
reaches TimePicker, there's a transient state of DateTimePicker
(Jan 1 2020, 12:00AM) that doesn't fall within the specified interval and thus
an incorrect value is raised through SelectionChanged.

We add isWithinInterval predicate and raiseSelectionChanged handler to prevent
this from happening.

Author: boygao1992

src/DateTimePicker.purs

@@ -17,6 +17,7 @@ module Ocelot.DateTimePicker
 import Prelude
 import Data.DateTime (Date, DateTime(..), Month, Time, Year)
 import Data.DateTime as Date.DateTime
+import Data.Foldable as Data.Foldable
 import Data.Maybe (Maybe(..))
 import Data.Maybe as Data.Maybe
 import Data.Tuple.Nested (type (/\))
@@ -107,14 +108,14 @@ handleAction :: forall m. Action -> ComponentM m Unit
 handleAction = case _ of
   HandleDate msg -> case msg of
     DatePicker.SelectionChanged date' -> do
-      time' <- H.gets _.time
-      H.raise $ SelectionChanged (DateTime <$> date' <*> time')
+      state <- H.get
+      raiseSelectionChanged state.interval date' state.time
       H.modify_ _ { date = date' }
     _ -> H.raise $ DateOutput msg
   HandleTime msg -> case msg of
     TimePicker.SelectionChanged time' -> do
-      date' <- H.gets _.date
-      H.raise $ SelectionChanged (DateTime <$> date' <*> time')
+      state <- H.get
+      raiseSelectionChanged state.interval state.date time'
       H.modify_ _ { time = time' }
     _ -> H.raise $ TimeOutput msg
   Receive input -> do
@@ -147,6 +148,32 @@ initialState input =
   , time: input.selection <#> Date.DateTime.time
   }
 
+-- check if a datetime is within a **closed** interval
+isWithinInterval :: Interval -> DateTime -> Boolean
+isWithinInterval interval x =
+  Data.Foldable.and
+    [ Data.Maybe.maybe true (_ <= x) interval.start
+    , Data.Maybe.maybe true (x <= _) interval.end
+    ]
+
+raiseSelectionChanged ::
+  forall m.
+  Maybe Interval ->
+  Maybe Date ->
+  Maybe Time ->
+  ComponentM m Unit
+raiseSelectionChanged mInterval mDate mTime = case mInterval of
+  Nothing -> H.raise $ SelectionChanged mDateTime
+  Just interval -> case mDateTime of
+    Nothing -> H.raise $ SelectionChanged mDateTime
+    Just dateTime
+      | isWithinInterval interval dateTime -> H.raise $ SelectionChanged mDateTime
+      | otherwise -> pure unit -- NOTE transient state during parent-child synchronization
+  where
+  mDateTime :: Maybe DateTime
+  mDateTime = DateTime <$> mDate <*> mTime
+
+
 render :: forall m. MonadAff m => ComponentRender m
 render state =
   HH.div