Challenge 13 confused (Spoilers!!!!!!!!!!!!!!!!)

[Abelaby]

I'm facing issue with challenge 13. I tried the challenge 13 by deploying it in 'local remix vm' and also deployed my own version of the challenge contract and the helper contract to 'sepolia' and I was able to solve the challenge both times.

But when I try to solve the challenge by using 'write contract' in etherscan, It is reverting.

[Abelaby]

@shikhar229169 tagging you cos it seems like you are the last person who solved this. Sorry for bothering you.
Any hints?

[shikhar229169]

idk how it passed in your local remix.

But ensure that you understand the concept of delegate call.
Suppose contract A performs delegate call on contract B along with the data which reference to a function in contract B, then the actual function execution takes place in contract A not in contract B, that means that the storage slots are read/write from the contract A.

[Abelaby]

These are my version of challenge contract and helper contract(I just copied the original contracts and did some edits, lol). I dont why they pass with my test contracts. The delegatecall always seems to add 12 to the passed value in my sample contracts. Can you help me sort this out?

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.18;

interface YourContract {
    function owner() external view returns (address);
    function getNumber() external view returns (int256);
}

contract LessonThirteen {
    error LessonThirteen__NotSolved();

    string private constant LESSON_IMAGE = "ipfs://QmdHgyTYLg3hpjMdf6D9nE7Udwubxk2WvmJtv2KewCd6KM"; // TODO
    uint256 private constant TARGET_NUMBER = 1337;
    uint256 private LESSON_VERSION = 2;
    uint256 private COURSE_VERSION = 3;
    uint256 public result;
    bool public solved = false;

    LessonThirteenHelper private immutable i_helperContract;

    constructor()  {
        i_helperContract = new LessonThirteenHelper();
    }


    function solveChallenge(address yourContract, string memory yourTwitterHandle) external {
        YourContract yc = YourContract(yourContract);
        int256 number = yc.getNumber();
        address yourOwner = yc.owner();

        if (yourOwner != msg.sender) {
            revert LessonThirteen__NotSolved();
        }
        (bool success, bytes memory data) =
            address(i_helperContract).delegatecall(abi.encodeWithSignature("addTen(int256)", number));

        if (!success) {
            revert LessonThirteen__NotSolved();
        }
         result = abi.decode(data, (uint256));

         if (result != TARGET_NUMBER) {
            revert LessonThirteen__NotSolved();
         }
        solved = true;
    }
}    
contract LessonThirteenHelper {
    int256 myValue = 100;

    function addTen(int256 number) public view returns (int256) {
        unchecked {
            return number + myValue + int256(10);
        }
    }
}

[Abelaby]

Here's how I understood it: @shikhar229169

when we are using the delegatecall, num becomes LESSON_VERSION in the challenge contract which gets added to the number and 10.
LESSON_VERSION is the one in storage slot(0) since it is the first STATE variable in our contract and I also verified it by writing the following function in my version of challenge contract:

function getStorage(int256 slot)public view returns (int result){
        assembly{
            result:=sload(slot)
        }
    }

So essentially, when the delegatecall happens, 12 is added to the number in our contract so shouldn't the number be 1325 which after delegatecall gives us 1337 which is the target number.
But still im getting my transaction reverted, idk where this is going wrong.

[shikhar229169]

I got this now why its happening.
Actually as you modified your smart contract, and removed the inherited contract AFoundryCourseChallenge, so the storage slots changed.
As the variables of AFoundryCourseChallenge are now not available in your challenge contract.

So to get storage slot of contract, you can get it easily by cast command:

cast storage <contract address> <storage slot> --rpc-url <network_rpc_url>

And you can run this for the actual challenge contract, and then convert the value at that storage slot to decimal.

[Abelaby]

Thank you so much mate..... I considered the inheritance but I didn't wanna go down the rabbit hole. You are great fren!!!

Also I learned a new cast command, thanks to you again.

Also I'm sorry if I spoiled this challenge for anyone, I will edit the heading of this discussion.

[Ynyesto]

Thanks a lot! I was struggling as well even though I understood well the concepts, this can get very tricky! However, we should be able to work out which number it is we need without having to use cast, right? Storage slot 0 in AFoundryCourseChallenge is that of Ownable, since there is also inheritance here, so the number we need is just the owner of the LessonThirteen contract cast to int256!! (Of course that is not the result getNumber() needs to return). I'm just adding this answer because, since the challenge is already spoiled (I solved it with cast before thinking of all this), I thought it would be nice for other people to understand this as well before passing onto the next lesson! :-)

[Ynyesto]

Also, I would have thought instead of using cast to-dec to get to get the number we could just cast the owner's address like this: int256(uint256(uint160(0x643315C9Be056cDEA171F4e7b2222a4ddaB9F88D))). However, this doesn't work. Anybody now why? How could we get the int number we need programatically, to solve this challenge without using cast at all?

[SyedAsadKazmi]

Because you need to calculate the number using the value (i.e., int256(uint256(uint160(0x643315C9Be056cDEA171F4e7b2222a4ddaB9F88D)))). Here's how I did that:

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.24;

contract Calculate {

    // number + myValue + int256(10) = 1337 

    function getValue() public pure returns(uint256) {
        return uint256(uint160(0x643315C9Be056cDEA171F4e7b2222a4ddaB9F88D)); // 572038313094850821099624258919152072749626292365
    }

    function getNumber() public pure returns(int256) {
        return int256(1337) - int256(getValue()) - int256(10); // -572038313094850821099624258919152072749626291038
    }

    function shouldReturn_1337() external pure returns(int256) {
        return int256(getNumber()) + int256(getValue()) + int256(10); // 1337
    }
}