build.gradle

buildscript {
    ext {
        depManagementVersion = "1.0.6.RELEASE"
        sonarqubeVersion = "2.7.1"
        coverallsVersion = "2.8.4"
    }

    repositories {
        mavenLocal()
        mavenCentral()
        jcenter()
        maven { url "https://plugins.gradle.org/m2/" }
    }

    dependencies {
        classpath "io.spring.gradle:dependency-management-plugin:${depManagementVersion}"
        classpath "org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:${sonarqubeVersion}"
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.+'
        classpath "gradle.plugin.com.github.kt3k.coveralls:coveralls-gradle-plugin:${coverallsVersion}"
    }
}

apply plugin: "org.sonarqube"

version '1.5.1'

allprojects {
    group = "com.github.swce"
    version = "1.5.1"
}

subprojects {
    apply plugin: "java"
    apply plugin: "io.spring.dependency-management"
    apply plugin: "jacoco"
    apply plugin: "com.github.kt3k.coveralls"

    sourceCompatibility = 1.8
    targetCompatibility = 1.8

    jacocoTestReport {
        reports {
            xml.enabled = true // coveralls plugin depends on xml format report
            html.enabled = true
        }
    }

    repositories {
        mavenLocal()
        mavenCentral()
        jcenter()
        maven { url "http://repo.maven.apache.org/maven2" }
    }

    dependencyManagement {
        imports {
            mavenBom "org.springframework.cloud:spring-cloud-dependencies:${spring_cloud_version}"
            mavenBom "org.springframework.boot:spring-boot-starter-parent:${spring_boot_version}"
        }
    }

    dependencies {
        compileOnly "org.projectlombok:lombok:${lombok_version}"
        annotationProcessor "org.projectlombok:lombok:${lombok_version}"

        testCompileOnly "org.projectlombok:lombok:${lombok_version}"
        testAnnotationProcessor "org.projectlombok:lombok:${lombok_version}"

        testCompile group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: junit_version
        testCompile group: 'org.junit.jupiter', name: 'junit-jupiter-params', version: junit_version
        testRuntime group: 'org.junit.jupiter', name: 'junit-jupiter-engine', version: junit_version
        testCompile(group: "org.springframework.boot", name: "spring-boot-starter-test", version: spring_boot_version) {
            exclude(module: "commons-logging")
        }
        testCompile group: "org.mockito", name: "mockito-core", version: "${mockito_version}"
    }
}

wrapper {
    gradleVersion = "4.10.3"
}