build.gradle

buildscript {
	repositories {
		jcenter()
		maven {
			name = 'lukflug'
			url = 'https://lukflug.github.io/maven/'
		}
		maven {
			name = 'SpongePowered'
			url = 'https://repo.spongepowered.org/repository/maven-public/'
		}
	}
	dependencies {
		classpath 'net.minecraftforge.gradle:ForgeGradle:2.3-SNAPSHOT'
		classpath 'org.spongepowered:mixingradle:0.4-SNAPSHOT'
		classpath 'com.github.jengelman.gradle.plugins:shadow:1.2.3'
	}
}

apply plugin: 'net.minecraftforge.gradle.forge'
apply plugin: 'org.spongepowered.mixin'
apply plugin: 'com.github.johnrengelman.shadow'

version project.modVersion
group project.modGroup

compileJava {
	sourceCompatibility = targetCompatibility = JavaVersion.VERSION_1_8
}

minecraft {
	version = project.forgeVersion
	runDir = 'run'
	mappings = project.mcpVersion
	coreMod = 'com.gamesense.mixin.GameSenseMixinLoader'
	makeObfSourceJar = false
}

repositories {
	maven {
		name = 'spongepowered-repo'
		url = 'https://repo.spongepowered.org/repository/maven-public/'
	}
	maven {
		name = 'impactdevelopment-repo'
		url = 'https://impactdevelopment.github.io/maven/'
	}
	maven {
		name = 'swt-repo'
		url = "https://maven-eclipse.github.io/maven"
	}
	maven {
		name = 'jitpack.io'
		url = "https://jitpack.io"
	}
	maven {
		name = 'lukflug'
		url = 'https://lukflug.github.io/maven'
	}
	mavenCentral()
}

dependencies {
	compile('org.spongepowered:mixin:0.7.4-SNAPSHOT') {
		exclude module: 'launchwrapper'
		exclude module: 'guava'
		exclude module: 'gson'
		exclude module: 'commons-io'
	}
	compile 'com.github.ZeroMemes:Alpine:1.5'
	compile group: 'net.jodah', name: 'typetools', version: '0.5.0'
	compile group: 'com.googlecode.json-simple', name: 'json-simple', version: '1.1.1'
	compile group: 'club.minnced', name: 'java-discord-rpc', version: '2.0.1'
	compile('com.lukflug:panelstudio:0.1.8')
	compile('com.lukflug:panelstudio-mc12:0.1.8')
}

processResources {
	inputs.property 'version', project.version
	inputs.property 'mcversion', project.minecraft.version

	from(sourceSets.main.resources.srcDirs) {
		include 'mcmod.info'
		expand 'version': project.version, 'mcversion': project.minecraft.version
	}

	from(sourceSets.main.resources.srcDirs) {
		exclude 'mcmod.info'
	}

	rename '(.+_at.cfg)', 'META-INF/$1'
}

shadowJar {
	dependencies {
		include(dependency('org.spongepowered:mixin'))
		include(dependency('com.github.ZeroMemes:Alpine'))
		include(dependency('net.jodah:typetools'))
		include(dependency('com.googlecode.json-simple:json-simple:1.1.1'))
		include(dependency('club.minnced:java-discord-rpc:2.0.1'))
		include(dependency('com.lukflug:panelstudio'))
		include(dependency('com.lukflug:panelstudio-mc12'))
	}
	exclude 'dummyThing'
	exclude 'LICENSE.txt'
	classifier = 'release'
}

mixin {
	defaultObfuscationEnv searge
	add sourceSets.main, 'mixins.gamesense.refmap.json'
}

reobf {
	shadowJar {
		mappingType = 'SEARGE'
		classpath = sourceSets.main.compileClasspath
	}
}

jar {
	manifest {
		attributes(
				'MixinConfigs': 'mixins.gamesense.json',
				'tweakClass': 'org.spongepowered.asm.launch.MixinTweaker',
				'TweakOrder': 0,
				'FMLCorePluginContainsFMLMod': 'true',
				'FMLCorePlugin': 'com.gamesense.mixin.GameSenseMixinLoader',
				'ForceLoadAsMod': 'true',
				'FMLAT': 'gamesense_at.cfg'
		)
	}
}

build.dependsOn(shadowJar)