scroll-flake/flake.nix at master · Diax170/scroll-flake · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
{
  description = "NixOS flake for scroll, a fork of Sway with a scrolling tiling layout";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-unstable";

    scroll-stable = {
      url = "github:dawsers/scroll?ref=refs/tags/1.12.17";
      flake = false;
    };

    scroll-git = {
      url = "github:dawsers/scroll?ref=master";
      flake = false;
    };
  };

  outputs =
    inputs@{ self, nixpkgs, ... }:
    let
      supportedSystems = [
        "x86_64-linux"
        "aarch64-linux"
      ];
      forAllSystems = nixpkgs.lib.genAttrs supportedSystems;
      nixpkgsFor = forAllSystems (system: import nixpkgs { inherit system; });
    in
    {
      packages = forAllSystems (
        system:
        let
          scrollStablePkgs = (
            import nixpkgs {
              inherit system;
              overlays = [ (import ./overlays/scroll-stable.nix { inherit inputs; }) ];
            }
          );
          scrollGitPkgs = (
            import nixpkgs {
              inherit system;
              overlays = [ (import ./overlays/scroll-git.nix { inherit inputs; }) ];
            }
          );
        in
        {
          "scroll-stable" = scrollStablePkgs.sway;
          "scroll-stable-unwrapped" = scrollStablePkgs.sway-unwrapped;

          "scroll-git" = scrollGitPkgs.sway;
          "scroll-git-unwrapped" = scrollGitPkgs.sway-unwrapped;

          default = self.packages.${system}."scroll-stable";
        }
      );

      devShells = forAllSystems (
        system:
        let
          pkgs = nixpkgsFor.${system};
          scroll-unwrapped = self.packages.${pkgs.system}.scroll-git-unwrapped;
        in
        {
          default = pkgs.mkShell {
            inputsFrom = [ scroll-unwrapped ];
            packages = with pkgs; [
              meson
              cmake
              ninja
              pkg-config
            ];
          };
        }
      );

      nixosModules.default = import ./modules/nixos.nix { inherit self; };
      homeModules.default = import ./modules/home/home.nix { inherit self; };
    };
}