Add PythonCommandStringFactory

Author: akgrant43

src/PythonBridge/PBApplication.class.st

@@ -210,6 +210,11 @@ PBApplication >> newCommandFactory [
 	^ self executionHandler newCommandFactory
 ]
 
+{ #category : #'instance creation' }
+PBApplication >> newCommandStringFactory [
+	^ self executionHandler newCommandStringFactory
+]
+
 { #category : #instructions }
 PBApplication >> notifyDebuggerPaused: aDebugger [
 	"Notify all promises that the server debugger has paused in case the Bloc UI process is waiting on one of the promises."

src/PythonBridge/PBCommand.class.st

@@ -89,7 +89,7 @@ PBCommand >> promise: anObject [
 	promise := anObject
 ]
 
-{ #category : #'as yet unclassified' }
+{ #category : #accessing }
 PBCommand >> pythonCode [
 	| py3CodeStream |
 	py3CodeStream := String new writeStream.

src/PythonBridge/PBCommandString.class.st

@@ -0,0 +1,12 @@
+Class {
+	#name : #PBCommandString,
+	#superclass : #PBCommand,
+	#category : #'PythonBridge-Execution'
+}
+
+{ #category : #accessing }
+PBCommandString >> pythonCode [
+
+	^ instructions
+
+]

src/PythonBridge/PBCommandStringFactory.class.st

@@ -0,0 +1,100 @@
+"
+PBCommandStringFactory is variant of the command factory that takes two strings to build the set of statements:
+
+- script: a python script that will be evaluated on the remote.
+- resultExpression: a single python expression whose value will be returned.
+
+Note that PBCommandStringFactory no longer uses the instructions instance variable from ${class:name=PBCommandFactory}$.
+
+Example usage:
+
+[[[ 
+self application newCommandStringFactory
+	script: 
+'a = 4
+b = 3';
+	resultExpression: 'a + b';
+	sendAndWait
+]]]
+"
+Class {
+	#name : #PBCommandStringFactory,
+	#superclass : #PBCommandFactory,
+	#instVars : [
+		'script',
+		'resultExpression'
+	],
+	#category : #'PythonBridge-Execution'
+}
+
+{ #category : #streaming }
+PBCommandStringFactory >> << anObject [
+
+	self error: 'PBCommandStringFactory expects a single python script'
+]
+
+{ #category : #api }
+PBCommandStringFactory >> addAllBindings: aDictionary [
+	"Add the supplied key / value pairs as bindings to the receiver"
+
+	aDictionary keysAndValuesDo: [ :key :value |
+		self bindingAt: key put: value ]
+]
+
+{ #category : #streaming }
+PBCommandStringFactory >> append: aPythonStatement [
+
+	self error: 'PBCommandStringFactory expects a single python script'
+]
+
+{ #category : #accessing }
+PBCommandStringFactory >> instructionsWithNotifyAtEnd [
+
+	^ String streamContents: [ :stream |
+		stream 
+			<< script withUnixLineEndings;
+			lf;
+			<< 'notify(';
+			<< resultExpression;
+			<< ', ';
+			print: command id;
+			<< ')' ].
+
+]
+
+{ #category : #initialization }
+PBCommandStringFactory >> reset [
+	script := ''.
+	resultExpression := #None.
+	bindingsDictionary := Dictionary new.
+	observers := OrderedCollection new.
+	command := PBCommandString new.
+	transformBlock := #yourself
+]
+
+{ #category : #accessing }
+PBCommandStringFactory >> resultExpression [
+	<return: #String>
+
+	^ resultExpression
+]
+
+{ #category : #accessing }
+PBCommandStringFactory >> resultExpression: aString [
+
+	resultExpression := aString
+]
+
+{ #category : #accessing }
+PBCommandStringFactory >> script [
+	<return: #String>
+
+	^ script
+]
+
+{ #category : #accessing }
+PBCommandStringFactory >> script: aString [
+	"Set the Python script to be executed on the remote"
+
+	script := aString
+]

src/PythonBridge/PBCommandStringFactoryTest.class.st

@@ -0,0 +1,41 @@
+Class {
+	#name : #PBCommandStringFactoryTest,
+	#superclass : #TestCase,
+	#instVars : [
+		'factory'
+	],
+	#category : #'PythonBridge-Tests'
+}
+
+{ #category : #initialization }
+PBCommandStringFactoryTest >> setUp [
+	factory := PBCommandStringFactory new
+]
+
+{ #category : #tests }
+PBCommandStringFactoryTest >> testBuildEmptyCommand [
+	| command |
+	command := factory buildCommand.
+	self assert: command class equals: PBCommandString.
+	self assert: (command pythonCode trimLeft beginsWith: 'notify(None,').
+	self assert: command bindings isEmpty
+]
+
+{ #category : #tests }
+PBCommandStringFactoryTest >> testBuildFullCommand [
+	| command |
+
+	factory script: 'foo'.
+	factory bindingAt: #myVar put: 3.
+	command := factory buildCommand.
+	self assert: command pythonCode lines first equals: 'foo'.
+	self assert: (command bindingsDictionary at: #myVar) equals: 3
+]
+
+{ #category : #tests }
+PBCommandStringFactoryTest >> testBuildWithObservers [
+	| command |
+	factory observerFromCallback: [ 32 ].
+	command := factory buildCommand.
+	self assert: command observers first callback value equals: 32.
+]

src/PythonBridge/PBCommandStringTest.class.st

@@ -0,0 +1,30 @@
+Class {
+	#name : #PBCommandStringTest,
+	#superclass : #TestCase,
+	#category : #'PythonBridge-Tests'
+}
+
+{ #category : #tests }
+PBCommandStringTest >> testNewCommandHasEmtptyBindings [
+	| command |
+	command := PBCommandString new.
+	self assert: command id isString.
+	self assert: command id notEmpty.
+	self assert: command bindings equals: #().
+]
+
+{ #category : #tests }
+PBCommandStringTest >> testNotValidBindingsKeyNotString [
+	| command |
+	command := PBCommandString new.
+	command bindings: { 33 -> 'bar' }.
+	self deny: command isValid
+]
+
+{ #category : #tests }
+PBCommandStringTest >> testNotValidBindingsNotAssoc [
+	| command |
+	command := PBCommandString new.
+	command bindings: { '33' -> 'bar'. 'foo' }.
+	self deny: command isValid
+]

src/PythonBridge/PBExecutionHandler.class.st

@@ -67,6 +67,13 @@ PBExecutionHandler >> newCommandFactory [
 		yourself
 ]
 
+{ #category : #'as yet unclassified' }
+PBExecutionHandler >> newCommandStringFactory [
+	^ PBCommandStringFactory new
+		application: self application;
+		yourself
+]
+
 { #category : #handlers }
 PBExecutionHandler >> notifyCallbackHandler: msg [
 	| val serialization |

src/PythonBridge/PBObject.class.st

@@ -112,6 +112,12 @@ PBObject >> newCommandFactory [
 	^ self application newCommandFactory
 ]
 
+{ #category : #'instance creation' }
+PBObject >> newCommandStringFactory [
+
+	^ self application newCommandFactory
+]
+
 { #category : #'instance creation' }
 PBObject >> newPythonVar [
 	^ self class newPythonVar