Error: "chainId" not found or not visible after argument-dependent lookup in block.

[goofylawz]

Good day folks,

I'm receiving the following error:

--> script/HelperConfig.s.sol:51:35:
   |
51 |         return getConfigByChainId(block.chainId);
   |                                   ^^^^^^^^^^^^^

My HelperConfig.s.sol file has the following code:

// SPDX-License-Identifier: MIT

pragma solidity 0.8.19;

import {Script} from "forge-std/Script.sol";
import {VRFCoordinatorV2_5Mock} from "@chainlink/contracts/src/v0.8/vrf/mocks/VRFCoordinatorV2_5Mock.sol";

abstract contract CodeConstants {
    /* VRF Mock Values */
    uint96 public MOCK_BASE_FEE = 0.25 ether;
    uint96 public MOCK_GAS_PRICE_LINK = 1e9;
    // Link / ETH Price
    int256 public MOCK_WEI_PER_UINT_LINK = 4e15;

    uint256 public constant ETH_SEPOLIA_CHAIN_ID = 11155111;
    uint256 public constant LOCAL_CHAIN_ID = 31337;
}

contract HelperConfig is CodeConstants, Script {
    error HelperConfig__InvalidChainID();

    struct NetworkConfig {
        uint256 entranceFee;
        uint256 interval;
        address vrfCoordinator;
        bytes32 gasLane;
        uint32 callbackGasLimit;
        uint256 subscriptionId;
    }

    NetworkConfig public localNetworkConfig;
    mapping(uint256 chainId => NetworkConfig) public networkConfigs;

    constructor() {
        networkConfigs[ETH_SEPOLIA_CHAIN_ID] = getSepoliaEthConfig();
    }

    function getConfigByChainId(
        uint256 chainId
    ) public returns (NetworkConfig memory) {
        if (networkConfigs[chainId].vrfCoordinator != address(0)) {
            return networkConfigs[chainId];
        } else if (chainId == LOCAL_CHAIN_ID) {
            return getOrCreateAnvilEthConfig();
        } else {
            revert HelperConfig__InvalidChainID();
        }
    }

    function getConfig() public returns (NetworkConfig memory) {
        return getConfigByChainId(block.chainId);
    }

    function getSepoliaEthConfig() public pure returns (NetworkConfig memory) {
        return
            NetworkConfig({
                entranceFee: 0.01 ether, // 1e16
                interval: 30, // 30 seconds
                vrfCoordinator: 0x9DdfaCa8183c41ad55329BdeeD9F6A8d53168B1B,
                gasLane: 0x787d74caea10b2b357790d5b5247c2f63d1d91572a9846f780606e4d953677ae,
                callbackGasLimit: 500000, // 500,000 gas
                subscriptionId: 0
            });
    }

    function getOrCreateAnvilEthConfig() public returns (NetworkConfig memory) {
        // check to see if we set an active network config
        if (localNetworkConfig.vrfCoordinator != address(0)) {
            return localNetworkConfig;
        }

        // Deploy mocks
        vm.startBroadcast();
        VRFCoordinatorV2_5Mock vrfCoordinatorMock = new VRFCoordinatorV2_5Mock(
            MOCK_BASE_FEE,
            MOCK_GAS_PRICE_LINK,
            MOCK_WEI_PER_UINT_LINK
        );
        vm.stopBroadcast();

        localNetworkConfig = NetworkConfig({
            entranceFee: 0.01 ether, // 1e16
            interval: 30, // 30 seconds
            vrfCoordinator: address(vrfCoordinatorMock),
            gasLane: 0x787d74caea10b2b357790d5b5247c2f63d1d91572a9846f780606e4d953677ae, //doesn't matter
            callbackGasLimit: 500000, // 500,000 gas
            subscriptionId: 0 // might have to fix this
        });
        return localNetworkConfig;
    }
}

I rewatched a couple of time how Patrick was writing his code and tried to debug this with phind.com / ChatGPT but no success whatsoever.

Any tips?

[EngrPips]

Hello @goofylawz, it is block.chainid not block.chainId

[EngrPips]

Yeah, that is because, in the whole code, we were declaring our own variable, which we can name however we like, but here we want to access a variable that was declared at the global level, which was declared by the Solidity team I suppose, so we have to use the name they declared it as.

[goofylawz]

Thank you!

[EngrPips]

Anytime, Friend.

[goofylawz]

gm, any ideas what might be the issue here:

Error: Compiler run failed:
Error (9574): Type struct VmSafe.Log[] memory is not implicitly convertible to expected type struct VmSafe.Log[] memory.
   --> test/unit/RaffleTest.t.sol:168:9:
    |
168 |         Vm.Log[] memory entries = vm.getRecordedLogs();
    |         ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

[EngrPips]

Hello @goofylawz, Please open a separate discussion for this issue and give it an appropriate topic so that it will be easy for others to search and find it incase they run into the same issue.