An opinion on my test?

[DarKKnight270]

Hi everyone, At the end of the raffle course, Patrick tells us to make our own integration test, here is mine, can you help me about it ? Maybe tell me what is good in it and what is wrong, and what can I do to improve it, thanks :

`// SPDX-License-Identifier: MIT
pragma solidity ^0.8.19;

import {Raffle} from "../../src/Raffle.sol";
import {Test, console2} from "forge-std/Test.sol";
import {DeployRaffle} from "../../script/DeployRaffle.s.sol";
import {HelperConfig} from "../../script/HelperConfig.s.sol";
import {VRFCoordinatorV2_5Mock} from "@chainlink/contracts/src/v0.8/vrf/mocks/VRFCoordinatorV2_5Mock.sol";
import {Vm} from "forge-std/Vm.sol";

/**

• @title InteractionsTest
• @notice Full integration test (enterRaffle -> upkeep -> VRF fulfill)
  */

contract InteractionsTest is Test {
/* Events */
event RaffleEntered(address indexed player);
event WinnerPicked(address indexed winner);
event RequestRaffleWinner(uint256 indexed requestId);

Raffle public raffle;
address public PLAYER = makeAddr("PLAYER");
uint256 public constant STARTING_BALANCE = 100000000000000 ether;
uint256 public constant ENTRANCE_FEE = 0.1 ether;
uint256 public constant INTERVAL = 30;
address public newVRFCoordinator;

function setUp() external {
    DeployRaffle deployRaffle = new DeployRaffle();
    HelperConfig helperConfig;
    (raffle, helperConfig) = deployRaffle.run();

    // Récupère l'adresse du VRF mock depuis la config
    newVRFCoordinator = helperConfig.getConfig().vrfCoordinator;

    // Donne un solde à PLAYER
    vm.deal(PLAYER, STARTING_BALANCE);
}

/**
 * @notice Test complet : on entre dans la loterie,
 * si upkeepNeeded => on performUpkeep,
 * puis on fulfillRandomWords, etc.
 */
function testUserCanEnterRaffleAndHaveAChanceToWin() public {
    for (uint256 i = 0; i < 4; i++) {
        console2.log("======== Cycle:", i);

        // 1) Enter the raffle
        vm.startPrank(PLAYER);
        vm.warp(block.timestamp + INTERVAL + 1);
        vm.roll(block.number + 1);
        raffle.enterRaffle{value: ENTRANCE_FEE}();
        vm.stopPrank();

        (bool upkeepNeeded, ) = raffle.checkUpkeep("");
        console2.log("Upkeep needed:", upkeepNeeded);

        if (upkeepNeeded) {
            // 2) Perform Upkeep
            vm.recordLogs();
            console2.log("Performing upkeep...");
            raffle.performUpkeep("");
            Vm.Log[] memory logsUpkeep = vm.getRecordedLogs();
            console2.log("Logs after performUpkeep:", logsUpkeep.length);

            // 3) Récupère le requestId depuis l'event RequestRaffleWinner
            bytes32 requestId = _findRequestRaffleWinner(logsUpkeep);

            // Vérification de l'état
            uint256 rState = uint256(raffle.getRaffleState());
            console2.log("Raffle state after upkeep:", rState);
            require(
                rState == 1,
                "Raffle should be CALCULATING after upkeep"
            );

            // 4) fulfillRandomWords avec le vrai requestId
            console2.log("Fulfilling random words with requestId:");
            console2.logBytes32(requestId);
            vm.recordLogs();
            VRFCoordinatorV2_5Mock(newVRFCoordinator).fulfillRandomWords(
                uint256(requestId),
                address(raffle)
            );
            Vm.Log[] memory logsFulfill = vm.getRecordedLogs();
            console2.log(
                "Logs after fulfillRandomWords:",
                logsFulfill.length
            );

            // 5) Vérifier l'event WinnerPicked
            _checkWinnerPicked(logsFulfill);

            // 6) Vérifie qu'on a un winner et que players est vide
            address recentWinner = raffle.getRecentWinner();
            require(recentWinner != address(0), "Winner address not set");
            address payable[] memory players = raffle.gets_players();
            require(players.length == 0, "Players array not reset");
        } else {
            // Si upkeepNeeded == false => expect revert
            console2.log("Expect revert UpkeepNotNeeded");
            vm.expectRevert(Raffle.Raffle__UpkeepNotNeeded.selector);
            raffle.performUpkeep("");
        }
    }
}

/**
 * @notice Parcourt les logs pour trouver l'event RequestRaffleWinner
 * @return requestId Extrait de topics[1] si trouvé
 */
function _findRequestRaffleWinner(
    Vm.Log[] memory logsArr
) internal pure returns (bytes32 requestId) {
    bytes32 topic = keccak256("RequestRaffleWinner(uint256)");
    for (uint256 i = 0; i < logsArr.length; i++) {
        if (logsArr[i].topics[0] == topic) {
            return logsArr[i].topics[1];
        }
    }
    revert("RequestRaffleWinner event not found");
}

/**
 * @notice Vérifie l'event WinnerPicked(address) dans logsFulfill
 */
function _checkWinnerPicked(Vm.Log[] memory logsFulfill) internal {
    bytes32 topic = keccak256("WinnerPicked(address)");
    bool found = false;
    for (uint256 i = 0; i < logsFulfill.length; i++) {
        if (logsFulfill[i].topics[0] == topic) {
            found = true;
            break;
        }
    }
    require(found, "WinnerPicked event not emitted");
}

}
`

[EngrPips]

Hello @DarKKnight270, Have you run the test and everything works as expected.

[DarKKnight270]

hi @EngrPips, how are you ? yes the test passes

[EngrPips]

Awesome, I will advise that you make it so different addresses enter the raffle to make it more real instead of only the USER entering the lottery multiple times.