CMakeTOPSInformation.cmake

#
# Copyright 2020-2022 Enflame. All Rights Reserved.
#
if(UNIX)
  set(CMAKE_TOPS_OUTPUT_EXTENSION .o)
else()
  set(CMAKE_TOPS_OUTPUT_EXTENSION .obj)
endif()
set(CMAKE_INCLUDE_FLAG_TOPS "-I")

# Set implicit links early so compiler-specific modules can use them.
set(__IMPLICIT_LINKS)
foreach(dir ${CMAKE_TOPS_HOST_IMPLICIT_LINK_DIRECTORIES})
  string(APPEND __IMPLICIT_LINKS " -L\"${dir}\" -rpath \"${dir}\"")
endforeach()
foreach(lib ${CMAKE_TOPS_HOST_IMPLICIT_LINK_LIBRARIES})
  if(${lib} MATCHES "/")
    string(APPEND __IMPLICIT_LINKS " \"${lib}\"")
  else()
    string(APPEND __IMPLICIT_LINKS " -l${lib}")
  endif()
endforeach()


# Load compiler-specific information.
if(CMAKE_TOPS_COMPILER_ID)
  include(Compiler/${CMAKE_TOPS_COMPILER_ID}-TOPS OPTIONAL)
endif()


# This should be included before the _INIT variables are
# used to initialize the cache.  Since the rule variables
# have if blocks on them, users can still define them here.
# But, it should still be after the platform file so changes can
# be made to those values.

if(CMAKE_USER_MAKE_RULES_OVERRIDE)
  # Save the full path of the file so try_compile can use it.
  include(${CMAKE_USER_MAKE_RULES_OVERRIDE} RESULT_VARIABLE _override)
  set(CMAKE_USER_MAKE_RULES_OVERRIDE "${_override}")
endif()

if(CMAKE_USER_MAKE_RULES_OVERRIDE_TOPS)
  # Save the full path of the file so try_compile can use it.
  include(${CMAKE_USER_MAKE_RULES_OVERRIDE_TOPS} RESULT_VARIABLE _override)
  set(CMAKE_USER_MAKE_RULES_OVERRIDE_TOPS "${_override}")
endif()


if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_TOPS_FLAG)
  set(CMAKE_SHARED_LIBRARY_RUNTIME_TOPS_FLAG ${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG})
endif()

if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_TOPS_FLAG_SEP)
  set(CMAKE_SHARED_LIBRARY_RUNTIME_TOPS_FLAG_SEP ${CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG_SEP})
endif()

if(NOT CMAKE_SHARED_LIBRARY_RPATH_LINK_TOPS_FLAG)
  set(CMAKE_SHARED_LIBRARY_RPATH_LINK_TOPS_FLAG ${CMAKE_SHARED_LIBRARY_RPATH_LINK_C_FLAG})
endif()

if(NOT DEFINED CMAKE_EXE_EXPORTS_TOPS_FLAG)
  set(CMAKE_EXE_EXPORTS_TOPS_FLAG ${CMAKE_EXE_EXPORTS_C_FLAG})
endif()

if(NOT DEFINED CMAKE_SHARED_LIBRARY_SONAME_TOPS_FLAG)
  set(CMAKE_SHARED_LIBRARY_SONAME_TOPS_FLAG ${CMAKE_SHARED_LIBRARY_SONAME_C_FLAG})
endif()

if(NOT CMAKE_EXECUTABLE_RUNTIME_TOPS_FLAG)
  set(CMAKE_EXECUTABLE_RUNTIME_TOPS_FLAG ${CMAKE_SHARED_LIBRARY_RUNTIME_TOPS_FLAG})
endif()

if(NOT CMAKE_EXECUTABLE_RUNTIME_TOPS_FLAG_SEP)
  set(CMAKE_EXECUTABLE_RUNTIME_TOPS_FLAG_SEP ${CMAKE_SHARED_LIBRARY_RUNTIME_TOPS_FLAG_SEP})
endif()

if(NOT CMAKE_EXECUTABLE_RPATH_LINK_TOPS_FLAG)
  set(CMAKE_EXECUTABLE_RPATH_LINK_TOPS_FLAG ${CMAKE_SHARED_LIBRARY_RPATH_LINK_TOPS_FLAG})
endif()

if(NOT DEFINED CMAKE_SHARED_LIBRARY_LINK_TOPS_WITH_RUNTIME_PATH)
  set(CMAKE_SHARED_LIBRARY_LINK_TOPS_WITH_RUNTIME_PATH ${CMAKE_SHARED_LIBRARY_LINK_C_WITH_RUNTIME_PATH})
endif()


# for most systems a module is the same as a shared library
# so unless the variable CMAKE_MODULE_EXISTS is set just
# copy the values from the LIBRARY variables
if(NOT CMAKE_MODULE_EXISTS)
  set(CMAKE_SHARED_MODULE_TOPS_FLAGS ${CMAKE_SHARED_LIBRARY_TOPS_FLAGS})
  set(CMAKE_SHARED_MODULE_CREATE_TOPS_FLAGS ${CMAKE_SHARED_LIBRARY_CREATE_TOPS_FLAGS})
endif()

if(CMAKE_EXECUTABLE_FORMAT STREQUAL "ELF")
  if(NOT DEFINED CMAKE_TOPS_LINK_WHAT_YOU_USE_FLAG)
    set(CMAKE_TOPS_LINK_WHAT_YOU_USE_FLAG "LINKER:--no-as-needed")
  endif()
  if(NOT DEFINED CMAKE_LINK_WHAT_YOU_USE_CHECK)
    set(CMAKE_LINK_WHAT_YOU_USE_CHECK ldd -u -r)
  endif()
endif()

# add the flags to the cache based
# on the initial values computed in the platform/*.cmake files
# use _INIT variables so that this only happens the first time
# and you can set these flags in the cmake cache
set(CMAKE_TOPS_FLAGS_INIT "$ENV{TOPSFLAGS} ${CMAKE_TOPS_FLAGS_INIT}")

cmake_initialize_per_config_variable(CMAKE_TOPS_FLAGS "Flags used by the TOPS compiler")

if(CMAKE_TOPS_STANDARD_LIBRARIES_INIT)
  set(CMAKE_TOPS_STANDARD_LIBRARIES "${CMAKE_TOPS_STANDARD_LIBRARIES_INIT}"
    CACHE STRING "Libraries linked by default with all TOPS applications.")
  mark_as_advanced(CMAKE_TOPS_STANDARD_LIBRARIES)
endif()

if(NOT CMAKE_TOPS_COMPILER_LAUNCHER AND DEFINED ENV{CMAKE_TOPS_COMPILER_LAUNCHER})
  set(CMAKE_TOPS_COMPILER_LAUNCHER "$ENV{CMAKE_TOPS_COMPILER_LAUNCHER}"
    CACHE STRING "Compiler launcher for TOPS.")
endif()

set(CMAKE_TOPS_COMPILE_OPTIONS_PIC "-fPIC")
set(CMAKE_TOPS_COMPILE_OPTIONS_PIE "-fPIE")
set(_CMAKE_TOPS_PIE_MAY_BE_SUPPORTED_BY_LINKER YES)
set(CMAKE_TOPS_LINK_OPTIONS_PIE "-fPIE")
set(CMAKE_TOPS_LINK_OPTIONS_NO_PIE "")
set(CMAKE_SHARED_LIBRARY_TOPS_FLAGS "-fPIC")
set(CMAKE_SHARED_LIBRARY_CREATE_TOPS_FLAGS "-shared")
set(CMAKE_SHARED_LIBRARY_LINK_TOPS_FLAGS "")

include(CMakeCommonLanguageInclude)

# now define the following rules:
# CMAKE_TOPS_CREATE_SHARED_LIBRARY
# CMAKE_TOPS_CREATE_SHARED_MODULE
# CMAKE_TOPS_COMPILE_WHOLE_COMPILATION
# CMAKE_TOPS_COMPILE_PTX_COMPILATION
# CMAKE_TOPS_COMPILE_SEPARABLE_COMPILATION
# CMAKE_TOPS_LINK_EXECUTABLE

# create a shared library
if(NOT CMAKE_TOPS_CREATE_SHARED_LIBRARY)
  set(CMAKE_TOPS_CREATE_SHARED_LIBRARY
      "<CMAKE_TOPS_COMPILER> <CMAKE_SHARED_LIBRARY_TOPS_FLAGS> <LINK_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_TOPS_FLAGS> <SONAME_FLAG><TARGET_SONAME> -o <TARGET> <OBJECTS> <LINK_LIBRARIES>${__IMPLICIT_LINKS}")
endif()

# create a shared module copy the shared library rule by default
if(NOT CMAKE_TOPS_CREATE_SHARED_MODULE)
  set(CMAKE_TOPS_CREATE_SHARED_MODULE ${CMAKE_TOPS_CREATE_SHARED_LIBRARY})
endif()

# Create a static archive incrementally for large object file counts.
if(NOT DEFINED CMAKE_TOPS_ARCHIVE_CREATE)
  set(CMAKE_TOPS_ARCHIVE_CREATE "<CMAKE_AR> qc <TARGET> <LINK_FLAGS> <OBJECTS>")
endif()
if(NOT DEFINED CMAKE_TOPS_ARCHIVE_APPEND)
  set(CMAKE_TOPS_ARCHIVE_APPEND "<CMAKE_AR> q <TARGET> <LINK_FLAGS> <OBJECTS>")
endif()
if(NOT DEFINED CMAKE_TOPS_ARCHIVE_FINISH)
  set(CMAKE_TOPS_ARCHIVE_FINISH "<CMAKE_RANLIB> <TARGET>")
endif()

if(NOT CMAKE_TOPS_COMPILE_OBJECT)
  set(CMAKE_TOPS_COMPILE_OBJECT
    "<CMAKE_TOPS_COMPILER> ${_CMAKE_TOPS_EXTRA_FLAGS} <DEFINES> <INCLUDES> <FLAGS> ${_CMAKE_COMPILE_AS_TOPS_FLAG} -c <SOURCE> -o <OBJECT>")
endif()

# compile a cu file into an executable
if(NOT CMAKE_TOPS_LINK_EXECUTABLE)
  set(CMAKE_TOPS_LINK_EXECUTABLE
    "<CMAKE_TOPS_COMPILER> <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>${__IMPLICIT_LINKS}")
endif()

# Add implicit host link directories that contain device libraries
# to the device link line.
set(__IMPLICIT_DLINK_DIRS ${CMAKE_TOPS_IMPLICIT_LINK_DIRECTORIES})
if(__IMPLICIT_DLINK_DIRS)
  list(REMOVE_ITEM __IMPLICIT_DLINK_DIRS ${CMAKE_TOPS_HOST_IMPLICIT_LINK_DIRECTORIES})
endif()
set(__IMPLICIT_DLINK_FLAGS)
foreach(dir ${__IMPLICIT_DLINK_DIRS})
  if(EXISTS "${dir}/libcurand_static.a")
    string(APPEND __IMPLICIT_DLINK_FLAGS " -L\"${dir}\"")
  endif()
endforeach()
unset(__IMPLICIT_DLINK_DIRS)


#These are used when linking relocatable (dc) TOPS code
if(NOT CMAKE_TOPS_DEVICE_LINK_LIBRARY)
  set(CMAKE_TOPS_DEVICE_LINK_LIBRARY
    "<CMAKE_TOPS_COMPILER> ${_CMAKE_TOPS_EXTRA_FLAGS} <LANGUAGE_COMPILE_FLAGS> <LINK_FLAGS> ${CMAKE_TOPS_COMPILE_OPTIONS_PIC} ${_CMAKE_TOPS_EXTRA_DEVICE_LINK_FLAGS} -shared -dlink <OBJECTS> -o <TARGET> <LINK_LIBRARIES>${__IMPLICIT_DLINK_FLAGS}")
endif()
if(NOT CMAKE_TOPS_DEVICE_LINK_EXECUTABLE)
  set(CMAKE_TOPS_DEVICE_LINK_EXECUTABLE
    "<CMAKE_TOPS_COMPILER> ${_CMAKE_TOPS_EXTRA_FLAGS} <LANGUAGE_COMPILE_FLAGS> <LINK_FLAGS> ${CMAKE_TOPS_COMPILE_OPTIONS_PIC} ${_CMAKE_TOPS_EXTRA_DEVICE_LINK_FLAGS} -shared -dlink <OBJECTS> -o <TARGET> <LINK_LIBRARIES>${__IMPLICIT_DLINK_FLAGS}")
endif()

# Used when device linking is handled by CMake.
if(NOT CMAKE_TOPS_DEVICE_LINK_COMPILE)
  set(CMAKE_TOPS_DEVICE_LINK_COMPILE "<CMAKE_TOPS_COMPILER> ${_CMAKE_TOPS_EXTRA_FLAGS} <FLAGS> <LINK_FLAGS> -D__TOPS_INCLUDE_COMPILER_INTERNAL_HEADERS__ -D__NV_EXTRA_INITIALIZATION=\"\" -D__NV_EXTRA_FINALIZATION=\"\" -DREGISTERLINKBINARYFILE=\\\"<REGISTER_FILE>\\\" -DFATBINFILE=\\\"<FATBINARY>\\\" ${_CMAKE_COMPILE_AS_TOPS_FLAG} -c \"${CMAKE_TOPS_COMPILER_TOOLKIT_LIBRARY_ROOT}/bin/crt/link.stub\" -o <OBJECT>")
endif()

unset(__IMPLICIT_DLINK_FLAGS)

set(CMAKE_TOPS_INFORMATION_LOADED 1)
set(CMAKE_INCLUDE_SYSTEM_FLAG_TOPS "-isystem ")