mdiv.asm

global mdiv

section .text

; Function arguments for mdiv:
;   rdi - pointer to array x
;   rsi - value n (size of array x)
;   rdx - value y
mdiv:
    mov r9, rdx    ; Assign the value of y to r9
    mov r10, rdx   ; Assign the value of abs(y) to r10
    neg r10
    cmovs r10, rdx ; If y was positive, reassign y back to r10

    xor rdx, rdx   ; Clear rdx before performing division

    ; Assign the last element of array x to r8
    mov r8, [rdi + 8 * (rsi - 1)]

.set_rcx:
    mov rcx, rsi   ; rcx = n (size of array x)
    ; If the value is positive, jump to .loop
    test r8, r8
    jns .loop

; Loop to negate all elements of array x
.negate_loop:
    ; Negate the element in array x
    not qword [rdi + 8 * (rcx - 1)]

    loop .negate_loop

    mov rcx, rsi   ; Reset the rcx counter
    xor r11, r11   ; r11 is the counter for the .add_one loop, initialize it to zero

; Adding one to x
.add_one:
    ; Check if the loop should exit (counter equal to the size of array x)
    cmp r11, rsi
    je .if_sec_loop

    add qword [rdi + 8 * r11], 1
    inc r11
    jc .add_one    ; Continue loop if there was a carry

.if_sec_loop:
    test dl, dl    ; Check if this is the second invocation of the loop
    jnz .end       ; If it is, jump to .end

; Divide abs(x) by abs(y)
.loop:
    ; Assign the element of the array to rax
    mov rax, [rdi + 8 * (rcx - 1)]

    ; Perform division of rdx:rax by r10 - abs(y)
    div r10         ; Result of the division in rax, remainder in rdx

    ; Write the division result back to the array
    mov [rdi + 8 * (rcx - 1)], rax

    loop .loop

    ; Negate the remainder if the last element of the original array x was negative
    mov rax, rdx
    neg rdx        ; Negate the remainder
    test r8, r8
    cmovs rax, rdx ; If y was negative, move the negative remainder into rax
    mov dl, 1      ; Set the lowest 8 bits of rdx to 1

    ; Check if y is -1
    cmp r9, -1
    jnz .continue  ; If not, jump to .continue

    ; Check if the most significant bit of the last array element is set
    bt qword [rdi + 8 * (rsi - 1)], 63
    jnc .continue  ; If it is not set, jump to .continue

    ; Overflow occurred - trigger division by 0
    div cl         ; We know this register is zero because the .loop cleared it

.continue:
    ; Check if the elements of array x need to be negated
    xor r8, r9
    js .set_rcx

.end:
    ret