publish-mavencentral.gradle

apply plugin: 'maven'
apply plugin: 'signing'


ext["signing.keyId"] = ''
ext["signing.password"] = ''
ext["signing.secretKeyRingFile"] = ''
ext["ossrhUsername"] = ''
ext["ossrhPassword"] = ''

File secretPropsFile = project.rootProject.file('local.properties')
if (secretPropsFile.exists()) {
    println "Found secret props file, loading props"
    Properties p = new Properties()
    p.load(new FileInputStream(secretPropsFile))
    p.each { name, value ->
        ext[name] = value
    }
} else {
    println "No props file, loading env vars"
}


def PUBLISH_GROUP_ID = 'com.whatspos.sdk' //这里可以不是直接申请时候的groupId只要开头是就可以

def PUBLISH_ARTIFACT_ID = "emm-java-sdk"

def PUBLISH_VERSION = "1.0.0-SNAPSHOT"

// 当你发布的是一个纯java的依赖，那么就需要把下面的方法打开因为纯java的依赖，maven那边要求提供完整的javadoc，
// 但是aar不需要提供，也无法提供，因为下面的task javadocJar命令无法被识别
task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

//签名
signing {
    required { gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {

            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
            repository(url: "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            snapshotRepository(url: "https://s01.oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            pom.groupId = PUBLISH_GROUP_ID
            pom.artifactId = PUBLISH_ARTIFACT_ID
            pom.version = PUBLISH_VERSION

            pom.project {
                name 'emm-java-sdk'
                packaging 'jar' //我这里发布的是安卓的包，所有写的aar,如果你要发布纯jar包，那就写jar
                // optionally artifactId can be defined here
                description 'EMM JAVA SDK provides simple and easy-to-use service interfaces for third party developers to develop apps on PAXSTORE emm service.'
                url 'https://github.com/PAXSTORE/emm-java-sdk' // 修改这里为你要发布的项目地址

                    scm {
                    //修改成你的Git地址：
                    connection = 'scm:git:github.com/PAXSTORE/emm-java-sdk.git'
                    developerConnection = 'scm:git:ssh://github.com/PAXSTORE/emm-java-sdk.git'
                    //分支地址：
                    url = 'https://github.com/PAXSTORE/emm-java-sdk/tree/master'
                }

                licenses {
                    license {
                        name 'The Apache License, Version 2.0'
                        url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }

                developers {
                    developer { // 这里改成自己的信息
                        name 'Derek'
                        email 'paxstore-support@paxsz.com'
                    }
                }
            }
        }
    }
}