ModAPI/build.gradle.kts at main · MCDiamondFire/ModAPI · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
import com.google.protobuf.gradle.id

plugins {
	id("java")
	alias(libs.plugins.protobuf)
    alias(libs.plugins.maven.publish)
}

group = project.property("GROUP").toString()
version = project.property("VERSION_NAME").toString()
val artifactId = project.property("POM_ARTIFACT_ID").toString()

base {
    archivesName.set(artifactId)
}

repositories {
	mavenCentral()
}

dependencies {
	implementation(libs.protobuf.java)
	implementation(libs.protobuf.java.util)
	implementation(libs.gson)

	implementation(libs.jspecify)
}

protobuf {
	// https://github.com/google/protobuf-gradle-plugin/blob/master/examples/exampleKotlinDslProject/build.gradle.kts
	protoc {
		artifact = libs.protoc.artifact.get().toString()
	}
	plugins {
		id("doc") {
			artifact = libs.protoc.gen.doc.artifact.get().toString()
		}
	}
	generateProtoTasks {
		ofSourceSet("main").forEach {
			it.plugins {
				id("doc") {
					option("markdown,docs/api/proto.md")
				}
			}
		}
	}
}

java {
	withJavadocJar()
	withSourcesJar()
}

tasks.withType<Jar> {
    // Exclude proto files.
    exclude("**/*.proto")
    includeEmptyDirs = false
}

tasks.matching { it.name == "plainJavadocJar" }.configureEach {
    enabled = false
}

tasks.withType<Javadoc> {
    options {
        val options = this as StandardJavadocDocletOptions
        options.addStringOption("Xdoclint:none", "-quiet") // Protobuf generates DocLint warnings.
    }
}

mavenPublishing {
    publishToMavenCentral()
    signAllPublications()

    coordinates(group.toString(), artifactId, version.toString())
}