build.zig

const std = @import("std");

pub fn build(b: *std.Build) void {
    const upstream = b.dependency("argp-standalone", .{});
    const target = b.standardTargetOptions(.{});
    const optimize = b.standardOptimizeOption(.{});

    const linkage = b.option(std.builtin.LinkMode, "linkage", "Link mode") orelse .static;
    const strip = b.option(bool, "strip", "Omit debug information");
    const pic = b.option(bool, "pie", "Produce Position Independent Code");

    const is_gnu_lib_c_version_2_3 = target.result.isGnuLibC() and target.result.os.isAtLeast(.linux, .{ .major = 2, .minor = 3, .patch = 0 }) orelse false;

    const config_header = b.addConfigHeader(.{
        // Zig does not suport meson style config headers so it has been manually converted to cmake style.
        .style = .{ .cmake = b.path("config.h.in") },
    }, .{
        .HAVE_CONFIG_H = true,
        .HAVE_UNISTD_H = true,
        .HAVE_ALLOCA_H = target.result.os.tag != .windows,
        .HAVE_EX_USAGE = target.result.os.tag != .windows,
        .HAVE_DECL_FLOCKFILE = target.result.os.tag != .windows and target.result.os.tag != .wasi,
        .HAVE_DECL_FPUTS_UNLOCKED = false,
        .HAVE_DECL_FPUTC_UNLOCKED = target.result.os.tag != .windows and !target.result.os.tag.isDarwin(),
        .HAVE_DECL_FWRITE_UNLOCKED = target.result.os.tag != .windows and !target.result.os.tag.isDarwin(),
        .HAVE_DECL_PUTC_UNLOCKED = target.result.os.tag != .windows,
        .HAVE_MEMPCPY = target.result.os.tag == .windows,
        .HAVE_ASPRINTF = if (target.result.isGnuLibC())
            is_gnu_lib_c_version_2_3
        else
            target.result.os.tag != .windows,
        .HAVE_STRCHRNUL = is_gnu_lib_c_version_2_3,
        .HAVE_STRNDUP = if (target.result.isGnuLibC())
            is_gnu_lib_c_version_2_3
        else
            target.result.os.tag != .windows,
        .HAVE_DECL_PROGRAM_INVOCATION_NAME = false,
        .HAVE_DECL_PROGRAM_INVOCATION_SHORT_NAME = false,
    });
    const argp = b.addLibrary(.{
        .linkage = linkage,
        .name = "argp",
        .root_module = b.createModule(.{
            .target = target,
            .optimize = optimize,
            .strip = strip,
            .pic = pic,
            .link_libc = true,
        }),
    });
    b.installArtifact(argp);
    argp.installHeader(upstream.path("argp.h"), "argp.h");
    argp.root_module.addConfigHeader(config_header);
    argp.root_module.addCMacro("HAVE_CONFIG_H", "1");
    argp.root_module.addIncludePath(upstream.path(""));
    argp.root_module.addCSourceFiles(.{
        .root = upstream.path(""),
        .files = &.{
            "argp-ba.c",
            "argp-eexst.c",
            "argp-fmtstream.c",
            "argp-help.c",
            "argp-parse.c",
            "argp-pv.c",
            "argp-pvh.c",
        },
    });
    if (!config_header.values.get("HAVE_STRCHRNUL").?.boolean) argp.root_module.addCSourceFile(.{ .file = upstream.path("compat/strchrnul.c") });
    if (!config_header.values.get("HAVE_STRNDUP").?.boolean) argp.root_module.addCSourceFile(.{ .file = upstream.path("compat/strndup.c") });
    // if (!config_header.values.get("HAVE_STRCASECMP").?.boolean) argp.root_module.addCSourceFile(.{ .file = upstream.path("compat/strcasecmp.c") });
    if (!config_header.values.get("HAVE_MEMPCPY").?.boolean) argp.root_module.addCSourceFile(.{ .file = upstream.path("compat/mempcpy.c") });
}