build.gradle

plugins {
    id 'base'
    id 'org.springframework.boot' version '4.0.2' apply false
    id 'io.spring.dependency-management' version '1.1.7' apply false
}

group = 'me.go-gradually'
version = '0.0.1-SNAPSHOT'

allprojects {
    repositories {
        mavenCentral()
    }
}

subprojects {
    apply plugin: 'java-library'
    apply plugin: 'io.spring.dependency-management'

    group = rootProject.group
    version = rootProject.version

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(21)
        }
    }

    configurations {
        compileOnly {
            extendsFrom annotationProcessor
        }
    }

    dependencyManagement {
        imports {
            mavenBom org.springframework.boot.gradle.plugin.SpringBootPlugin.BOM_COORDINATES
        }
    }

    dependencies {
        compileOnly 'org.projectlombok:lombok'
        annotationProcessor 'org.projectlombok:lombok'
        testCompileOnly 'org.projectlombok:lombok'
        testAnnotationProcessor 'org.projectlombok:lombok'
        testImplementation 'org.springframework.boot:spring-boot-starter-test'
        testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    }

    tasks.named('test') {
        useJUnitPlatform()
    }
}

project(':bootstrap') {
    apply plugin: 'org.springframework.boot'

    tasks.named('jar') {
        enabled = false
    }
}

tasks.named('clean') {
    dependsOn(subprojects.collect { "${it.path}:clean" })
}

tasks.named('build') {
    dependsOn(subprojects.collect { "${it.path}:build" })
}

tasks.register('test') {
    group = 'verification'
    dependsOn(subprojects.collect { "${it.path}:test" })
}

tasks.register('bootRun') {
    group = 'application'
    dependsOn(':bootstrap:bootRun')
}

tasks.register('bootJar') {
    group = 'build'
    dependsOn(':bootstrap:bootJar')
}